git.squeep.com Git - akkoma/blob - lib/pleroma/web/federator/federator.ex

   1 defmodule Pleroma.Web.Federator do
   2   use GenServer
   3   alias Pleroma.User
   4   alias Pleroma.Web.{WebFinger, Websub}
   5   require Logger
   6
   7   @websub Application.get_env(:pleroma, :websub)
   8   @ostatus Application.get_env(:pleroma, :ostatus)
   9   @httpoison Application.get_env(:pleroma, :httpoison)
  10   @max_jobs 10
  11
  12   def start_link do
  13     spawn(fn ->
  14       Process.sleep(1000 * 60 * 1) # 1 minute
  15       enqueue(:refresh_subscriptions, nil)
  16     end)
  17     GenServer.start_link(__MODULE__, {:sets.new(), :queue.new()}, name: __MODULE__)
  18   end
  19
  20   def handle(:refresh_subscriptions, _) do
  21     Logger.debug("Federator running refresh subscriptions")
  22     Websub.refresh_subscriptions()
  23     spawn(fn ->
  24       Process.sleep(1000 * 60 * 60 * 6) # 6 hours
  25       enqueue(:refresh_subscriptions, nil)
  26     end)
  27   end
  28
  29   def handle(:publish, activity) do
  30     Logger.debug(fn -> "Running publish for #{activity.data["id"]}" end)
  31     with actor when not is_nil(actor) <- User.get_cached_by_ap_id(activity.data["actor"]) do
  32       Logger.debug(fn -> "Sending #{activity.data["id"]} out via websub" end)
  33       Websub.publish(Pleroma.Web.OStatus.feed_path(actor), actor, activity)
  34
  35       {:ok, actor} = WebFinger.ensure_keys_present(actor)
  36       Logger.debug(fn -> "Sending #{activity.data["id"]} out via salmon" end)
  37       Pleroma.Web.Salmon.publish(actor, activity)
  38     end
  39   end
  40
  41   def handle(:verify_websub, websub) do
  42     Logger.debug(fn -> "Running websub verification for #{websub.id} (#{websub.topic}, #{websub.callback})" end)
  43     @websub.verify(websub)
  44   end
  45
  46   def handle(:incoming_doc, doc) do
  47     Logger.debug("Got document, trying to parse")
  48     @ostatus.handle_incoming(doc)
  49   end
  50
  51   def handle(:publish_single_websub, %{xml: xml, topic: topic, callback: callback, secret: secret}) do
  52     signature = @websub.sign(secret || "", xml)
  53     Logger.debug(fn -> "Pushing #{topic} to #{callback}" end)
  54
  55     with {:ok, %{status_code: code}} <- @httpoison.post(callback, xml, [
  56                   {"Content-Type", "application/atom+xml"},
  57                   {"X-Hub-Signature", "sha1=#{signature}"}
  58                 ], timeout: 10000, recv_timeout: 20000) do
  59       Logger.debug(fn -> "Pushed to #{callback}, code #{code}" end)
  60     else e ->
  61         Logger.debug(fn -> "Couldn't push to #{callback}, #{inspect(e)}" end)
  62     end
  63   end
  64
  65   def handle(type, payload) do
  66     Logger.debug(fn -> "Unknown task: #{type}" end)
  67     {:error, "Don't know what do do with this"}
  68   end
  69
  70   def enqueue(type, payload) do
  71     if Mix.env == :test do
  72       handle(type, payload)
  73     else
  74       GenServer.cast(__MODULE__, {:enqueue, type, payload})
  75     end
  76   end
  77
  78   def maybe_start_job(running_jobs, queue) do
  79     if (:sets.size(running_jobs) < @max_jobs) && !:queue.is_empty(queue) do
  80       {{:value, {type, payload}}, queue} = :queue.out(queue)
  81       {:ok, pid} = Task.start(fn -> handle(type, payload) end)
  82       mref = Process.monitor(pid)
  83       {:sets.add_element(mref, running_jobs), queue}
  84     else
  85       {running_jobs, queue}
  86     end
  87   end
  88
  89   def handle_cast({:enqueue, type, payload}, {running_jobs, queue}) do
  90     queue = :queue.in({type, payload}, queue)
  91     {running_jobs, queue} = maybe_start_job(running_jobs, queue)
  92     {:noreply, {running_jobs, queue}}
  93   end
  94
  95   def handle_info({:DOWN, ref, :process, _pid, _reason}, {running_jobs, queue}) do
  96     running_jobs = :sets.del_element(ref, running_jobs)
  97     {running_jobs, queue} = maybe_start_job(running_jobs, queue)
  98     {:noreply, {running_jobs, queue}}
  99   end
 100
 101   def handle_cast(m, state) do
 102     IO.inspect("Unknown: #{inspect(m)}, #{inspect(state)}")
 103     {:noreply, state}
 104   end
 105 end