git.squeep.com Git - akkoma/blob - lib/pleroma/web/controller_helper.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ControllerHelper do
   6   use Pleroma.Web, :controller
   7
   8   # As in MastoAPI, per https://api.rubyonrails.org/classes/ActiveModel/Type/Boolean.html
   9   @falsy_param_values [false, 0, "0", "f", "F", "false", "False", "FALSE", "off", "OFF"]
  10   def truthy_param?(blank_value) when blank_value in [nil, ""], do: nil
  11   def truthy_param?(value), do: value not in @falsy_param_values
  12
  13   def json_response(conn, status, json) do
  14     conn
  15     |> put_status(status)
  16     |> json(json)
  17   end
  18
  19   @spec fetch_integer_param(map(), String.t(), integer() | nil) :: integer() | nil
  20   def fetch_integer_param(params, name, default \\ nil) do
  21     params
  22     |> Map.get(name, default)
  23     |> param_to_integer(default)
  24   end
  25
  26   defp param_to_integer(val, _) when is_integer(val), do: val
  27
  28   defp param_to_integer(val, default) when is_binary(val) do
  29     case Integer.parse(val) do
  30       {res, _} -> res
  31       _ -> default
  32     end
  33   end
  34
  35   defp param_to_integer(_, default), do: default
  36
  37   def add_link_headers(conn, activities, extra_params \\ %{})
  38
  39   def add_link_headers(%{assigns: %{skip_link_headers: true}} = conn, _activities, _extra_params),
  40     do: conn
  41
  42   def add_link_headers(conn, activities, extra_params) do
  43     case List.last(activities) do
  44       %{id: max_id} ->
  45         params =
  46           conn.params
  47           |> Map.drop(Map.keys(conn.path_params))
  48           |> Map.drop(["since_id", "max_id", "min_id"])
  49           |> Map.merge(extra_params)
  50
  51         limit =
  52           params
  53           |> Map.get("limit", "20")
  54           |> String.to_integer()
  55
  56         min_id =
  57           if length(activities) <= limit do
  58             activities
  59             |> List.first()
  60             |> Map.get(:id)
  61           else
  62             activities
  63             |> Enum.at(limit * -1)
  64             |> Map.get(:id)
  65           end
  66
  67         next_url = current_url(conn, Map.merge(params, %{max_id: max_id}))
  68         prev_url = current_url(conn, Map.merge(params, %{min_id: min_id}))
  69
  70         put_resp_header(conn, "link", "<#{next_url}>; rel=\"next\", <#{prev_url}>; rel=\"prev\"")
  71
  72       _ ->
  73         conn
  74     end
  75   end
  76
  77   def assign_account_by_id(%{params: %{"id" => id}} = conn, _) do
  78     case Pleroma.User.get_cached_by_id(id) do
  79       %Pleroma.User{} = account -> assign(conn, :account, account)
  80       nil -> Pleroma.Web.MastodonAPI.FallbackController.call(conn, {:error, :not_found}) |> halt()
  81     end
  82   end
  83
  84   def try_render(conn, target, params) when is_binary(target) do
  85     case render(conn, target, params) do
  86       nil -> render_error(conn, :not_implemented, "Can't display this activity")
  87       res -> res
  88     end
  89   end
  90
  91   def try_render(conn, _, _) do
  92     render_error(conn, :not_implemented, "Can't display this activity")
  93   end
  94
  95   @spec put_if_exist(map(), atom() | String.t(), any) :: map()
  96   def put_if_exist(map, _key, nil), do: map
  97
  98   def put_if_exist(map, key, value), do: Map.put(map, key, value)
  99 end