git.squeep.com Git - akkoma/blob - lib/pleroma/web/common_api/common_api.ex

   1 defmodule Pleroma.Web.CommonAPI do
   2   alias Pleroma.{User, Repo, Activity, Object}
   3   alias Pleroma.Web.ActivityPub.ActivityPub
   4   alias Pleroma.Formatter
   5
   6   import Pleroma.Web.CommonAPI.Utils
   7
   8   def delete(activity_id, user) do
   9     with %Activity{data: %{"object" => %{"id" => object_id}}} <- Repo.get(Activity, activity_id),
  10          %Object{} = object <- Object.normalize(object_id),
  11          true <- user.info["is_moderator"] || user.ap_id == object.data["actor"],
  12          {:ok, delete} <- ActivityPub.delete(object) do
  13       {:ok, delete}
  14     end
  15   end
  16
  17   def repeat(id_or_ap_id, user) do
  18     with %Activity{} = activity <- get_by_id_or_ap_id(id_or_ap_id),
  19          object <- Object.normalize(activity.data["object"]["id"]) do
  20       ActivityPub.announce(user, object)
  21     else
  22       _ ->
  23         {:error, "Could not repeat"}
  24     end
  25   end
  26
  27   def unrepeat(id_or_ap_id, user) do
  28     with %Activity{} = activity <- get_by_id_or_ap_id(id_or_ap_id),
  29          object <- Object.normalize(activity.data["object"]["id"]) do
  30       ActivityPub.unannounce(user, object)
  31     else
  32       _ ->
  33         {:error, "Could not unrepeat"}
  34     end
  35   end
  36
  37   def favorite(id_or_ap_id, user) do
  38     with %Activity{} = activity <- get_by_id_or_ap_id(id_or_ap_id),
  39          false <- activity.data["actor"] == user.ap_id,
  40          object <- Object.normalize(activity.data["object"]["id"]) do
  41       ActivityPub.like(user, object)
  42     else
  43       _ ->
  44         {:error, "Could not favorite"}
  45     end
  46   end
  47
  48   def unfavorite(id_or_ap_id, user) do
  49     with %Activity{} = activity <- get_by_id_or_ap_id(id_or_ap_id),
  50          false <- activity.data["actor"] == user.ap_id,
  51          object <- Object.normalize(activity.data["object"]["id"]) do
  52       ActivityPub.unlike(user, object)
  53     else
  54       _ ->
  55         {:error, "Could not unfavorite"}
  56     end
  57   end
  58
  59   def get_visibility(%{"visibility" => visibility})
  60       when visibility in ~w{public unlisted private direct},
  61       do: visibility
  62
  63   def get_visibility(%{"in_reply_to_status_id" => status_id}) when not is_nil(status_id) do
  64     case get_replied_to_activity(status_id) do
  65       nil ->
  66         "public"
  67
  68       inReplyTo ->
  69         Pleroma.Web.MastodonAPI.StatusView.get_visibility(inReplyTo.data["object"])
  70     end
  71   end
  72
  73   def get_visibility(_), do: "public"
  74
  75   @instance Application.get_env(:pleroma, :instance)
  76   @allowed_post_formats Keyword.get(@instance, :allowed_post_formats)
  77
  78   defp get_content_type(content_type) when content_type in @allowed_post_formats, do: content_type
  79   defp get_content_type(_), do: "text/plain"
  80
  81   @limit Keyword.get(@instance, :limit)
  82   def post(user, %{"status" => status} = data) do
  83     visibility = get_visibility(data)
  84
  85     with status <- String.trim(status),
  86          length when length in 1..@limit <- String.length(status),
  87          attachments <- attachments_from_ids(data["media_ids"]),
  88          mentions <- Formatter.parse_mentions(status),
  89          inReplyTo <- get_replied_to_activity(data["in_reply_to_status_id"]),
  90          {to, cc} <- to_for_user_and_mentions(user, mentions, inReplyTo, visibility),
  91          tags <- Formatter.parse_tags(status, data),
  92          content_html <-
  93            make_content_html(
  94              status,
  95              mentions,
  96              attachments,
  97              tags,
  98              get_content_type(data["content_type"]),
  99              data["no_attachment_links"]
 100            ),
 101          context <- make_context(inReplyTo),
 102          cw <- data["spoiler_text"],
 103          object <-
 104            make_note_data(
 105              user.ap_id,
 106              to,
 107              context,
 108              content_html,
 109              attachments,
 110              inReplyTo,
 111              tags,
 112              cw,
 113              cc
 114            ),
 115          object <-
 116            Map.put(
 117              object,
 118              "emoji",
 119              Formatter.get_emoji(status)
 120              |> Enum.reduce(%{}, fn {name, file}, acc ->
 121                Map.put(acc, name, "#{Pleroma.Web.Endpoint.static_url()}#{file}")
 122              end)
 123            ) do
 124       res =
 125         ActivityPub.create(%{
 126           to: to,
 127           actor: user,
 128           context: context,
 129           object: object,
 130           additional: %{"cc" => cc}
 131         })
 132
 133       res
 134     end
 135   end
 136
 137   def update(user) do
 138     user =
 139       with emoji <- emoji_from_profile(user),
 140            source_data <- (user.info["source_data"] || %{}) |> Map.put("tag", emoji),
 141            new_info <- Map.put(user.info, "source_data", source_data),
 142            change <- User.info_changeset(user, %{info: new_info}),
 143            {:ok, user} <- User.update_and_set_cache(change) do
 144         user
 145       else
 146         _e ->
 147           user
 148       end
 149
 150     ActivityPub.update(%{
 151       local: true,
 152       to: [user.follower_address],
 153       cc: [],
 154       actor: user.ap_id,
 155       object: Pleroma.Web.ActivityPub.UserView.render("user.json", %{user: user})
 156     })
 157   end
 158 end