git.squeep.com Git - akkoma/blob - lib/pleroma/web/mastodon_api/controllers/filter_controller.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2021 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.MastodonAPI.FilterController do
   6   use Pleroma.Web, :controller
   7
   8   alias Pleroma.Filter
   9   alias Pleroma.Web.Plugs.OAuthScopesPlug
  10
  11   @oauth_read_actions [:show, :index]
  12
  13   plug(Pleroma.Web.ApiSpec.CastAndValidate)
  14   plug(OAuthScopesPlug, %{scopes: ["read:filters"]} when action in @oauth_read_actions)
  15
  16   plug(
  17     OAuthScopesPlug,
  18     %{scopes: ["write:filters"]} when action not in @oauth_read_actions
  19   )
  20
  21   defdelegate open_api_operation(action), to: Pleroma.Web.ApiSpec.FilterOperation
  22
  23   action_fallback(Pleroma.Web.MastodonAPI.FallbackController)
  24
  25   @doc "GET /api/v1/filters"
  26   def index(%{assigns: %{user: user}} = conn, _) do
  27     filters = Filter.get_filters(user)
  28
  29     render(conn, "index.json", filters: filters)
  30   end
  31
  32   @doc "POST /api/v1/filters"
  33   def create(%{assigns: %{user: user}, body_params: params} = conn, _) do
  34     with {:ok, response} <-
  35            params
  36            |> Map.put(:user_id, user.id)
  37            |> Map.put(:hide, params[:irreversible])
  38            |> Map.delete(:irreversible)
  39            |> Filter.create() do
  40       render(conn, "show.json", filter: response)
  41     end
  42   end
  43
  44   @doc "GET /api/v1/filters/:id"
  45   def show(%{assigns: %{user: user}} = conn, %{id: filter_id}) do
  46     with %Filter{} = filter <- Filter.get(filter_id, user) do
  47       render(conn, "show.json", filter: filter)
  48     else
  49       nil -> {:error, :not_found}
  50     end
  51   end
  52
  53   @doc "PUT /api/v1/filters/:id"
  54   def update(
  55         %{assigns: %{user: user}, body_params: params} = conn,
  56         %{id: filter_id}
  57       ) do
  58     params =
  59       if is_boolean(params[:irreversible]) do
  60         params
  61         |> Map.put(:hide, params[:irreversible])
  62         |> Map.delete(:irreversible)
  63       else
  64         params
  65       end
  66
  67     with %Filter{} = filter <- Filter.get(filter_id, user),
  68          {:ok, %Filter{} = filter} <- Filter.update(filter, params) do
  69       render(conn, "show.json", filter: filter)
  70     else
  71       nil -> {:error, :not_found}
  72       error -> error
  73     end
  74   end
  75
  76   @doc "DELETE /api/v1/filters/:id"
  77   def delete(%{assigns: %{user: user}} = conn, %{id: filter_id}) do
  78     with %Filter{} = filter <- Filter.get(filter_id, user),
  79          {:ok, _} <- Filter.delete(filter) do
  80       json(conn, %{})
  81     else
  82       nil -> {:error, :not_found}
  83       error -> error
  84     end
  85   end
  86 end