git.squeep.com Git - akkoma/blob - lib/pleroma/web/mastodon_api/controllers/app_controller.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2021 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.MastodonAPI.AppController do
   6   @moduledoc """
   7   Controller for supporting app-related actions.
   8   If authentication is an option, app tokens (user-unbound) must be supported.
   9   """
  10
  11   use Pleroma.Web, :controller
  12
  13   alias Pleroma.Repo
  14   alias Pleroma.Web.OAuth.App
  15   alias Pleroma.Web.OAuth.Scopes
  16   alias Pleroma.Web.OAuth.Token
  17
  18   action_fallback(Pleroma.Web.MastodonAPI.FallbackController)
  19
  20   plug(:skip_auth when action in [:create, :verify_credentials])
  21
  22   plug(Pleroma.Web.ApiSpec.CastAndValidate)
  23
  24   @local_mastodon_name "Mastodon-Local"
  25
  26   defdelegate open_api_operation(action), to: Pleroma.Web.ApiSpec.AppOperation
  27
  28   @doc "POST /api/v1/apps"
  29   def create(%{body_params: params} = conn, _params) do
  30     scopes = Scopes.fetch_scopes(params, ["read"])
  31
  32     app_attrs =
  33       params
  34       |> Map.take([:client_name, :redirect_uris, :website])
  35       |> Map.put(:scopes, scopes)
  36
  37     with cs <- App.register_changeset(%App{}, app_attrs),
  38          false <- cs.changes[:client_name] == @local_mastodon_name,
  39          {:ok, app} <- Repo.insert(cs) do
  40       render(conn, "show.json", app: app)
  41     end
  42   end
  43
  44   @doc """
  45   GET /api/v1/apps/verify_credentials
  46   Gets compact non-secret representation of the app. Supports app tokens and user tokens.
  47   """
  48   def verify_credentials(%{assigns: %{token: %Token{} = token}} = conn, _) do
  49     with %{app: %App{} = app} <- Repo.preload(token, :app) do
  50       render(conn, "compact_non_secret.json", app: app)
  51     end
  52   end
  53 end