git.squeep.com Git - akkoma/blob - lib/pleroma/web/feed/user_controller.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.Feed.UserController do
   6   use Pleroma.Web, :controller
   7
   8   alias Fallback.RedirectController
   9   alias Pleroma.User
  10   alias Pleroma.Web.ActivityPub.ActivityPub
  11   alias Pleroma.Web.ActivityPub.ActivityPubController
  12   alias Pleroma.Web.Feed.FeedView
  13
  14   plug(Pleroma.Plugs.SetFormatPlug when action in [:feed_redirect])
  15
  16   action_fallback(:errors)
  17
  18   def feed_redirect(%{assigns: %{format: "html"}} = conn, %{"nickname" => nickname}) do
  19     with {_, %User{} = user} <- {:fetch_user, User.get_cached_by_nickname_or_id(nickname)} do
  20       RedirectController.redirector_with_meta(conn, %{user: user})
  21     end
  22   end
  23
  24   def feed_redirect(%{assigns: %{format: format}} = conn, _params)
  25       when format in ["json", "activity+json"] do
  26     with %{halted: false} = conn <-
  27            Pleroma.Plugs.EnsureAuthenticatedPlug.call(conn,
  28              unless_func: &Pleroma.Web.FederatingPlug.federating?/1
  29            ) do
  30       ActivityPubController.call(conn, :user)
  31     end
  32   end
  33
  34   def feed_redirect(conn, %{"nickname" => nickname}) do
  35     with {_, %User{} = user} <- {:fetch_user, User.get_cached_by_nickname(nickname)} do
  36       redirect(conn, external: "#{user_feed_url(conn, :feed, user.nickname)}.atom")
  37     end
  38   end
  39
  40   def feed(conn, params) do
  41     unless Pleroma.Config.restrict_unauthenticated_access?(:profiles, :local) do
  42       render_feed(conn, params)
  43     else
  44       errors(conn, {:error, :not_found})
  45     end
  46   end
  47
  48   def render_feed(conn, %{"nickname" => nickname} = params) do
  49     format = get_format(conn)
  50
  51     format =
  52       if format in ["rss", "atom"] do
  53         format
  54       else
  55         "atom"
  56       end
  57
  58     with {_, %User{local: true} = user} <- {:fetch_user, User.get_cached_by_nickname(nickname)} do
  59       activities =
  60         %{
  61           type: ["Create"],
  62           actor_id: user.ap_id
  63         }
  64         |> Pleroma.Maps.put_if_present(:max_id, params["max_id"])
  65         |> ActivityPub.fetch_public_or_unlisted_activities()
  66
  67       conn
  68       |> put_resp_content_type("application/#{format}+xml")
  69       |> put_view(FeedView)
  70       |> render("user.#{format}",
  71         user: user,
  72         activities: activities,
  73         feed_config: Pleroma.Config.get([:feed])
  74       )
  75     end
  76   end
  77
  78   def errors(conn, {:error, :not_found}) do
  79     render_error(conn, :not_found, "Not found")
  80   end
  81
  82   def errors(conn, {:fetch_user, %User{local: false}}), do: errors(conn, {:error, :not_found})
  83   def errors(conn, {:fetch_user, nil}), do: errors(conn, {:error, :not_found})
  84
  85   def errors(conn, _) do
  86     render_error(conn, :internal_server_error, "Something went wrong")
  87   end
  88 end