git.squeep.com Git - akkoma/blob - lib/pleroma/web/endpoint.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.Endpoint do
   6   use Phoenix.Endpoint, otp_app: :pleroma
   7
   8   socket("/socket", Pleroma.Web.UserSocket)
   9
  10   plug(Pleroma.Plugs.SetLocalePlug)
  11   plug(CORSPlug)
  12   plug(Pleroma.Plugs.HTTPSecurityPlug)
  13   plug(Pleroma.Plugs.UploadedMedia)
  14
  15   @static_cache_control "public, no-cache"
  16
  17   # InstanceStatic needs to be before Plug.Static to be able to override shipped-static files
  18   # If you're adding new paths to `only:` you'll need to configure them in InstanceStatic as well
  19   # Cache-control headers are duplicated in case we turn off etags in the future
  20   plug(Pleroma.Plugs.InstanceStatic,
  21     at: "/",
  22     gzip: true,
  23     cache_control_for_etags: @static_cache_control,
  24     headers: %{
  25       "cache-control" => @static_cache_control
  26     }
  27   )
  28
  29   # Serve at "/" the static files from "priv/static" directory.
  30   #
  31   # You should set gzip to true if you are running phoenix.digest
  32   # when deploying your static files in production.
  33   plug(
  34     Plug.Static,
  35     at: "/",
  36     from: :pleroma,
  37     only:
  38       ~w(index.html robots.txt static finmoji emoji packs sounds images instance sw.js sw-pleroma.js favicon.png schemas doc),
  39     # credo:disable-for-previous-line Credo.Check.Readability.MaxLineLength
  40     gzip: true,
  41     cache_control_for_etags: @static_cache_control,
  42     headers: %{
  43       "cache-control" => @static_cache_control
  44     }
  45   )
  46
  47   plug(Plug.Static.IndexHtml, at: "/pleroma/admin/")
  48
  49   plug(Plug.Static,
  50     at: "/pleroma/admin/",
  51     from: {:pleroma, "priv/static/adminfe/"}
  52   )
  53
  54   # Code reloading can be explicitly enabled under the
  55   # :code_reloader configuration of your endpoint.
  56   if code_reloading? do
  57     plug(Phoenix.CodeReloader)
  58   end
  59
  60   plug(Pleroma.Plugs.TrailingFormatPlug)
  61   plug(Plug.RequestId)
  62   plug(Plug.Logger)
  63
  64   plug(
  65     Plug.Parsers,
  66     parsers: [:urlencoded, :multipart, :json],
  67     pass: ["*/*"],
  68     json_decoder: Jason,
  69     length: Pleroma.Config.get([:instance, :upload_limit]),
  70     body_reader: {Pleroma.Web.Plugs.DigestPlug, :read_body, []}
  71   )
  72
  73   plug(Plug.MethodOverride)
  74   plug(Plug.Head)
  75
  76   secure_cookies = Pleroma.Config.get([__MODULE__, :secure_cookie_flag])
  77
  78   cookie_name =
  79     if secure_cookies,
  80       do: "__Host-pleroma_key",
  81       else: "pleroma_key"
  82
  83   extra =
  84     Pleroma.Config.get([__MODULE__, :extra_cookie_attrs])
  85     |> Enum.join(";")
  86
  87   # The session will be stored in the cookie and signed,
  88   # this means its contents can be read but not tampered with.
  89   # Set :encryption_salt if you would also like to encrypt it.
  90   plug(
  91     Plug.Session,
  92     store: :cookie,
  93     key: cookie_name,
  94     signing_salt: Pleroma.Config.get([__MODULE__, :signing_salt], "CqaoopA2"),
  95     http_only: true,
  96     secure: secure_cookies,
  97     extra: extra
  98   )
  99
 100   plug(Pleroma.Plugs.RemoteIp)
 101
 102   defmodule Instrumenter do
 103     use Prometheus.PhoenixInstrumenter
 104   end
 105
 106   defmodule PipelineInstrumenter do
 107     use Prometheus.PlugPipelineInstrumenter
 108   end
 109
 110   defmodule MetricsExporter do
 111     use Prometheus.PlugExporter
 112   end
 113
 114   plug(PipelineInstrumenter)
 115   plug(MetricsExporter)
 116
 117   plug(Pleroma.Web.Router)
 118
 119   @doc """
 120   Dynamically loads configuration from the system environment
 121   on startup.
 122
 123   It receives the endpoint configuration from the config files
 124   and must return the updated configuration.
 125   """
 126   def load_from_system_env(config) do
 127     port = System.get_env("PORT") || raise "expected the PORT environment variable to be set"
 128     {:ok, Keyword.put(config, :http, [:inet6, port: port])}
 129   end
 130
 131   def websocket_url do
 132     String.replace_leading(url(), "http", "ws")
 133   end
 134 end