git.squeep.com Git - akkoma/blob - lib/pleroma/web/federator/retry_queue.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.Federator.RetryQueue do
   6   use GenServer
   7
   8   require Logger
   9
  10   def init(args) do
  11     queue_table = :ets.new(:pleroma_retry_queue, [:bag, :protected])
  12
  13     {:ok, %{args | queue_table: queue_table, running_jobs: :sets.new()}}
  14   end
  15
  16   def start_link() do
  17     enabled =
  18       if Mix.env() == :test, do: true, else: Pleroma.Config.get([__MODULE__, :enabled], false)
  19
  20     if enabled do
  21       Logger.info("Starting retry queue")
  22
  23       linkres =
  24         GenServer.start_link(
  25           __MODULE__,
  26           %{delivered: 0, dropped: 0, queue_table: nil, running_jobs: nil},
  27           name: __MODULE__
  28         )
  29
  30       maybe_kickoff_timer()
  31       linkres
  32     else
  33       Logger.info("Retry queue disabled")
  34       :ignore
  35     end
  36   end
  37
  38   def enqueue(data, transport, retries \\ 0) do
  39     GenServer.cast(__MODULE__, {:maybe_enqueue, data, transport, retries + 1})
  40   end
  41
  42   def get_stats() do
  43     GenServer.call(__MODULE__, :get_stats)
  44   end
  45
  46   def reset_stats() do
  47     GenServer.call(__MODULE__, :reset_stats)
  48   end
  49
  50   def get_retry_params(retries) do
  51     if retries > Pleroma.Config.get([__MODULE__, :max_retries]) do
  52       {:drop, "Max retries reached"}
  53     else
  54       {:retry, growth_function(retries)}
  55     end
  56   end
  57
  58   def get_retry_timer_interval() do
  59     Pleroma.Config.get([:retry_queue, :interval], 1000)
  60   end
  61
  62   defp ets_count_expires(table, current_time) do
  63     :ets.select_count(
  64       table,
  65       [
  66         {
  67           {:"$1", :"$2"},
  68           [{:"=<", :"$1", {:const, current_time}}],
  69           [true]
  70         }
  71       ]
  72     )
  73   end
  74
  75   defp ets_pop_n_expired(table, current_time, desired) do
  76     {popped, _continuation} =
  77       :ets.select(
  78         table,
  79         [
  80           {
  81             {:"$1", :"$2"},
  82             [{:"=<", :"$1", {:const, current_time}}],
  83             [:"$_"]
  84           }
  85         ],
  86         desired
  87       )
  88
  89     popped
  90     |> Enum.each(fn e ->
  91       :ets.delete_object(table, e)
  92     end)
  93
  94     popped
  95   end
  96
  97   def maybe_start_job(running_jobs, queue_table) do
  98     # we don't want to hit the ets or the DateTime more times than we have to
  99     # could optimize slightly further by not using the count, and instead grabbing
 100     # up to N objects early...
 101     current_time = DateTime.to_unix(DateTime.utc_now())
 102     n_running_jobs = :sets.size(running_jobs)
 103
 104     if n_running_jobs < Pleroma.Config.get([__MODULE__, :max_jobs]) do
 105       n_ready_jobs = ets_count_expires(queue_table, current_time)
 106
 107       if n_ready_jobs > 0 do
 108         # figure out how many we could start
 109         available_job_slots = Pleroma.Config.get([__MODULE__, :max_jobs]) - n_running_jobs
 110         start_n_jobs(running_jobs, queue_table, current_time, available_job_slots)
 111       else
 112         running_jobs
 113       end
 114     else
 115       running_jobs
 116     end
 117   end
 118
 119   defp start_n_jobs(running_jobs, _queue_table, _current_time, 0) do
 120     running_jobs
 121   end
 122
 123   defp start_n_jobs(running_jobs, queue_table, current_time, available_job_slots)
 124        when available_job_slots > 0 do
 125     candidates = ets_pop_n_expired(queue_table, current_time, available_job_slots)
 126
 127     candidates
 128     |> List.foldl(running_jobs, fn {_, e}, rj ->
 129       {:ok, pid} = Task.start(fn -> worker(e) end)
 130       mref = Process.monitor(pid)
 131       :sets.add_element(mref, rj)
 132     end)
 133   end
 134
 135   def worker({:send, data, transport, retries}) do
 136     case transport.publish_one(data) do
 137       {:ok, _} ->
 138         GenServer.cast(__MODULE__, :inc_delivered)
 139         :delivered
 140
 141       {:error, _reason} ->
 142         enqueue(data, transport, retries)
 143         :retry
 144     end
 145   end
 146
 147   def handle_call(:get_stats, _from, %{delivered: delivery_count, dropped: drop_count} = state) do
 148     {:reply, %{delivered: delivery_count, dropped: drop_count}, state}
 149   end
 150
 151   def handle_call(:reset_stats, _from, %{delivered: delivery_count, dropped: drop_count} = state) do
 152     {:reply, %{delivered: delivery_count, dropped: drop_count},
 153      %{state | delivered: 0, dropped: 0}}
 154   end
 155
 156   def handle_cast(:reset_stats, state) do
 157     {:noreply, %{state | delivered: 0, dropped: 0}}
 158   end
 159
 160   def handle_cast(
 161         {:maybe_enqueue, data, transport, retries},
 162         %{dropped: drop_count, queue_table: queue_table, running_jobs: running_jobs} = state
 163       ) do
 164     case get_retry_params(retries) do
 165       {:retry, timeout} ->
 166         :ets.insert(queue_table, {timeout, {:send, data, transport, retries}})
 167         running_jobs = maybe_start_job(running_jobs, queue_table)
 168         {:noreply, %{state | running_jobs: running_jobs}}
 169
 170       {:drop, message} ->
 171         Logger.debug(message)
 172         {:noreply, %{state | dropped: drop_count + 1}}
 173     end
 174   end
 175
 176   def handle_cast(:kickoff_timer, state) do
 177     retry_interval = get_retry_timer_interval()
 178     Process.send_after(__MODULE__, :retry_timer_run, retry_interval)
 179     {:noreply, state}
 180   end
 181
 182   def handle_cast(:inc_delivered, %{delivered: delivery_count} = state) do
 183     {:noreply, %{state | delivered: delivery_count + 1}}
 184   end
 185
 186   def handle_cast(:inc_dropped, %{dropped: drop_count} = state) do
 187     {:noreply, %{state | dropped: drop_count + 1}}
 188   end
 189
 190   def handle_info({:send, data, transport, retries}, %{delivered: delivery_count} = state) do
 191     case transport.publish_one(data) do
 192       {:ok, _} ->
 193         {:noreply, %{state | delivered: delivery_count + 1}}
 194
 195       {:error, _reason} ->
 196         enqueue(data, transport, retries)
 197         {:noreply, state}
 198     end
 199   end
 200
 201   def handle_info(
 202         :retry_timer_run,
 203         %{queue_table: queue_table, running_jobs: running_jobs} = state
 204       ) do
 205     maybe_kickoff_timer()
 206     running_jobs = maybe_start_job(running_jobs, queue_table)
 207     {:noreply, %{state | running_jobs: running_jobs}}
 208   end
 209
 210   def handle_info({:DOWN, ref, :process, _pid, _reason}, state) do
 211     %{running_jobs: running_jobs, queue_table: queue_table} = state
 212     running_jobs = :sets.del_element(ref, running_jobs)
 213     running_jobs = maybe_start_job(running_jobs, queue_table)
 214     {:noreply, %{state | running_jobs: running_jobs}}
 215   end
 216
 217   def handle_info(unknown, state) do
 218     Logger.debug("RetryQueue: don't know what to do with #{inspect(unknown)}, ignoring")
 219     {:noreply, state}
 220   end
 221
 222   if Mix.env() == :test do
 223     defp growth_function(_retries) do
 224       _shutit = Pleroma.Config.get([__MODULE__, :initial_timeout])
 225       DateTime.to_unix(DateTime.utc_now()) - 1
 226     end
 227   else
 228     defp growth_function(retries) do
 229       round(Pleroma.Config.get([__MODULE__, :initial_timeout]) * :math.pow(retries, 3)) +
 230         DateTime.to_unix(DateTime.utc_now())
 231     end
 232   end
 233
 234   defp maybe_kickoff_timer() do
 235     GenServer.cast(__MODULE__, :kickoff_timer)
 236   end
 237 end