git.squeep.com Git - akkoma/blob - lib/pleroma/web/common_api/common_api.ex

   1 defmodule Pleroma.Web.CommonAPI do
   2   alias Pleroma.{User, Repo, Activity, Object}
   3   alias Pleroma.Web.ActivityPub.ActivityPub
   4   alias Pleroma.Formatter
   5
   6   import Pleroma.Web.CommonAPI.Utils
   7
   8   def delete(activity_id, user) do
   9     with %Activity{data: %{"object" => %{"id" => object_id}}} <- Repo.get(Activity, activity_id),
  10          %Object{} = object <- Object.normalize(object_id),
  11          true <- user.info["is_moderator"] || user.ap_id == object.data["actor"],
  12          {:ok, delete} <- ActivityPub.delete(object) do
  13       {:ok, delete}
  14     end
  15   end
  16
  17   def repeat(id_or_ap_id, user) do
  18     with %Activity{} = activity <- get_by_id_or_ap_id(id_or_ap_id),
  19          object <- Object.normalize(activity.data["object"]["id"]) do
  20       ActivityPub.announce(user, object)
  21     else
  22       _ ->
  23         {:error, "Could not repeat"}
  24     end
  25   end
  26
  27   def unrepeat(id_or_ap_id, user) do
  28     with %Activity{} = activity <- get_by_id_or_ap_id(id_or_ap_id),
  29          object <- Object.normalize(activity.data["object"]["id"]) do
  30       ActivityPub.unannounce(user, object)
  31     else
  32       _ ->
  33         {:error, "Could not unrepeat"}
  34     end
  35   end
  36
  37   def favorite(id_or_ap_id, user) do
  38     with %Activity{} = activity <- get_by_id_or_ap_id(id_or_ap_id),
  39          false <- activity.data["actor"] == user.ap_id,
  40          object <- Object.normalize(activity.data["object"]["id"]) do
  41       ActivityPub.like(user, object)
  42     else
  43       _ ->
  44         {:error, "Could not favorite"}
  45     end
  46   end
  47
  48   def unfavorite(id_or_ap_id, user) do
  49     with %Activity{} = activity <- get_by_id_or_ap_id(id_or_ap_id),
  50          false <- activity.data["actor"] == user.ap_id,
  51          object <- Object.normalize(activity.data["object"]["id"]) do
  52       ActivityPub.unlike(user, object)
  53     else
  54       _ ->
  55         {:error, "Could not unfavorite"}
  56     end
  57   end
  58
  59   def get_visibility(%{"visibility" => visibility})
  60       when visibility in ~w{public unlisted private direct},
  61       do: visibility
  62
  63   def get_visibility(%{"in_reply_to_status_id" => status_id}) when not is_nil(status_id) do
  64     case get_replied_to_activity(status_id) do
  65       nil ->
  66         "public"
  67
  68       inReplyTo ->
  69         Pleroma.Web.MastodonAPI.StatusView.get_visibility(inReplyTo.data["object"])
  70     end
  71   end
  72
  73   def get_visibility(_), do: "public"
  74
  75   @instance Application.get_env(:pleroma, :instance)
  76   @limit Keyword.get(@instance, :limit)
  77   def post(user, %{"status" => status} = data) do
  78     visibility = get_visibility(data)
  79
  80     with status <- String.trim(status),
  81          length when length in 1..@limit <- String.length(status),
  82          attachments <- attachments_from_ids(data["media_ids"]),
  83          mentions <- Formatter.parse_mentions(status),
  84          inReplyTo <- get_replied_to_activity(data["in_reply_to_status_id"]),
  85          {to, cc} <- to_for_user_and_mentions(user, mentions, inReplyTo, visibility),
  86          tags <- Formatter.parse_tags(status, data),
  87          content_html <-
  88            make_content_html(status, mentions, attachments, tags, data["no_attachment_links"]),
  89          context <- make_context(inReplyTo),
  90          cw <- data["spoiler_text"],
  91          object <-
  92            make_note_data(
  93              user.ap_id,
  94              to,
  95              context,
  96              content_html,
  97              attachments,
  98              inReplyTo,
  99              tags,
 100              cw,
 101              cc
 102            ),
 103          object <-
 104            Map.put(
 105              object,
 106              "emoji",
 107              Formatter.get_emoji(status)
 108              |> Enum.reduce(%{}, fn {name, file}, acc ->
 109                Map.put(acc, name, "#{Pleroma.Web.Endpoint.static_url()}#{file}")
 110              end)
 111            ) do
 112       res =
 113         ActivityPub.create(%{
 114           to: to,
 115           actor: user,
 116           context: context,
 117           object: object,
 118           additional: %{"cc" => cc}
 119         })
 120
 121       res
 122     end
 123   end
 124
 125   def update(user) do
 126     user =
 127       with emoji <- emoji_from_profile(user),
 128            source_data <- (user.info["source_data"] || %{}) |> Map.put("tag", emoji),
 129            new_info <- Map.put(user.info, "source_data", source_data),
 130            change <- User.info_changeset(user, %{info: new_info}),
 131            {:ok, user} <- User.update_and_set_cache(change) do
 132         user
 133       else
 134         _e ->
 135           user
 136       end
 137
 138     ActivityPub.update(%{
 139       local: true,
 140       to: [user.follower_address],
 141       cc: [],
 142       actor: user.ap_id,
 143       object: Pleroma.Web.ActivityPub.UserView.render("user.json", %{user: user})
 144     })
 145   end
 146 end