git.squeep.com Git - akkoma/blob - lib/pleroma/web/common_api/utils.ex

   1 defmodule Pleroma.Web.CommonAPI.Utils do
   2   alias Calendar.Strftime
   3   alias Comeonin.Pbkdf2
   4   alias Pleroma.{Activity, Formatter, Object, Repo}
   5   alias Pleroma.User
   6   alias Pleroma.Web
   7   alias Pleroma.Web.ActivityPub.Utils
   8   alias Pleroma.Web.Endpoint
   9   alias Pleroma.Web.MediaProxy
  10
  11   # This is a hack for twidere.
  12   def get_by_id_or_ap_id(id) do
  13     activity = Repo.get(Activity, id) || Activity.get_create_activity_by_object_ap_id(id)
  14
  15     activity &&
  16       if activity.data["type"] == "Create" do
  17         activity
  18       else
  19         Activity.get_create_activity_by_object_ap_id(activity.data["object"])
  20       end
  21   end
  22
  23   def get_replied_to_activity(""), do: nil
  24
  25   def get_replied_to_activity(id) when not is_nil(id) do
  26     Repo.get(Activity, id)
  27   end
  28
  29   def get_replied_to_activity(_), do: nil
  30
  31   def attachments_from_ids(ids) do
  32     Enum.map(ids || [], fn media_id ->
  33       Repo.get(Object, media_id).data
  34     end)
  35   end
  36
  37   def to_for_user_and_mentions(user, mentions, inReplyTo, "public") do
  38     mentioned_users = Enum.map(mentions, fn {_, %{ap_id: ap_id}} -> ap_id end)
  39
  40     to = ["https://www.w3.org/ns/activitystreams#Public" | mentioned_users]
  41     cc = [user.follower_address]
  42
  43     if inReplyTo do
  44       {Enum.uniq([inReplyTo.data["actor"] | to]), cc}
  45     else
  46       {to, cc}
  47     end
  48   end
  49
  50   def to_for_user_and_mentions(user, mentions, inReplyTo, "unlisted") do
  51     mentioned_users = Enum.map(mentions, fn {_, %{ap_id: ap_id}} -> ap_id end)
  52
  53     to = [user.follower_address | mentioned_users]
  54     cc = ["https://www.w3.org/ns/activitystreams#Public"]
  55
  56     if inReplyTo do
  57       {Enum.uniq([inReplyTo.data["actor"] | to]), cc}
  58     else
  59       {to, cc}
  60     end
  61   end
  62
  63   def to_for_user_and_mentions(user, mentions, inReplyTo, "private") do
  64     {to, cc} = to_for_user_and_mentions(user, mentions, inReplyTo, "direct")
  65     {[user.follower_address | to], cc}
  66   end
  67
  68   def to_for_user_and_mentions(_user, mentions, inReplyTo, "direct") do
  69     mentioned_users = Enum.map(mentions, fn {_, %{ap_id: ap_id}} -> ap_id end)
  70
  71     if inReplyTo do
  72       {Enum.uniq([inReplyTo.data["actor"] | mentioned_users]), []}
  73     else
  74       {mentioned_users, []}
  75     end
  76   end
  77
  78   def make_content_html(
  79         status,
  80         mentions,
  81         attachments,
  82         tags,
  83         content_type,
  84         no_attachment_links \\ false
  85       ) do
  86     status
  87     |> format_input(mentions, tags, content_type)
  88     |> maybe_add_attachments(attachments, no_attachment_links)
  89   end
  90
  91   def make_context(%Activity{data: %{"context" => context}}), do: context
  92   def make_context(_), do: Utils.generate_context_id()
  93
  94   def maybe_add_attachments(text, _attachments, _no_links = true), do: text
  95
  96   def maybe_add_attachments(text, attachments, _no_links) do
  97     add_attachments(text, attachments)
  98   end
  99
 100   def add_attachments(text, attachments) do
 101     attachment_text =
 102       Enum.map(attachments, fn
 103         %{"url" => [%{"href" => href} | _]} = attachment ->
 104           name = attachment["name"] || URI.decode(Path.basename(href))
 105           href = MediaProxy.url(href)
 106           "<a href=\"#{href}\" class='attachment'>#{shortname(name)}</a>"
 107
 108         _ ->
 109           ""
 110       end)
 111
 112     Enum.join([text | attachment_text], "<br>")
 113   end
 114
 115   def format_input(text, mentions, tags, "text/plain") do
 116     text
 117     |> Formatter.html_escape("text/plain")
 118     |> String.replace(~r/\r?\n/, "<br>")
 119     |> (&{[], &1}).()
 120     |> Formatter.add_links()
 121     |> Formatter.add_user_links(mentions)
 122     |> Formatter.add_hashtag_links(tags)
 123     |> Formatter.finalize()
 124   end
 125
 126   def format_input(text, mentions, _tags, "text/html") do
 127     text
 128     |> Formatter.html_escape("text/html")
 129     |> String.replace(~r/\r?\n/, "<br>")
 130     |> (&{[], &1}).()
 131     |> Formatter.add_user_links(mentions)
 132     |> Formatter.finalize()
 133   end
 134
 135   def format_input(text, mentions, tags, "text/markdown") do
 136     text
 137     |> Earmark.as_html!()
 138     |> Formatter.html_escape("text/html")
 139     |> String.replace(~r/\r?\n/, "")
 140     |> (&{[], &1}).()
 141     |> Formatter.add_user_links(mentions)
 142     |> Formatter.add_hashtag_links(tags)
 143     |> Formatter.finalize()
 144   end
 145
 146   def add_tag_links(text, tags) do
 147     tags =
 148       tags
 149       |> Enum.sort_by(fn {tag, _} -> -String.length(tag) end)
 150
 151     Enum.reduce(tags, text, fn {full, tag}, text ->
 152       url = "<a href='#{Web.base_url()}/tag/#{tag}' rel='tag'>##{tag}</a>"
 153       String.replace(text, full, url)
 154     end)
 155   end
 156
 157   def make_note_data(
 158         actor,
 159         to,
 160         context,
 161         content_html,
 162         attachments,
 163         inReplyTo,
 164         tags,
 165         cw \\ nil,
 166         cc \\ []
 167       ) do
 168     object = %{
 169       "type" => "Note",
 170       "to" => to,
 171       "cc" => cc,
 172       "content" => content_html,
 173       "summary" => cw,
 174       "context" => context,
 175       "attachment" => attachments,
 176       "actor" => actor,
 177       "tag" => tags |> Enum.map(fn {_, tag} -> tag end) |> Enum.uniq()
 178     }
 179
 180     if inReplyTo do
 181       object
 182       |> Map.put("inReplyTo", inReplyTo.data["object"]["id"])
 183       |> Map.put("inReplyToStatusId", inReplyTo.id)
 184     else
 185       object
 186     end
 187   end
 188
 189   def format_naive_asctime(date) do
 190     date |> DateTime.from_naive!("Etc/UTC") |> format_asctime
 191   end
 192
 193   def format_asctime(date) do
 194     Strftime.strftime!(date, "%a %b %d %H:%M:%S %z %Y")
 195   end
 196
 197   def date_to_asctime(date) do
 198     with {:ok, date, _offset} <- date |> DateTime.from_iso8601() do
 199       format_asctime(date)
 200     else
 201       _e ->
 202         ""
 203     end
 204   end
 205
 206   def to_masto_date(%NaiveDateTime{} = date) do
 207     date
 208     |> NaiveDateTime.to_iso8601()
 209     |> String.replace(~r/(\.\d+)?$/, ".000Z", global: false)
 210   end
 211
 212   def to_masto_date(date) do
 213     try do
 214       date
 215       |> NaiveDateTime.from_iso8601!()
 216       |> NaiveDateTime.to_iso8601()
 217       |> String.replace(~r/(\.\d+)?$/, ".000Z", global: false)
 218     rescue
 219       _e -> ""
 220     end
 221   end
 222
 223   defp shortname(name) do
 224     if String.length(name) < 30 do
 225       name
 226     else
 227       String.slice(name, 0..30) <> "…"
 228     end
 229   end
 230
 231   def confirm_current_password(user, password) do
 232     with %User{local: true} = db_user <- Repo.get(User, user.id),
 233          true <- Pbkdf2.checkpw(password, db_user.password_hash) do
 234       {:ok, db_user}
 235     else
 236       _ -> {:error, "Invalid password."}
 237     end
 238   end
 239
 240   def emoji_from_profile(%{info: _info} = user) do
 241     (Formatter.get_emoji(user.bio) ++ Formatter.get_emoji(user.name))
 242     |> Enum.map(fn {shortcode, url} ->
 243       %{
 244         "type" => "Emoji",
 245         "icon" => %{"type" => "Image", "url" => "#{Endpoint.url()}#{url}"},
 246         "name" => ":#{shortcode}:"
 247       }
 248     end)
 249   end
 250 end