git.squeep.com Git - akkoma/blob - lib/pleroma/web/feed/user_controller.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.Feed.UserController do
   6   use Pleroma.Web, :controller
   7
   8   alias Fallback.RedirectController
   9   alias Pleroma.User
  10   alias Pleroma.Web.ActivityPub.ActivityPub
  11   alias Pleroma.Web.ActivityPub.ActivityPubController
  12   alias Pleroma.Web.Feed.FeedView
  13
  14   import Pleroma.Web.ControllerHelper, only: [put_if_exist: 3]
  15
  16   plug(Pleroma.Plugs.SetFormatPlug when action in [:feed_redirect])
  17
  18   action_fallback(:errors)
  19
  20   def feed_redirect(%{assigns: %{format: "html"}} = conn, %{"nickname" => nickname}) do
  21     with {_, %User{} = user} <- {:fetch_user, User.get_cached_by_nickname_or_id(nickname)} do
  22       RedirectController.redirector_with_meta(conn, %{user: user})
  23     end
  24   end
  25
  26   def feed_redirect(%{assigns: %{format: format}} = conn, _params)
  27       when format in ["json", "activity+json"] do
  28     with %{halted: false} = conn <-
  29            Pleroma.Plugs.EnsureAuthenticatedPlug.call(conn,
  30              unless_func: &Pleroma.Web.FederatingPlug.federating?/1
  31            ) do
  32       ActivityPubController.call(conn, :user)
  33     end
  34   end
  35
  36   def feed_redirect(conn, %{"nickname" => nickname}) do
  37     with {_, %User{} = user} <- {:fetch_user, User.get_cached_by_nickname(nickname)} do
  38       redirect(conn, external: "#{user_feed_url(conn, :feed, user.nickname)}.atom")
  39     end
  40   end
  41
  42   def feed(conn, %{"nickname" => nickname} = params) do
  43     format = get_format(conn)
  44
  45     format =
  46       if format in ["rss", "atom"] do
  47         format
  48       else
  49         "atom"
  50       end
  51
  52     with {_, %User{} = user} <- {:fetch_user, User.get_cached_by_nickname(nickname)} do
  53       activities =
  54         %{
  55           "type" => ["Create"],
  56           "actor_id" => user.ap_id
  57         }
  58         |> put_if_exist("max_id", params["max_id"])
  59         |> ActivityPub.fetch_public_activities()
  60
  61       conn
  62       |> put_resp_content_type("application/#{format}+xml")
  63       |> put_view(FeedView)
  64       |> render("user.#{format}",
  65         user: user,
  66         activities: activities,
  67         feed_config: Pleroma.Config.get([:feed])
  68       )
  69     end
  70   end
  71
  72   def errors(conn, {:error, :not_found}) do
  73     render_error(conn, :not_found, "Not found")
  74   end
  75
  76   def errors(conn, {:fetch_user, nil}), do: errors(conn, {:error, :not_found})
  77
  78   def errors(conn, _) do
  79     render_error(conn, :internal_server_error, "Something went wrong")
  80   end
  81 end