git.squeep.com Git - akkoma/blob - lib/pleroma/web/mastodon_api/controllers/poll_controller.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.MastodonAPI.PollController do
   6   use Pleroma.Web, :controller
   7
   8   import Pleroma.Web.ControllerHelper, only: [try_render: 3, json_response: 3]
   9
  10   alias Pleroma.Activity
  11   alias Pleroma.Object
  12   alias Pleroma.Web.ActivityPub.Visibility
  13   alias Pleroma.Web.CommonAPI
  14
  15   action_fallback(Pleroma.Web.MastodonAPI.FallbackController)
  16
  17   @doc "GET /api/v1/polls/:id"
  18   def show(%{assigns: %{user: user}} = conn, %{"id" => id}) do
  19     with %Object{} = object <- Object.get_by_id_and_maybe_refetch(id, interval: 60),
  20          %Activity{} = activity <- Activity.get_create_by_object_ap_id(object.data["id"]),
  21          true <- Visibility.visible_for_user?(activity, user) do
  22       try_render(conn, "show.json", %{object: object, for: user})
  23     else
  24       error when is_nil(error) or error == false ->
  25         render_error(conn, :not_found, "Record not found")
  26     end
  27   end
  28
  29   @doc "POST /api/v1/polls/:id/votes"
  30   def vote(%{assigns: %{user: user}} = conn, %{"id" => id, "choices" => choices}) do
  31     with %Object{data: %{"type" => "Question"}} = object <- Object.get_by_id(id),
  32          %Activity{} = activity <- Activity.get_create_by_object_ap_id(object.data["id"]),
  33          true <- Visibility.visible_for_user?(activity, user),
  34          {:ok, _activities, object} <- get_cached_vote_or_vote(user, object, choices) do
  35       try_render(conn, "show.json", %{object: object, for: user})
  36     else
  37       nil -> render_error(conn, :not_found, "Record not found")
  38       false -> render_error(conn, :not_found, "Record not found")
  39       {:error, message} -> json_response(conn, :unprocessable_entity, %{error: message})
  40     end
  41   end
  42
  43   defp get_cached_vote_or_vote(user, object, choices) do
  44     idempotency_key = "polls:#{user.id}:#{object.data["id"]}"
  45
  46     Cachex.fetch!(:idempotency_cache, idempotency_key, fn ->
  47       case CommonAPI.vote(user, object, choices) do
  48         {:error, _message} = res -> {:ignore, res}
  49         res -> {:commit, res}
  50       end
  51     end)
  52   end
  53 end