git.squeep.com Git - akkoma/blob - lib/pleroma/web/federator/federator.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.Federator do
   6   alias Pleroma.Activity
   7   alias Pleroma.Object.Containment
   8   alias Pleroma.User
   9   alias Pleroma.Web.ActivityPub.ActivityPub
  10   alias Pleroma.Web.ActivityPub.Transmogrifier
  11   alias Pleroma.Web.ActivityPub.Utils
  12   alias Pleroma.Web.Federator.Publisher
  13   alias Pleroma.Web.Federator.RetryQueue
  14   alias Pleroma.Web.Websub
  15
  16   require Logger
  17
  18   @websub Application.get_env(:pleroma, :websub)
  19   @ostatus Application.get_env(:pleroma, :ostatus)
  20
  21   def init do
  22     # 1 minute
  23     Process.sleep(1000 * 60)
  24     refresh_subscriptions()
  25   end
  26
  27   # Client API
  28
  29   def incoming_doc(doc) do
  30     PleromaJobQueue.enqueue(:federator_incoming, __MODULE__, [:incoming_doc, doc])
  31   end
  32
  33   def incoming_ap_doc(params) do
  34     PleromaJobQueue.enqueue(:federator_incoming, __MODULE__, [:incoming_ap_doc, params])
  35   end
  36
  37   def publish(activity, priority \\ 1) do
  38     PleromaJobQueue.enqueue(:federator_outgoing, __MODULE__, [:publish, activity], priority)
  39   end
  40
  41   def verify_websub(websub) do
  42     PleromaJobQueue.enqueue(:federator_outgoing, __MODULE__, [:verify_websub, websub])
  43   end
  44
  45   def request_subscription(sub) do
  46     PleromaJobQueue.enqueue(:federator_outgoing, __MODULE__, [:request_subscription, sub])
  47   end
  48
  49   def refresh_subscriptions do
  50     PleromaJobQueue.enqueue(:federator_outgoing, __MODULE__, [:refresh_subscriptions])
  51   end
  52
  53   # Job Worker Callbacks
  54
  55   def perform(:refresh_subscriptions) do
  56     Logger.debug("Federator running refresh subscriptions")
  57     Websub.refresh_subscriptions()
  58
  59     spawn(fn ->
  60       # 6 hours
  61       Process.sleep(1000 * 60 * 60 * 6)
  62       refresh_subscriptions()
  63     end)
  64   end
  65
  66   def perform(:request_subscription, websub) do
  67     Logger.debug("Refreshing #{websub.topic}")
  68
  69     with {:ok, websub} <- Websub.request_subscription(websub) do
  70       Logger.debug("Successfully refreshed #{websub.topic}")
  71     else
  72       _e -> Logger.debug("Couldn't refresh #{websub.topic}")
  73     end
  74   end
  75
  76   def perform(:publish, activity) do
  77     Logger.debug(fn -> "Running publish for #{activity.data["id"]}" end)
  78
  79     with %User{} = actor <- User.get_cached_by_ap_id(activity.data["actor"]),
  80          {:ok, actor} <- User.ensure_keys_present(actor) do
  81       Publisher.publish(actor, activity)
  82     end
  83   end
  84
  85   def perform(:verify_websub, websub) do
  86     Logger.debug(fn ->
  87       "Running WebSub verification for #{websub.id} (#{websub.topic}, #{websub.callback})"
  88     end)
  89
  90     @websub.verify(websub)
  91   end
  92
  93   def perform(:incoming_doc, doc) do
  94     Logger.info("Got document, trying to parse")
  95     @ostatus.handle_incoming(doc)
  96   end
  97
  98   def perform(:incoming_ap_doc, params) do
  99     Logger.info("Handling incoming AP activity")
 100
 101     params = Utils.normalize_params(params)
 102
 103     # NOTE: we use the actor ID to do the containment, this is fine because an
 104     # actor shouldn't be acting on objects outside their own AP server.
 105     with {:ok, _user} <- ap_enabled_actor(params["actor"]),
 106          nil <- Activity.normalize(params["id"]),
 107          :ok <- Containment.contain_origin_from_id(params["actor"], params),
 108          {:ok, activity} <- Transmogrifier.handle_incoming(params) do
 109       {:ok, activity}
 110     else
 111       %Activity{} ->
 112         Logger.info("Already had #{params["id"]}")
 113         :error
 114
 115       _e ->
 116         # Just drop those for now
 117         Logger.info("Unhandled activity")
 118         Logger.info(Jason.encode!(params, pretty: true))
 119         :error
 120     end
 121   end
 122
 123   def perform(
 124         :publish_single_websub,
 125         %{xml: _xml, topic: _topic, callback: _callback, secret: _secret} = params
 126       ) do
 127     case Websub.publish_one(params) do
 128       {:ok, _} ->
 129         :ok
 130
 131       {:error, _} ->
 132         RetryQueue.enqueue(params, Websub)
 133     end
 134   end
 135
 136   def perform(type, _) do
 137     Logger.debug(fn -> "Unknown task: #{type}" end)
 138     {:error, "Don't know what to do with this"}
 139   end
 140
 141   def ap_enabled_actor(id) do
 142     user = User.get_cached_by_ap_id(id)
 143
 144     if User.ap_enabled?(user) do
 145       {:ok, user}
 146     else
 147       ActivityPub.make_user_from_ap_id(id)
 148     end
 149   end
 150 end