git.squeep.com Git - akkoma/blob - lib/pleroma/web/http_signatures/http_signatures.ex

   1 # https://tools.ietf.org/html/draft-cavage-http-signatures-08
   2 defmodule Pleroma.Web.HTTPSignatures do
   3   alias Pleroma.User
   4   alias Pleroma.Web.ActivityPub.Utils
   5   alias Pleroma.Web.ActivityPub.ActivityPub
   6   require Logger
   7
   8   def split_signature(sig) do
   9     default = %{"headers" => "date"}
  10
  11     sig =
  12       sig
  13       |> String.trim()
  14       |> String.split(",")
  15       |> Enum.reduce(default, fn part, acc ->
  16         [key | rest] = String.split(part, "=")
  17         value = Enum.join(rest, "=")
  18         Map.put(acc, key, String.trim(value, "\""))
  19       end)
  20
  21     Map.put(sig, "headers", String.split(sig["headers"], ~r/\s/))
  22   end
  23
  24   def validate(headers, signature, public_key) do
  25     sigstring = build_signing_string(headers, signature["headers"])
  26     Logger.debug("Signature: #{signature["signature"]}")
  27     Logger.debug("Sigstring: #{sigstring}")
  28     {:ok, sig} = Base.decode64(signature["signature"])
  29     :public_key.verify(sigstring, :sha256, sig, public_key)
  30   end
  31
  32   def validate_conn(conn) do
  33     # TODO: How to get the right key and see if it is actually valid for that request.
  34     # For now, fetch the key for the actor.
  35     with actor_id <- Utils.get_ap_id(conn.params["actor"]),
  36          {:ok, public_key} <- User.get_public_key_for_ap_id(actor_id) do
  37       if validate_conn(conn, public_key) do
  38         true
  39       else
  40         Logger.debug("Could not validate, re-fetching user and trying one more time")
  41         # Fetch user anew and try one more time
  42         with actor_id <- Utils.get_ap_id(conn.params["actor"]),
  43              {:ok, _user} <- ActivityPub.make_user_from_ap_id(actor_id),
  44              {:ok, public_key} <- User.get_public_key_for_ap_id(actor_id) do
  45           validate_conn(conn, public_key)
  46         end
  47       end
  48     else
  49       _e ->
  50         Logger.debug("Could not public key!")
  51         false
  52     end
  53   end
  54
  55   def validate_conn(conn, public_key) do
  56     headers = Enum.into(conn.req_headers, %{})
  57     signature = split_signature(headers["signature"])
  58     validate(headers, signature, public_key)
  59   end
  60
  61   def build_signing_string(headers, used_headers) do
  62     used_headers
  63     |> Enum.map(fn header -> "#{header}: #{headers[header]}" end)
  64     |> Enum.join("\n")
  65   end
  66
  67   def sign(user, headers) do
  68     with {:ok, %{info: %{"keys" => keys}}} <- Pleroma.Web.WebFinger.ensure_keys_present(user),
  69          {:ok, private_key, _} = Pleroma.Web.Salmon.keys_from_pem(keys) do
  70       sigstring = build_signing_string(headers, Map.keys(headers))
  71
  72       signature =
  73         :public_key.sign(sigstring, :sha256, private_key)
  74         |> Base.encode64()
  75
  76       [
  77         keyId: user.ap_id <> "#main-key",
  78         algorithm: "rsa-sha256",
  79         headers: Map.keys(headers) |> Enum.join(" "),
  80         signature: signature
  81       ]
  82       |> Enum.map(fn {k, v} -> "#{k}=\"#{v}\"" end)
  83       |> Enum.join(",")
  84     end
  85   end
  86 end