git.squeep.com Git - akkoma/blob - lib/pleroma/web/mastodon_api/controllers/timeline_controller.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.MastodonAPI.TimelineController do
   6   use Pleroma.Web, :controller
   7
   8   import Pleroma.Web.ControllerHelper,
   9     only: [add_link_headers: 2, add_link_headers: 3, truthy_param?: 1]
  10
  11   alias Pleroma.Pagination
  12   alias Pleroma.Plugs.EnsurePublicOrAuthenticatedPlug
  13   alias Pleroma.Plugs.OAuthScopesPlug
  14   alias Pleroma.Plugs.RateLimiter
  15   alias Pleroma.User
  16   alias Pleroma.Web.ActivityPub.ActivityPub
  17
  18   plug(:skip_plug, EnsurePublicOrAuthenticatedPlug when action in [:public, :hashtag])
  19
  20   # TODO: Replace with a macro when there is a Phoenix release with the following commit in it:
  21   # https://github.com/phoenixframework/phoenix/commit/2e8c63c01fec4dde5467dbbbf9705ff9e780735e
  22
  23   plug(RateLimiter, [name: :timeline, bucket_name: :direct_timeline] when action == :direct)
  24   plug(RateLimiter, [name: :timeline, bucket_name: :public_timeline] when action == :public)
  25   plug(RateLimiter, [name: :timeline, bucket_name: :home_timeline] when action == :home)
  26   plug(RateLimiter, [name: :timeline, bucket_name: :hashtag_timeline] when action == :hashtag)
  27   plug(RateLimiter, [name: :timeline, bucket_name: :list_timeline] when action == :list)
  28
  29   plug(OAuthScopesPlug, %{scopes: ["read:statuses"]} when action in [:home, :direct])
  30   plug(OAuthScopesPlug, %{scopes: ["read:lists"]} when action == :list)
  31
  32   plug(
  33     OAuthScopesPlug,
  34     %{scopes: ["read:statuses"], fallback: :proceed_unauthenticated}
  35     when action in [:public, :hashtag]
  36   )
  37
  38   plug(:put_view, Pleroma.Web.MastodonAPI.StatusView)
  39
  40   # GET /api/v1/timelines/home
  41   def home(%{assigns: %{user: user}} = conn, params) do
  42     params =
  43       params
  44       |> Map.put("type", ["Create", "Announce"])
  45       |> Map.put("blocking_user", user)
  46       |> Map.put("muting_user", user)
  47       |> Map.put("reply_filtering_user", user)
  48       |> Map.put("user", user)
  49
  50     recipients = [user.ap_id | User.following(user)]
  51
  52     activities =
  53       recipients
  54       |> ActivityPub.fetch_activities(params)
  55       |> Enum.reverse()
  56
  57     conn
  58     |> add_link_headers(activities)
  59     |> render("index.json",
  60       activities: activities,
  61       for: user,
  62       as: :activity
  63     )
  64   end
  65
  66   # GET /api/v1/timelines/direct
  67   def direct(%{assigns: %{user: user}} = conn, params) do
  68     params =
  69       params
  70       |> Map.put("type", "Create")
  71       |> Map.put("blocking_user", user)
  72       |> Map.put("user", user)
  73       |> Map.put(:visibility, "direct")
  74
  75     activities =
  76       [user.ap_id]
  77       |> ActivityPub.fetch_activities_query(params)
  78       |> Pagination.fetch_paginated(params)
  79
  80     conn
  81     |> add_link_headers(activities)
  82     |> render("index.json",
  83       activities: activities,
  84       for: user,
  85       as: :activity
  86     )
  87   end
  88
  89   # GET /api/v1/timelines/public
  90   def public(%{assigns: %{user: user}} = conn, params) do
  91     local_only = truthy_param?(params["local"])
  92
  93     cfg_key =
  94       if local_only do
  95         :local
  96       else
  97         :federated
  98       end
  99
 100     restrict? = Pleroma.Config.get([:restrict_unauthenticated, :timelines, cfg_key])
 101
 102     if restrict? and is_nil(user) do
 103       render_error(conn, :unauthorized, "authorization required for timeline view")
 104     else
 105       activities =
 106         params
 107         |> Map.put("type", ["Create", "Announce"])
 108         |> Map.put("local_only", local_only)
 109         |> Map.put("blocking_user", user)
 110         |> Map.put("muting_user", user)
 111         |> Map.put("reply_filtering_user", user)
 112         |> ActivityPub.fetch_public_activities()
 113
 114       conn
 115       |> add_link_headers(activities, %{"local" => local_only})
 116       |> render("index.json",
 117         activities: activities,
 118         for: user,
 119         as: :activity
 120       )
 121     end
 122   end
 123
 124   defp hashtag_fetching(params, user, local_only) do
 125     tags =
 126       [params["tag"], params["any"]]
 127       |> List.flatten()
 128       |> Enum.uniq()
 129       |> Enum.filter(& &1)
 130       |> Enum.map(&String.downcase(&1))
 131
 132     tag_all =
 133       params
 134       |> Map.get("all", [])
 135       |> Enum.map(&String.downcase(&1))
 136
 137     tag_reject =
 138       params
 139       |> Map.get("none", [])
 140       |> Enum.map(&String.downcase(&1))
 141
 142     _activities =
 143       params
 144       |> Map.put("type", "Create")
 145       |> Map.put("local_only", local_only)
 146       |> Map.put("blocking_user", user)
 147       |> Map.put("muting_user", user)
 148       |> Map.put("user", user)
 149       |> Map.put("tag", tags)
 150       |> Map.put("tag_all", tag_all)
 151       |> Map.put("tag_reject", tag_reject)
 152       |> ActivityPub.fetch_public_activities()
 153   end
 154
 155   # GET /api/v1/timelines/tag/:tag
 156   def hashtag(%{assigns: %{user: user}} = conn, params) do
 157     local_only = truthy_param?(params["local"])
 158
 159     activities = hashtag_fetching(params, user, local_only)
 160
 161     conn
 162     |> add_link_headers(activities, %{"local" => local_only})
 163     |> render("index.json",
 164       activities: activities,
 165       for: user,
 166       as: :activity
 167     )
 168   end
 169
 170   # GET /api/v1/timelines/list/:list_id
 171   def list(%{assigns: %{user: user}} = conn, %{"list_id" => id} = params) do
 172     with %Pleroma.List{title: _title, following: following} <- Pleroma.List.get(id, user) do
 173       params =
 174         params
 175         |> Map.put("type", "Create")
 176         |> Map.put("blocking_user", user)
 177         |> Map.put("user", user)
 178         |> Map.put("muting_user", user)
 179
 180       # we must filter the following list for the user to avoid leaking statuses the user
 181       # does not actually have permission to see (for more info, peruse security issue #270).
 182
 183       user_following = User.following(user)
 184
 185       activities =
 186         following
 187         |> Enum.filter(fn x -> x in user_following end)
 188         |> ActivityPub.fetch_activities_bounded(following, params)
 189         |> Enum.reverse()
 190
 191       render(conn, "index.json",
 192         activities: activities,
 193         for: user,
 194         as: :activity
 195       )
 196     else
 197       _e -> render_error(conn, :forbidden, "Error.")
 198     end
 199   end
 200 end