git.squeep.com Git - akkoma/blob - lib/pleroma/web/http_signatures/http_signatures.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 # https://tools.ietf.org/html/draft-cavage-http-signatures-08
   6 defmodule Pleroma.Web.HTTPSignatures do
   7   alias Pleroma.User
   8   alias Pleroma.Web.ActivityPub.Utils
   9   alias Pleroma.Web.ActivityPub.ActivityPub
  10   require Logger
  11
  12   def split_signature(sig) do
  13     default = %{"headers" => "date"}
  14
  15     sig =
  16       sig
  17       |> String.trim()
  18       |> String.split(",")
  19       |> Enum.reduce(default, fn part, acc ->
  20         [key | rest] = String.split(part, "=")
  21         value = Enum.join(rest, "=")
  22         Map.put(acc, key, String.trim(value, "\""))
  23       end)
  24
  25     Map.put(sig, "headers", String.split(sig["headers"], ~r/\s/))
  26   end
  27
  28   def validate(headers, signature, public_key) do
  29     sigstring = build_signing_string(headers, signature["headers"])
  30     Logger.debug("Signature: #{signature["signature"]}")
  31     Logger.debug("Sigstring: #{sigstring}")
  32     {:ok, sig} = Base.decode64(signature["signature"])
  33     :public_key.verify(sigstring, :sha256, sig, public_key)
  34   end
  35
  36   def validate_conn(conn) do
  37     # TODO: How to get the right key and see if it is actually valid for that request.
  38     # For now, fetch the key for the actor.
  39     with actor_id <- Utils.get_ap_id(conn.params["actor"]),
  40          {:ok, public_key} <- User.get_public_key_for_ap_id(actor_id) do
  41       if validate_conn(conn, public_key) do
  42         true
  43       else
  44         Logger.debug("Could not validate, re-fetching user and trying one more time")
  45         # Fetch user anew and try one more time
  46         with actor_id <- Utils.get_ap_id(conn.params["actor"]),
  47              {:ok, _user} <- ActivityPub.make_user_from_ap_id(actor_id),
  48              {:ok, public_key} <- User.get_public_key_for_ap_id(actor_id) do
  49           validate_conn(conn, public_key)
  50         end
  51       end
  52     else
  53       _e ->
  54         Logger.debug("Could not public key!")
  55         false
  56     end
  57   end
  58
  59   def validate_conn(conn, public_key) do
  60     headers = Enum.into(conn.req_headers, %{})
  61     signature = split_signature(headers["signature"])
  62     validate(headers, signature, public_key)
  63   end
  64
  65   def build_signing_string(headers, used_headers) do
  66     used_headers
  67     |> Enum.map(fn header -> "#{header}: #{headers[header]}" end)
  68     |> Enum.join("\n")
  69   end
  70
  71   def sign(user, headers) do
  72     with {:ok, %{info: %{keys: keys}}} <- Pleroma.Web.WebFinger.ensure_keys_present(user),
  73          {:ok, private_key, _} = Pleroma.Web.Salmon.keys_from_pem(keys) do
  74       sigstring = build_signing_string(headers, Map.keys(headers))
  75
  76       signature =
  77         :public_key.sign(sigstring, :sha256, private_key)
  78         |> Base.encode64()
  79
  80       [
  81         keyId: user.ap_id <> "#main-key",
  82         algorithm: "rsa-sha256",
  83         headers: Map.keys(headers) |> Enum.join(" "),
  84         signature: signature
  85       ]
  86       |> Enum.map(fn {k, v} -> "#{k}=\"#{v}\"" end)
  87       |> Enum.join(",")
  88     end
  89   end
  90 end