git.squeep.com Git - akkoma/blob - lib/pleroma/web/mastodon_api/controllers/suggestion_controller.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2021 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.MastodonAPI.SuggestionController do
   6   use Pleroma.Web, :controller
   7   alias Pleroma.User
   8   alias Pleroma.UserRelationship
   9
  10   require Logger
  11
  12   plug(Pleroma.Web.ApiSpec.CastAndValidate)
  13   plug(Pleroma.Web.Plugs.OAuthScopesPlug, %{scopes: ["read"]} when action in [:index, :index2])
  14   plug(Pleroma.Web.Plugs.OAuthScopesPlug, %{scopes: ["write"]} when action in [:dismiss])
  15
  16   def open_api_operation(action) do
  17     operation = String.to_existing_atom("#{action}_operation")
  18     apply(__MODULE__, operation, [])
  19   end
  20
  21   def index_operation do
  22     %OpenApiSpex.Operation{
  23       tags: ["Suggestions"],
  24       summary: "Follow suggestions (Not implemented)",
  25       operationId: "SuggestionController.index",
  26       responses: %{
  27         200 => Pleroma.Web.ApiSpec.Helpers.empty_array_response()
  28       }
  29     }
  30   end
  31
  32   def index2_operation do
  33     %OpenApiSpex.Operation{
  34       tags: ["Suggestions"],
  35       summary: "Follow suggestions",
  36       operationId: "SuggestionController.index2",
  37       responses: %{
  38         200 => Pleroma.Web.ApiSpec.Helpers.empty_array_response()
  39       }
  40     }
  41   end
  42
  43   def dismiss_operation do
  44     %OpenApiSpex.Operation{
  45       tags: ["Suggestions"],
  46       summary: "Remove a suggestion",
  47       operationId: "SuggestionController.dismiss",
  48       parameters: [
  49         OpenApiSpex.Operation.parameter(
  50           :account_id,
  51           :path,
  52           %OpenApiSpex.Schema{type: :string},
  53           "Account to dismiss",
  54           required: true
  55         )
  56       ],
  57       responses: %{
  58         200 => Pleroma.Web.ApiSpec.Helpers.empty_object_response()
  59       }
  60     }
  61   end
  62
  63   @doc "GET /api/v1/suggestions"
  64   def index(conn, params),
  65     do: Pleroma.Web.MastodonAPI.MastodonAPIController.empty_array(conn, params)
  66
  67   @doc "GET /api/v2/suggestions"
  68   def index2(%{assigns: %{user: user}} = conn, params) do
  69     limit = Map.get(params, :limit, 40) |> min(80)
  70
  71     users =
  72       %{is_suggested: true, limit: limit}
  73       |> User.Query.build()
  74       |> Pleroma.Repo.all()
  75
  76     render(conn, "index.json", %{users: users, source: :staff, for: user})
  77   end
  78
  79   @doc "DELETE /api/v1/suggestions/:account_id"
  80   def dismiss(%{assigns: %{user: source}} = conn, %{account_id: user_id}) do
  81     with %User{} = target <- User.get_cached_by_id(user_id),
  82          {:ok, _} <- UserRelationship.create(:suggestion_dismiss, source, target) do
  83       json(conn, %{})
  84     end
  85   end
  86 end