git.squeep.com Git - akkoma/blob - lib/pleroma/web/feed/user_controller.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.Feed.UserController do
   6   use Pleroma.Web, :controller
   7
   8   alias Fallback.RedirectController
   9   alias Pleroma.User
  10   alias Pleroma.Web.ActivityPub.ActivityPub
  11   alias Pleroma.Web.ActivityPub.ActivityPubController
  12   alias Pleroma.Web.Feed.FeedView
  13
  14   plug(Pleroma.Plugs.SetFormatPlug when action in [:feed_redirect])
  15
  16   action_fallback(:errors)
  17
  18   def feed_redirect(%{assigns: %{format: "html"}} = conn, %{"nickname" => nickname}) do
  19     with {_, %User{} = user} <- {:fetch_user, User.get_cached_by_nickname_or_id(nickname)} do
  20       RedirectController.redirector_with_meta(conn, %{user: user})
  21     end
  22   end
  23
  24   def feed_redirect(%{assigns: %{format: format}} = conn, _params)
  25       when format in ["json", "activity+json"] do
  26     with %{halted: false} = conn <-
  27            Pleroma.Plugs.EnsureAuthenticatedPlug.call(conn,
  28              unless_func: &Pleroma.Web.FederatingPlug.federating?/1
  29            ) do
  30       ActivityPubController.call(conn, :user)
  31     end
  32   end
  33
  34   def feed_redirect(conn, %{"nickname" => nickname}) do
  35     with {_, %User{} = user} <- {:fetch_user, User.get_cached_by_nickname(nickname)} do
  36       redirect(conn, external: "#{user_feed_url(conn, :feed, user.nickname)}.atom")
  37     end
  38   end
  39
  40   def feed(conn, %{"nickname" => nickname} = params) do
  41     format = get_format(conn)
  42
  43     format =
  44       if format in ["rss", "atom"] do
  45         format
  46       else
  47         "atom"
  48       end
  49
  50     with {_, %User{} = user} <- {:fetch_user, User.get_cached_by_nickname(nickname)} do
  51       activities =
  52         %{
  53           type: ["Create"],
  54           actor_id: user.ap_id
  55         }
  56         |> Pleroma.Maps.put_if_present(:max_id, params["max_id"])
  57         |> ActivityPub.fetch_public_or_unlisted_activities()
  58
  59       conn
  60       |> put_resp_content_type("application/#{format}+xml")
  61       |> put_view(FeedView)
  62       |> render("user.#{format}",
  63         user: user,
  64         activities: activities,
  65         feed_config: Pleroma.Config.get([:feed])
  66       )
  67     end
  68   end
  69
  70   def errors(conn, {:error, :not_found}) do
  71     render_error(conn, :not_found, "Not found")
  72   end
  73
  74   def errors(conn, {:fetch_user, nil}), do: errors(conn, {:error, :not_found})
  75
  76   def errors(conn, _) do
  77     render_error(conn, :internal_server_error, "Something went wrong")
  78   end
  79 end