git.squeep.com Git - akkoma/blob - lib/pleroma/web/federator/federator.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.Federator do
   6   alias Pleroma.User
   7   alias Pleroma.Activity
   8   alias Pleroma.Jobs
   9   alias Pleroma.Web.{WebFinger, Websub}
  10   alias Pleroma.Web.Federator.RetryQueue
  11   alias Pleroma.Web.ActivityPub.ActivityPub
  12   alias Pleroma.Web.ActivityPub.Relay
  13   alias Pleroma.Web.ActivityPub.Transmogrifier
  14   alias Pleroma.Web.ActivityPub.Utils
  15   alias Pleroma.Web.OStatus
  16   require Logger
  17
  18   @websub Application.get_env(:pleroma, :websub)
  19   @ostatus Application.get_env(:pleroma, :ostatus)
  20
  21   def init() do
  22     # 1 minute
  23     Process.sleep(1000 * 60 * 1)
  24     refresh_subscriptions()
  25   end
  26
  27   # Client API
  28
  29   def incoming_doc(doc) do
  30     Jobs.enqueue(:federator_incoming, __MODULE__, [:incoming_doc, doc])
  31   end
  32
  33   def incoming_ap_doc(params) do
  34     Jobs.enqueue(:federator_incoming, __MODULE__, [:incoming_ap_doc, params])
  35   end
  36
  37   def publish(activity, priority \\ 1) do
  38     Jobs.enqueue(:federator_out, __MODULE__, [:publish, activity], priority)
  39   end
  40
  41   def publish_single_ap(params) do
  42     Jobs.enqueue(:federator_out, __MODULE__, [:publish_single_ap, params])
  43   end
  44
  45   def publish_single_websub(websub) do
  46     Jobs.enqueue(:federator_out, __MODULE__, [:publish_single_websub, websub])
  47   end
  48
  49   def verify_websub(websub) do
  50     Jobs.enqueue(:federator_out, __MODULE__, [:verify_websub, websub])
  51   end
  52
  53   def request_subscription(sub) do
  54     Jobs.enqueue(:federator_out, __MODULE__, [:request_subscription, sub])
  55   end
  56
  57   def refresh_subscriptions() do
  58     Jobs.enqueue(:federator_out, __MODULE__, [:refresh_subscriptions])
  59   end
  60
  61   # Job Worker Callbacks
  62
  63   def perform(:refresh_subscriptions) do
  64     Logger.debug("Federator running refresh subscriptions")
  65     Websub.refresh_subscriptions()
  66
  67     spawn(fn ->
  68       # 6 hours
  69       Process.sleep(1000 * 60 * 60 * 6)
  70       refresh_subscriptions()
  71     end)
  72   end
  73
  74   def perform(:request_subscription, websub) do
  75     Logger.debug("Refreshing #{websub.topic}")
  76
  77     with {:ok, websub} <- Websub.request_subscription(websub) do
  78       Logger.debug("Successfully refreshed #{websub.topic}")
  79     else
  80       _e -> Logger.debug("Couldn't refresh #{websub.topic}")
  81     end
  82   end
  83
  84   def perform(:publish, activity) do
  85     Logger.debug(fn -> "Running publish for #{activity.data["id"]}" end)
  86
  87     with actor when not is_nil(actor) <- User.get_cached_by_ap_id(activity.data["actor"]) do
  88       {:ok, actor} = WebFinger.ensure_keys_present(actor)
  89
  90       if ActivityPub.is_public?(activity) do
  91         if OStatus.is_representable?(activity) do
  92           Logger.info(fn -> "Sending #{activity.data["id"]} out via WebSub" end)
  93           Websub.publish(Pleroma.Web.OStatus.feed_path(actor), actor, activity)
  94
  95           Logger.info(fn -> "Sending #{activity.data["id"]} out via Salmon" end)
  96           Pleroma.Web.Salmon.publish(actor, activity)
  97         end
  98
  99         if Keyword.get(Application.get_env(:pleroma, :instance), :allow_relay) do
 100           Logger.info(fn -> "Relaying #{activity.data["id"]} out" end)
 101           Relay.publish(activity)
 102         end
 103       end
 104
 105       Logger.info(fn -> "Sending #{activity.data["id"]} out via AP" end)
 106       Pleroma.Web.ActivityPub.ActivityPub.publish(actor, activity)
 107     end
 108   end
 109
 110   def perform(:verify_websub, websub) do
 111     Logger.debug(fn ->
 112       "Running WebSub verification for #{websub.id} (#{websub.topic}, #{websub.callback})"
 113     end)
 114
 115     @websub.verify(websub)
 116   end
 117
 118   def perform(:incoming_doc, doc) do
 119     Logger.info("Got document, trying to parse")
 120     @ostatus.handle_incoming(doc)
 121   end
 122
 123   def perform(:incoming_ap_doc, params) do
 124     Logger.info("Handling incoming AP activity")
 125
 126     params = Utils.normalize_params(params)
 127
 128     # NOTE: we use the actor ID to do the containment, this is fine because an
 129     # actor shouldn't be acting on objects outside their own AP server.
 130     with {:ok, _user} <- ap_enabled_actor(params["actor"]),
 131          nil <- Activity.normalize(params["id"]),
 132          :ok <- Transmogrifier.contain_origin_from_id(params["actor"], params),
 133          {:ok, activity} <- Transmogrifier.handle_incoming(params) do
 134       {:ok, activity}
 135     else
 136       %Activity{} ->
 137         Logger.info("Already had #{params["id"]}")
 138         :error
 139
 140       _e ->
 141         # Just drop those for now
 142         Logger.info("Unhandled activity")
 143         Logger.info(Poison.encode!(params, pretty: 2))
 144         :error
 145     end
 146   end
 147
 148   def perform(:publish_single_ap, params) do
 149     case ActivityPub.publish_one(params) do
 150       {:ok, _} ->
 151         :ok
 152
 153       {:error, _} ->
 154         RetryQueue.enqueue(params, ActivityPub)
 155     end
 156   end
 157
 158   def perform(
 159         :publish_single_websub,
 160         %{xml: _xml, topic: _topic, callback: _callback, secret: _secret} = params
 161       ) do
 162     case Websub.publish_one(params) do
 163       {:ok, _} ->
 164         :ok
 165
 166       {:error, _} ->
 167         RetryQueue.enqueue(params, Websub)
 168     end
 169   end
 170
 171   def perform(type, _) do
 172     Logger.debug(fn -> "Unknown task: #{type}" end)
 173     {:error, "Don't know what to do with this"}
 174   end
 175
 176   def ap_enabled_actor(id) do
 177     user = User.get_by_ap_id(id)
 178
 179     if User.ap_enabled?(user) do
 180       {:ok, user}
 181     else
 182       ActivityPub.make_user_from_ap_id(id)
 183     end
 184   end
 185 end