git.squeep.com Git - akkoma/blob - lib/pleroma/web/mastodon_api/controllers/timeline_controller.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.MastodonAPI.TimelineController do
   6   use Pleroma.Web, :controller
   7
   8   import Pleroma.Web.ControllerHelper,
   9     only: [add_link_headers: 2, add_link_headers: 3]
  10
  11   alias Pleroma.Pagination
  12   alias Pleroma.Plugs.EnsurePublicOrAuthenticatedPlug
  13   alias Pleroma.Plugs.OAuthScopesPlug
  14   alias Pleroma.Plugs.RateLimiter
  15   alias Pleroma.User
  16   alias Pleroma.Web.ActivityPub.ActivityPub
  17
  18   plug(Pleroma.Web.ApiSpec.CastAndValidate)
  19   plug(:skip_plug, EnsurePublicOrAuthenticatedPlug when action in [:public, :hashtag])
  20
  21   # TODO: Replace with a macro when there is a Phoenix release with the following commit in it:
  22   # https://github.com/phoenixframework/phoenix/commit/2e8c63c01fec4dde5467dbbbf9705ff9e780735e
  23
  24   plug(RateLimiter, [name: :timeline, bucket_name: :direct_timeline] when action == :direct)
  25   plug(RateLimiter, [name: :timeline, bucket_name: :public_timeline] when action == :public)
  26   plug(RateLimiter, [name: :timeline, bucket_name: :home_timeline] when action == :home)
  27   plug(RateLimiter, [name: :timeline, bucket_name: :hashtag_timeline] when action == :hashtag)
  28   plug(RateLimiter, [name: :timeline, bucket_name: :list_timeline] when action == :list)
  29
  30   plug(OAuthScopesPlug, %{scopes: ["read:statuses"]} when action in [:home, :direct])
  31   plug(OAuthScopesPlug, %{scopes: ["read:lists"]} when action == :list)
  32
  33   plug(
  34     OAuthScopesPlug,
  35     %{scopes: ["read:statuses"], fallback: :proceed_unauthenticated}
  36     when action in [:public, :hashtag]
  37   )
  38
  39   plug(:put_view, Pleroma.Web.MastodonAPI.StatusView)
  40
  41   defdelegate open_api_operation(action), to: Pleroma.Web.ApiSpec.TimelineOperation
  42
  43   # GET /api/v1/timelines/home
  44   def home(%{assigns: %{user: user}} = conn, params) do
  45     params =
  46       params
  47       |> Map.put(:type, ["Create", "Announce"])
  48       |> Map.put(:blocking_user, user)
  49       |> Map.put(:muting_user, user)
  50       |> Map.put(:reply_filtering_user, user)
  51       |> Map.put(:announce_filtering_user, user)
  52       |> Map.put(:user, user)
  53
  54     activities =
  55       [user.ap_id | User.following(user)]
  56       |> ActivityPub.fetch_activities(params)
  57       |> Enum.reverse()
  58
  59     conn
  60     |> add_link_headers(activities)
  61     |> render("index.json",
  62       activities: activities,
  63       for: user,
  64       as: :activity
  65     )
  66   end
  67
  68   # GET /api/v1/timelines/direct
  69   def direct(%{assigns: %{user: user}} = conn, params) do
  70     params =
  71       params
  72       |> Map.put(:type, "Create")
  73       |> Map.put(:blocking_user, user)
  74       |> Map.put(:user, user)
  75       |> Map.put(:visibility, "direct")
  76
  77     activities =
  78       [user.ap_id]
  79       |> ActivityPub.fetch_activities_query(params)
  80       |> Pagination.fetch_paginated(params)
  81
  82     conn
  83     |> add_link_headers(activities)
  84     |> render("index.json",
  85       activities: activities,
  86       for: user,
  87       as: :activity
  88     )
  89   end
  90
  91   defp restrict_unauthenticated?(local_only) do
  92     config_key =
  93       if local_only do
  94         :local
  95       else
  96         :federated
  97       end
  98
  99     Pleroma.Config.get([:restrict_unauthenticated, :timelines, config_key])
 100   end
 101
 102   # GET /api/v1/timelines/public
 103   def public(%{assigns: %{user: user}} = conn, params) do
 104     local_only = params[:local]
 105
 106     if is_nil(user) and restrict_unauthenticated?(local_only) do
 107       fail_on_bad_auth(conn)
 108     else
 109       activities =
 110         params
 111         |> Map.put(:type, ["Create"])
 112         |> Map.put(:local_only, local_only)
 113         |> Map.put(:blocking_user, user)
 114         |> Map.put(:muting_user, user)
 115         |> Map.put(:reply_filtering_user, user)
 116         |> ActivityPub.fetch_public_activities()
 117
 118       conn
 119       |> add_link_headers(activities, %{"local" => local_only})
 120       |> render("index.json",
 121         activities: activities,
 122         for: user,
 123         as: :activity
 124       )
 125     end
 126   end
 127
 128   defp fail_on_bad_auth(conn) do
 129     render_error(conn, :unauthorized, "authorization required for timeline view")
 130   end
 131
 132   defp hashtag_fetching(params, user, local_only) do
 133     tags =
 134       [params[:tag], params[:any]]
 135       |> List.flatten()
 136       |> Enum.uniq()
 137       |> Enum.reject(&is_nil/1)
 138       |> Enum.map(&String.downcase/1)
 139
 140     tag_all =
 141       params
 142       |> Map.get(:all, [])
 143       |> Enum.map(&String.downcase/1)
 144
 145     tag_reject =
 146       params
 147       |> Map.get(:none, [])
 148       |> Enum.map(&String.downcase/1)
 149
 150     _activities =
 151       params
 152       |> Map.put(:type, "Create")
 153       |> Map.put(:local_only, local_only)
 154       |> Map.put(:blocking_user, user)
 155       |> Map.put(:muting_user, user)
 156       |> Map.put(:user, user)
 157       |> Map.put(:tag, tags)
 158       |> Map.put(:tag_all, tag_all)
 159       |> Map.put(:tag_reject, tag_reject)
 160       |> ActivityPub.fetch_public_activities()
 161   end
 162
 163   # GET /api/v1/timelines/tag/:tag
 164   def hashtag(%{assigns: %{user: user}} = conn, params) do
 165     local_only = params[:local]
 166
 167     if is_nil(user) and restrict_unauthenticated?(local_only) do
 168       fail_on_bad_auth(conn)
 169     else
 170       activities = hashtag_fetching(params, user, local_only)
 171
 172       conn
 173       |> add_link_headers(activities, %{"local" => local_only})
 174       |> render("index.json",
 175         activities: activities,
 176         for: user,
 177         as: :activity
 178       )
 179     end
 180   end
 181
 182   # GET /api/v1/timelines/list/:list_id
 183   def list(%{assigns: %{user: user}} = conn, %{list_id: id} = params) do
 184     with %Pleroma.List{title: _title, following: following} <- Pleroma.List.get(id, user) do
 185       params =
 186         params
 187         |> Map.new(fn {key, value} -> {to_string(key), value} end)
 188         |> Map.put("type", "Create")
 189         |> Map.put("blocking_user", user)
 190         |> Map.put("user", user)
 191         |> Map.put("muting_user", user)
 192
 193       # we must filter the following list for the user to avoid leaking statuses the user
 194       # does not actually have permission to see (for more info, peruse security issue #270).
 195
 196       user_following = User.following(user)
 197
 198       activities =
 199         following
 200         |> Enum.filter(fn x -> x in user_following end)
 201         |> ActivityPub.fetch_activities_bounded(following, params)
 202         |> Enum.reverse()
 203
 204       render(conn, "index.json",
 205         activities: activities,
 206         for: user,
 207         as: :activity
 208       )
 209     else
 210       _e -> render_error(conn, :forbidden, "Error.")
 211     end
 212   end
 213 end