git.squeep.com Git - akkoma/blob - lib/pleroma/web/common_api/common_api.ex

   1 defmodule Pleroma.Web.CommonAPI do
   2   alias Pleroma.{User, Repo, Activity, Object}
   3   alias Pleroma.Web.ActivityPub.ActivityPub
   4   alias Pleroma.Formatter
   5
   6   import Pleroma.Web.CommonAPI.Utils
   7
   8   def delete(activity_id, user) do
   9     with %Activity{data: %{"object" => %{"id" => object_id}}} <- Repo.get(Activity, activity_id),
  10          %Object{} = object <- Object.normalize(object_id),
  11          true <- user.info.is_moderator || user.ap_id == object.data["actor"],
  12          {:ok, delete} <- ActivityPub.delete(object) do
  13       {:ok, delete}
  14     end
  15   end
  16
  17   def repeat(id_or_ap_id, user) do
  18     with %Activity{} = activity <- get_by_id_or_ap_id(id_or_ap_id),
  19          object <- Object.normalize(activity.data["object"]["id"]) do
  20       ActivityPub.announce(user, object)
  21     else
  22       _ ->
  23         {:error, "Could not repeat"}
  24     end
  25   end
  26
  27   def unrepeat(id_or_ap_id, user) do
  28     with %Activity{} = activity <- get_by_id_or_ap_id(id_or_ap_id),
  29          object <- Object.normalize(activity.data["object"]["id"]) do
  30       ActivityPub.unannounce(user, object)
  31     else
  32       _ ->
  33         {:error, "Could not unrepeat"}
  34     end
  35   end
  36
  37   def favorite(id_or_ap_id, user) do
  38     with %Activity{} = activity <- get_by_id_or_ap_id(id_or_ap_id),
  39          object <- Object.normalize(activity.data["object"]["id"]) do
  40       ActivityPub.like(user, object)
  41     else
  42       _ ->
  43         {:error, "Could not favorite"}
  44     end
  45   end
  46
  47   def unfavorite(id_or_ap_id, user) do
  48     with %Activity{} = activity <- get_by_id_or_ap_id(id_or_ap_id),
  49          object <- Object.normalize(activity.data["object"]["id"]) do
  50       ActivityPub.unlike(user, object)
  51     else
  52       _ ->
  53         {:error, "Could not unfavorite"}
  54     end
  55   end
  56
  57   def get_visibility(%{"visibility" => visibility})
  58       when visibility in ~w{public unlisted private direct},
  59       do: visibility
  60
  61   def get_visibility(%{"in_reply_to_status_id" => status_id}) when not is_nil(status_id) do
  62     case get_replied_to_activity(status_id) do
  63       nil ->
  64         "public"
  65
  66       inReplyTo ->
  67         Pleroma.Web.MastodonAPI.StatusView.get_visibility(inReplyTo.data["object"])
  68     end
  69   end
  70
  71   def get_visibility(_), do: "public"
  72
  73   defp get_content_type(content_type) do
  74     if Enum.member?(Pleroma.Config.get([:instance, :allowed_post_formats]), content_type) do
  75       content_type
  76     else
  77       "text/plain"
  78     end
  79   end
  80
  81   def post(user, %{"status" => status} = data) do
  82     visibility = get_visibility(data)
  83     limit = Pleroma.Config.get([:instance, :limit])
  84
  85     with status <- String.trim(status),
  86          attachments <- attachments_from_ids(data["media_ids"]),
  87          mentions <- Formatter.parse_mentions(status),
  88          inReplyTo <- get_replied_to_activity(data["in_reply_to_status_id"]),
  89          {to, cc} <- to_for_user_and_mentions(user, mentions, inReplyTo, visibility),
  90          tags <- Formatter.parse_tags(status, data),
  91          content_html <-
  92            make_content_html(
  93              status,
  94              mentions,
  95              attachments,
  96              tags,
  97              get_content_type(data["content_type"]),
  98              data["no_attachment_links"]
  99            ),
 100          context <- make_context(inReplyTo),
 101          cw <- data["spoiler_text"],
 102          full_payload <- String.trim(status <> (data["spoiler_text"] || "")),
 103          length when length in 1..limit <- String.length(full_payload),
 104          object <-
 105            make_note_data(
 106              user.ap_id,
 107              to,
 108              context,
 109              content_html,
 110              attachments,
 111              inReplyTo,
 112              tags,
 113              cw,
 114              cc
 115            ),
 116          object <-
 117            Map.put(
 118              object,
 119              "emoji",
 120              Formatter.get_emoji(status)
 121              |> Enum.reduce(%{}, fn {name, file}, acc ->
 122                Map.put(acc, name, "#{Pleroma.Web.Endpoint.static_url()}#{file}")
 123              end)
 124            ) do
 125       res =
 126         ActivityPub.create(%{
 127           to: to,
 128           actor: user,
 129           context: context,
 130           object: object,
 131           additional: %{"cc" => cc}
 132         })
 133
 134       res
 135     end
 136   end
 137
 138   # Updates the emojis for a user based on their profile
 139   def update(user) do
 140     user =
 141       with emoji <- emoji_from_profile(user),
 142            source_data <- (user.info.source_data || %{}) |> Map.put("tag", emoji),
 143            info_cng <- Pleroma.User.Info.set_source_data(user.info, source_data),
 144            change <- Ecto.Changeset.change(user) |> Ecto.Changeset.put_embed(:info, info_cng),
 145            {:ok, user} <- User.update_and_set_cache(change) do
 146         user
 147       else
 148         _e ->
 149           user
 150       end
 151
 152     ActivityPub.update(%{
 153       local: true,
 154       to: [user.follower_address],
 155       cc: [],
 156       actor: user.ap_id,
 157       object: Pleroma.Web.ActivityPub.UserView.render("user.json", %{user: user})
 158     })
 159   end
 160 end