git.squeep.com Git - akkoma/blob - lib/pleroma/web/feed/user_controller.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.Feed.UserController do
   6   use Pleroma.Web, :controller
   7
   8   alias Pleroma.User
   9   alias Pleroma.Web.ActivityPub.ActivityPub
  10   alias Pleroma.Web.ActivityPub.ActivityPubController
  11   alias Pleroma.Web.Feed.FeedView
  12
  13   plug(Pleroma.Web.Plugs.SetFormatPlug when action in [:feed_redirect])
  14
  15   action_fallback(:errors)
  16
  17   def feed_redirect(%{assigns: %{format: "html"}} = conn, %{"nickname" => nickname}) do
  18     with {_, %User{} = user} <- {:fetch_user, User.get_cached_by_nickname_or_id(nickname)} do
  19       Pleroma.Web.Fallback.RedirectController.redirector_with_meta(conn, %{user: user})
  20     end
  21   end
  22
  23   def feed_redirect(%{assigns: %{format: format}} = conn, _params)
  24       when format in ["json", "activity+json"] do
  25     ActivityPubController.call(conn, :user)
  26   end
  27
  28   def feed_redirect(conn, %{"nickname" => nickname}) do
  29     with {_, %User{} = user} <- {:fetch_user, User.get_cached_by_nickname(nickname)} do
  30       redirect(conn, external: "#{user_feed_url(conn, :feed, user.nickname)}.atom")
  31     end
  32   end
  33
  34   def feed(conn, %{"nickname" => nickname} = params) do
  35     format = get_format(conn)
  36
  37     format =
  38       if format in ["atom", "rss"] do
  39         format
  40       else
  41         "atom"
  42       end
  43
  44     with {_, %User{local: true} = user} <- {:fetch_user, User.get_cached_by_nickname(nickname)},
  45          {_, :visible} <- {:visibility, User.visible_for(user, _reading_user = nil)} do
  46       activities =
  47         %{
  48           type: ["Create"],
  49           actor_id: user.ap_id
  50         }
  51         |> Pleroma.Maps.put_if_present(:max_id, params["max_id"])
  52         |> ActivityPub.fetch_public_or_unlisted_activities()
  53
  54       conn
  55       |> put_resp_content_type("application/#{format}+xml")
  56       |> put_view(FeedView)
  57       |> render("user.#{format}",
  58         user: user,
  59         activities: activities,
  60         feed_config: Config.get([:feed])
  61       )
  62     end
  63   end
  64
  65   def errors(conn, {:error, :not_found}) do
  66     render_error(conn, :not_found, "Not found")
  67   end
  68
  69   def errors(conn, {:fetch_user, %User{local: false}}), do: errors(conn, {:error, :not_found})
  70   def errors(conn, {:fetch_user, nil}), do: errors(conn, {:error, :not_found})
  71
  72   def errors(conn, {:visibility, _}), do: errors(conn, {:error, :not_found})
  73
  74   def errors(conn, _) do
  75     render_error(conn, :internal_server_error, "Something went wrong")
  76   end
  77 end