git.squeep.com Git - akkoma/blob - lib/pleroma/web/feed/user_controller.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.Feed.UserController do
   6   use Pleroma.Web, :controller
   7
   8   alias Fallback.RedirectController
   9   alias Pleroma.User
  10   alias Pleroma.Web.ActivityPub.ActivityPub
  11   alias Pleroma.Web.ActivityPub.ActivityPubController
  12   alias Pleroma.Web.Feed.FeedView
  13
  14   plug(Pleroma.Plugs.SetFormatPlug when action in [:feed_redirect])
  15
  16   action_fallback(:errors)
  17
  18   def feed_redirect(%{assigns: %{format: "html"}} = conn, %{"nickname" => nickname}) do
  19     with {_, %User{} = user} <- {:fetch_user, User.get_cached_by_nickname_or_id(nickname)} do
  20       RedirectController.redirector_with_meta(conn, %{user: user})
  21     end
  22   end
  23
  24   def feed_redirect(%{assigns: %{format: format}} = conn, _params)
  25       when format in ["json", "activity+json"] do
  26     ActivityPubController.call(conn, :user)
  27   end
  28
  29   def feed_redirect(conn, %{"nickname" => nickname}) do
  30     with {_, %User{} = user} <- {:fetch_user, User.get_cached_by_nickname(nickname)} do
  31       redirect(conn, external: "#{user_feed_url(conn, :feed, user.nickname)}.atom")
  32     end
  33   end
  34
  35   def feed(conn, %{"nickname" => nickname} = params) do
  36     with {_, %User{} = user} <- {:fetch_user, User.get_cached_by_nickname(nickname)} do
  37       activities =
  38         %{
  39           "type" => ["Create"],
  40           "whole_db" => true,
  41           "actor_id" => user.ap_id
  42         }
  43         |> Map.merge(Map.take(params, ["max_id"]))
  44         |> ActivityPub.fetch_public_activities()
  45
  46       conn
  47       |> put_resp_content_type("application/atom+xml")
  48       |> put_view(FeedView)
  49       |> render("user.xml",
  50         user: user,
  51         activities: activities,
  52         feed_config: Pleroma.Config.get([:feed])
  53       )
  54     end
  55   end
  56
  57   def errors(conn, {:error, :not_found}) do
  58     render_error(conn, :not_found, "Not found")
  59   end
  60
  61   def errors(conn, {:fetch_user, nil}), do: errors(conn, {:error, :not_found})
  62
  63   def errors(conn, _) do
  64     render_error(conn, :internal_server_error, "Something went wrong")
  65   end
  66 end