git.squeep.com Git - akkoma/blob - lib/pleroma/web/fallback_redirect_controller.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Fallback.RedirectController do
   6   use Pleroma.Web, :controller
   7
   8   require Logger
   9
  10   alias Pleroma.User
  11   alias Pleroma.Web.Metadata
  12
  13   def api_not_implemented(conn, _params) do
  14     conn
  15     |> put_status(404)
  16     |> json(%{error: "Not implemented"})
  17   end
  18
  19   def redirector(conn, _params, code \\ 200)
  20
  21   # redirect to admin section
  22   # /pleroma/admin -> /pleroma/admin/
  23   #
  24   def redirector(conn, %{"path" => ["pleroma", "admin"]} = _, _code) do
  25     redirect(conn, to: "/pleroma/admin/")
  26   end
  27
  28   def redirector(conn, _params, code) do
  29     conn
  30     |> put_resp_content_type("text/html")
  31     |> send_file(code, index_file_path())
  32   end
  33
  34   def redirector_with_meta(conn, %{"maybe_nickname_or_id" => maybe_nickname_or_id} = params) do
  35     with %User{} = user <- User.get_cached_by_nickname_or_id(maybe_nickname_or_id) do
  36       redirector_with_meta(conn, %{user: user})
  37     else
  38       nil ->
  39         redirector(conn, params)
  40     end
  41   end
  42
  43   def redirector_with_meta(conn, params) do
  44     {:ok, index_content} = File.read(index_file_path())
  45
  46     tags =
  47       try do
  48         Metadata.build_tags(params)
  49       rescue
  50         e ->
  51           Logger.error(
  52             "Metadata rendering for #{conn.request_path} failed.\n" <>
  53               Exception.format(:error, e, __STACKTRACE__)
  54           )
  55
  56           ""
  57       end
  58
  59     response = String.replace(index_content, "<!--server-generated-meta-->", tags)
  60
  61     conn
  62     |> put_resp_content_type("text/html")
  63     |> send_resp(200, response)
  64   end
  65
  66   def index_file_path do
  67     Pleroma.Plugs.InstanceStatic.file_path("index.html")
  68   end
  69
  70   def registration_page(conn, params) do
  71     redirector(conn, params)
  72   end
  73
  74   def empty(conn, _params) do
  75     conn
  76     |> put_status(204)
  77     |> text("")
  78   end
  79 end