git.squeep.com Git - akkoma/blob - lib/pleroma/web/mastodon_api/controllers/subscription_controller.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.MastodonAPI.SubscriptionController do
   6   @moduledoc "The module represents functions to manage user subscriptions."
   7   use Pleroma.Web, :controller
   8
   9   alias Pleroma.Web.MastodonAPI.PushSubscriptionView, as: View
  10   alias Pleroma.Web.Push
  11   alias Pleroma.Web.Push.Subscription
  12
  13   action_fallback(:errors)
  14
  15   plug(Pleroma.Plugs.OAuthScopesPlug, %{scopes: ["push"]})
  16
  17   plug(Pleroma.Plugs.EnsurePublicOrAuthenticatedPlug)
  18
  19   # Creates PushSubscription
  20   # POST /api/v1/push/subscription
  21   #
  22   def create(%{assigns: %{user: user, token: token}} = conn, params) do
  23     with true <- Push.enabled(),
  24          {:ok, _} <- Subscription.delete_if_exists(user, token),
  25          {:ok, subscription} <- Subscription.create(user, token, params) do
  26       view = View.render("push_subscription.json", subscription: subscription)
  27       json(conn, view)
  28     end
  29   end
  30
  31   # Gets PushSubscription
  32   # GET /api/v1/push/subscription
  33   #
  34   def get(%{assigns: %{user: user, token: token}} = conn, _params) do
  35     with true <- Push.enabled(),
  36          {:ok, subscription} <- Subscription.get(user, token) do
  37       view = View.render("push_subscription.json", subscription: subscription)
  38       json(conn, view)
  39     end
  40   end
  41
  42   # Updates PushSubscription
  43   # PUT /api/v1/push/subscription
  44   #
  45   def update(%{assigns: %{user: user, token: token}} = conn, params) do
  46     with true <- Push.enabled(),
  47          {:ok, subscription} <- Subscription.update(user, token, params) do
  48       view = View.render("push_subscription.json", subscription: subscription)
  49       json(conn, view)
  50     end
  51   end
  52
  53   # Deletes PushSubscription
  54   # DELETE /api/v1/push/subscription
  55   #
  56   def delete(%{assigns: %{user: user, token: token}} = conn, _params) do
  57     with true <- Push.enabled(),
  58          {:ok, _response} <- Subscription.delete(user, token),
  59          do: json(conn, %{})
  60   end
  61
  62   # fallback action
  63   #
  64   def errors(conn, {:error, :not_found}) do
  65     conn
  66     |> put_status(:not_found)
  67     |> json(dgettext("errors", "Not found"))
  68   end
  69
  70   def errors(conn, _) do
  71     Pleroma.Web.MastodonAPI.FallbackController.call(conn, nil)
  72   end
  73 end