git.squeep.com Git - akkoma/blob - lib/pleroma/web/mastodon_api/controllers/account_controller.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.MastodonAPI.AccountController do
   6   use Pleroma.Web, :controller
   7
   8   import Pleroma.Web.ControllerHelper,
   9     only: [add_link_headers: 2, truthy_param?: 1, assign_account_by_id: 2, json_response: 3]
  10
  11   alias Pleroma.User
  12   alias Pleroma.Web.CommonAPI
  13   alias Pleroma.Web.ActivityPub.ActivityPub
  14   alias Pleroma.Web.MastodonAPI.StatusView
  15   alias Pleroma.Web.MastodonAPI.MastodonAPI
  16   alias Pleroma.Web.MastodonAPI.ListView
  17   alias Pleroma.Plugs.RateLimiter
  18
  19   @relations ~w(follow unfollow)a
  20
  21   plug(RateLimiter, {:relations_id_action, params: ["id", "uri"]} when action in @relations)
  22   plug(RateLimiter, :relations_actions when action in @relations)
  23   plug(:assign_account_by_id when action not in [:show, :statuses])
  24
  25   action_fallback(Pleroma.Web.MastodonAPI.FallbackController)
  26
  27   @doc "GET /api/v1/accounts/:id"
  28   def show(%{assigns: %{user: for_user}} = conn, %{"id" => nickname_or_id}) do
  29     with %User{} = user <- User.get_cached_by_nickname_or_id(nickname_or_id, for: for_user),
  30          true <- User.auth_active?(user) || user.id == for_user.id || User.superuser?(for_user) do
  31       render(conn, "show.json", user: user, for: for_user)
  32     else
  33       _e -> render_error(conn, :not_found, "Can't find user")
  34     end
  35   end
  36
  37   @doc "GET /api/v1/accounts/:id/statuses"
  38   def statuses(%{assigns: %{user: reading_user}} = conn, params) do
  39     with %User{} = user <- User.get_cached_by_nickname_or_id(params["id"], for: reading_user) do
  40       params = Map.put(params, "tag", params["tagged"])
  41       activities = ActivityPub.fetch_user_activities(user, reading_user, params)
  42
  43       conn
  44       |> add_link_headers(activities)
  45       |> put_view(StatusView)
  46       |> render("index.json", activities: activities, for: reading_user, as: :activity)
  47     end
  48   end
  49
  50   @doc "GET /api/v1/accounts/:id/followers"
  51   def followers(%{assigns: %{user: for_user, account: user}} = conn, params) do
  52     followers =
  53       cond do
  54         for_user && user.id == for_user.id -> MastodonAPI.get_followers(user, params)
  55         user.info.hide_followers -> []
  56         true -> MastodonAPI.get_followers(user, params)
  57       end
  58
  59     conn
  60     |> add_link_headers(followers)
  61     |> render("index.json", for: for_user, users: followers, as: :user)
  62   end
  63
  64   @doc "GET /api/v1/accounts/:id/following"
  65   def following(%{assigns: %{user: for_user, account: user}} = conn, params) do
  66     followers =
  67       cond do
  68         for_user && user.id == for_user.id -> MastodonAPI.get_friends(user, params)
  69         user.info.hide_follows -> []
  70         true -> MastodonAPI.get_friends(user, params)
  71       end
  72
  73     conn
  74     |> add_link_headers(followers)
  75     |> render("index.json", for: for_user, users: followers, as: :user)
  76   end
  77
  78   @doc "GET /api/v1/accounts/:id/lists"
  79   def lists(%{assigns: %{user: user, account: account}} = conn, _params) do
  80     lists = Pleroma.List.get_lists_account_belongs(user, account)
  81
  82     conn
  83     |> put_view(ListView)
  84     |> render("index.json", lists: lists)
  85   end
  86
  87   @doc "POST /api/v1/accounts/:id/follow"
  88   def follow(%{assigns: %{user: %{id: id}, account: %{id: id}}}, _params) do
  89     {:error, :not_found}
  90   end
  91
  92   def follow(%{assigns: %{user: follower, account: followed}} = conn, _params) do
  93     with {:ok, follower} <- MastodonAPI.follow(follower, followed, conn.params) do
  94       render(conn, "relationship.json", user: follower, target: followed)
  95     else
  96       {:error, message} -> json_response(conn, :forbidden, %{error: message})
  97     end
  98   end
  99
 100   @doc "POST /api/v1/accounts/:id/unfollow"
 101   def unfollow(%{assigns: %{user: %{id: id}, account: %{id: id}}}, _params) do
 102     {:error, :not_found}
 103   end
 104
 105   def unfollow(%{assigns: %{user: follower, account: followed}} = conn, _params) do
 106     with {:ok, follower} <- CommonAPI.unfollow(follower, followed) do
 107       render(conn, "relationship.json", user: follower, target: followed)
 108     end
 109   end
 110
 111   @doc "POST /api/v1/accounts/:id/mute"
 112   def mute(%{assigns: %{user: muter, account: muted}} = conn, params) do
 113     notifications? = params |> Map.get("notifications", true) |> truthy_param?()
 114
 115     with {:ok, muter} <- User.mute(muter, muted, notifications?) do
 116       render(conn, "relationship.json", user: muter, target: muted)
 117     else
 118       {:error, message} -> json_response(conn, :forbidden, %{error: message})
 119     end
 120   end
 121
 122   @doc "POST /api/v1/accounts/:id/unmute"
 123   def unmute(%{assigns: %{user: muter, account: muted}} = conn, _params) do
 124     with {:ok, muter} <- User.unmute(muter, muted) do
 125       render(conn, "relationship.json", user: muter, target: muted)
 126     else
 127       {:error, message} -> json_response(conn, :forbidden, %{error: message})
 128     end
 129   end
 130
 131   @doc "POST /api/v1/accounts/:id/block"
 132   def block(%{assigns: %{user: blocker, account: blocked}} = conn, _params) do
 133     with {:ok, blocker} <- User.block(blocker, blocked),
 134          {:ok, _activity} <- ActivityPub.block(blocker, blocked) do
 135       render(conn, "relationship.json", user: blocker, target: blocked)
 136     else
 137       {:error, message} -> json_response(conn, :forbidden, %{error: message})
 138     end
 139   end
 140
 141   @doc "POST /api/v1/accounts/:id/unblock"
 142   def unblock(%{assigns: %{user: blocker, account: blocked}} = conn, _params) do
 143     with {:ok, blocker} <- User.unblock(blocker, blocked),
 144          {:ok, _activity} <- ActivityPub.unblock(blocker, blocked) do
 145       render(conn, "relationship.json", user: blocker, target: blocked)
 146     else
 147       {:error, message} -> json_response(conn, :forbidden, %{error: message})
 148     end
 149   end
 150 end