git.squeep.com Git - akkoma/blob - lib/pleroma/web/common_api/common_api.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.CommonAPI do
   6   alias Pleroma.Activity
   7   alias Pleroma.Formatter
   8   alias Pleroma.Object
   9   alias Pleroma.ThreadMute
  10   alias Pleroma.User
  11   alias Pleroma.Web.ActivityPub.ActivityPub
  12   alias Pleroma.Web.ActivityPub.Utils
  13
  14   import Pleroma.Web.CommonAPI.Utils
  15
  16   def follow(follower, followed) do
  17     with {:ok, follower} <- User.maybe_direct_follow(follower, followed),
  18          {:ok, activity} <- ActivityPub.follow(follower, followed),
  19          {:ok, follower, followed} <-
  20            User.wait_and_refresh(
  21              Pleroma.Config.get([:activitypub, :follow_handshake_timeout]),
  22              follower,
  23              followed
  24            ) do
  25       {:ok, follower, followed, activity}
  26     end
  27   end
  28
  29   def unfollow(follower, unfollowed) do
  30     with {:ok, follower, _follow_activity} <- User.unfollow(follower, unfollowed),
  31          {:ok, _activity} <- ActivityPub.unfollow(follower, unfollowed) do
  32       {:ok, follower}
  33     end
  34   end
  35
  36   def accept_follow_request(follower, followed) do
  37     with {:ok, follower} <- User.maybe_follow(follower, followed),
  38          %Activity{} = follow_activity <- Utils.fetch_latest_follow(follower, followed),
  39          {:ok, follow_activity} <- Utils.update_follow_state(follow_activity, "accept"),
  40          {:ok, _activity} <-
  41            ActivityPub.accept(%{
  42              to: [follower.ap_id],
  43              actor: followed,
  44              object: follow_activity.data["id"],
  45              type: "Accept"
  46            }) do
  47       {:ok, follower}
  48     end
  49   end
  50
  51   def reject_follow_request(follower, followed) do
  52     with %Activity{} = follow_activity <- Utils.fetch_latest_follow(follower, followed),
  53          {:ok, follow_activity} <- Utils.update_follow_state(follow_activity, "reject"),
  54          {:ok, _activity} <-
  55            ActivityPub.reject(%{
  56              to: [follower.ap_id],
  57              actor: followed,
  58              object: follow_activity.data["id"],
  59              type: "Reject"
  60            }) do
  61       {:ok, follower}
  62     end
  63   end
  64
  65   def delete(activity_id, user) do
  66     with %Activity{data: %{"object" => _}} = activity <-
  67            Activity.get_by_id_with_object(activity_id),
  68          %Object{} = object <- Object.normalize(activity),
  69          true <- User.superuser?(user) || user.ap_id == object.data["actor"],
  70          {:ok, _} <- unpin(activity_id, user),
  71          {:ok, delete} <- ActivityPub.delete(object) do
  72       {:ok, delete}
  73     end
  74   end
  75
  76   def repeat(id_or_ap_id, user) do
  77     with %Activity{} = activity <- get_by_id_or_ap_id(id_or_ap_id),
  78          object <- Object.normalize(activity),
  79          nil <- Utils.get_existing_announce(user.ap_id, object) do
  80       ActivityPub.announce(user, object)
  81     else
  82       _ ->
  83         {:error, "Could not repeat"}
  84     end
  85   end
  86
  87   def unrepeat(id_or_ap_id, user) do
  88     with %Activity{} = activity <- get_by_id_or_ap_id(id_or_ap_id),
  89          object <- Object.normalize(activity) do
  90       ActivityPub.unannounce(user, object)
  91     else
  92       _ ->
  93         {:error, "Could not unrepeat"}
  94     end
  95   end
  96
  97   def favorite(id_or_ap_id, user) do
  98     with %Activity{} = activity <- get_by_id_or_ap_id(id_or_ap_id),
  99          object <- Object.normalize(activity),
 100          nil <- Utils.get_existing_like(user.ap_id, object) do
 101       ActivityPub.like(user, object)
 102     else
 103       _ ->
 104         {:error, "Could not favorite"}
 105     end
 106   end
 107
 108   def unfavorite(id_or_ap_id, user) do
 109     with %Activity{} = activity <- get_by_id_or_ap_id(id_or_ap_id),
 110          object <- Object.normalize(activity) do
 111       ActivityPub.unlike(user, object)
 112     else
 113       _ ->
 114         {:error, "Could not unfavorite"}
 115     end
 116   end
 117
 118   def get_visibility(%{"visibility" => visibility})
 119       when visibility in ~w{public unlisted private direct},
 120       do: visibility
 121
 122   def get_visibility(%{"in_reply_to_status_id" => status_id}) when not is_nil(status_id) do
 123     case get_replied_to_activity(status_id) do
 124       nil ->
 125         "public"
 126
 127       in_reply_to ->
 128         Pleroma.Web.MastodonAPI.StatusView.get_visibility(in_reply_to.data["object"])
 129     end
 130   end
 131
 132   def get_visibility(_), do: "public"
 133
 134   def post(user, %{"status" => status} = data) do
 135     visibility = get_visibility(data)
 136     limit = Pleroma.Config.get([:instance, :limit])
 137
 138     with status <- String.trim(status),
 139          attachments <- attachments_from_ids(data),
 140          in_reply_to <- get_replied_to_activity(data["in_reply_to_status_id"]),
 141          {content_html, mentions, tags} <-
 142            make_content_html(
 143              status,
 144              attachments,
 145              data,
 146              visibility
 147            ),
 148          {to, cc} <- to_for_user_and_mentions(user, mentions, in_reply_to, visibility),
 149          context <- make_context(in_reply_to),
 150          cw <- data["spoiler_text"],
 151          full_payload <- String.trim(status <> (data["spoiler_text"] || "")),
 152          length when length in 1..limit <- String.length(full_payload),
 153          object <-
 154            make_note_data(
 155              user.ap_id,
 156              to,
 157              context,
 158              content_html,
 159              attachments,
 160              in_reply_to,
 161              tags,
 162              cw,
 163              cc
 164            ),
 165          object <-
 166            Map.put(
 167              object,
 168              "emoji",
 169              (Formatter.get_emoji(status) ++ Formatter.get_emoji(data["spoiler_text"]))
 170              |> Enum.reduce(%{}, fn {name, file}, acc ->
 171                Map.put(acc, name, "#{Pleroma.Web.Endpoint.static_url()}#{file}")
 172              end)
 173            ) do
 174       res =
 175         ActivityPub.create(%{
 176           to: to,
 177           actor: user,
 178           context: context,
 179           object: object,
 180           additional: %{"cc" => cc, "directMessage" => visibility == "direct"}
 181         })
 182
 183       res
 184     end
 185   end
 186
 187   # Updates the emojis for a user based on their profile
 188   def update(user) do
 189     user =
 190       with emoji <- emoji_from_profile(user),
 191            source_data <- (user.info.source_data || %{}) |> Map.put("tag", emoji),
 192            info_cng <- Pleroma.User.Info.set_source_data(user.info, source_data),
 193            change <- Ecto.Changeset.change(user) |> Ecto.Changeset.put_embed(:info, info_cng),
 194            {:ok, user} <- User.update_and_set_cache(change) do
 195         user
 196       else
 197         _e ->
 198           user
 199       end
 200
 201     ActivityPub.update(%{
 202       local: true,
 203       to: [user.follower_address],
 204       cc: [],
 205       actor: user.ap_id,
 206       object: Pleroma.Web.ActivityPub.UserView.render("user.json", %{user: user})
 207     })
 208   end
 209
 210   def pin(id_or_ap_id, %{ap_id: user_ap_id} = user) do
 211     with %Activity{
 212            actor: ^user_ap_id,
 213            data: %{
 214              "type" => "Create",
 215              "object" => %{
 216                "to" => object_to,
 217                "type" => "Note"
 218              }
 219            }
 220          } = activity <- get_by_id_or_ap_id(id_or_ap_id),
 221          true <- Enum.member?(object_to, "https://www.w3.org/ns/activitystreams#Public"),
 222          %{valid?: true} = info_changeset <-
 223            Pleroma.User.Info.add_pinnned_activity(user.info, activity),
 224          changeset <-
 225            Ecto.Changeset.change(user) |> Ecto.Changeset.put_embed(:info, info_changeset),
 226          {:ok, _user} <- User.update_and_set_cache(changeset) do
 227       {:ok, activity}
 228     else
 229       %{errors: [pinned_activities: {err, _}]} ->
 230         {:error, err}
 231
 232       _ ->
 233         {:error, "Could not pin"}
 234     end
 235   end
 236
 237   def unpin(id_or_ap_id, user) do
 238     with %Activity{} = activity <- get_by_id_or_ap_id(id_or_ap_id),
 239          %{valid?: true} = info_changeset <-
 240            Pleroma.User.Info.remove_pinnned_activity(user.info, activity),
 241          changeset <-
 242            Ecto.Changeset.change(user) |> Ecto.Changeset.put_embed(:info, info_changeset),
 243          {:ok, _user} <- User.update_and_set_cache(changeset) do
 244       {:ok, activity}
 245     else
 246       %{errors: [pinned_activities: {err, _}]} ->
 247         {:error, err}
 248
 249       _ ->
 250         {:error, "Could not unpin"}
 251     end
 252   end
 253
 254   def add_mute(user, activity) do
 255     with {:ok, _} <- ThreadMute.add_mute(user.id, activity.data["context"]) do
 256       {:ok, activity}
 257     else
 258       {:error, _} -> {:error, "conversation is already muted"}
 259     end
 260   end
 261
 262   def remove_mute(user, activity) do
 263     ThreadMute.remove_mute(user.id, activity.data["context"])
 264     {:ok, activity}
 265   end
 266
 267   def thread_muted?(%{id: nil} = _user, _activity), do: false
 268
 269   def thread_muted?(user, activity) do
 270     with [] <- ThreadMute.check_muted(user.id, activity.data["context"]) do
 271       false
 272     else
 273       _ -> true
 274     end
 275   end
 276
 277   def report(user, data) do
 278     with {:account_id, %{"account_id" => account_id}} <- {:account_id, data},
 279          {:account, %User{} = account} <- {:account, User.get_by_id(account_id)},
 280          {:ok, {content_html, _, _}} <- make_report_content_html(data["comment"]),
 281          {:ok, statuses} <- get_report_statuses(account, data),
 282          {:ok, activity} <-
 283            ActivityPub.flag(%{
 284              context: Utils.generate_context_id(),
 285              actor: user,
 286              account: account,
 287              statuses: statuses,
 288              content: content_html,
 289              forward: data["forward"] || false
 290            }) do
 291       {:ok, activity}
 292     else
 293       {:error, err} -> {:error, err}
 294       {:account_id, %{}} -> {:error, "Valid `account_id` required"}
 295       {:account, nil} -> {:error, "Account not found"}
 296     end
 297   end
 298
 299   def hide_reblogs(user, muted) do
 300     ap_id = muted.ap_id
 301
 302     if ap_id not in user.info.muted_reblogs do
 303       info_changeset = User.Info.add_reblog_mute(user.info, ap_id)
 304       changeset = Ecto.Changeset.change(user) |> Ecto.Changeset.put_embed(:info, info_changeset)
 305       User.update_and_set_cache(changeset)
 306     end
 307   end
 308
 309   def show_reblogs(user, muted) do
 310     ap_id = muted.ap_id
 311
 312     if ap_id in user.info.muted_reblogs do
 313       info_changeset = User.Info.remove_reblog_mute(user.info, ap_id)
 314       changeset = Ecto.Changeset.change(user) |> Ecto.Changeset.put_embed(:info, info_changeset)
 315       User.update_and_set_cache(changeset)
 316     end
 317   end
 318 end