git.squeep.com Git - akkoma/blob - lib/pleroma/web/common_api/common_api.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.CommonAPI do
   6   alias Pleroma.Activity
   7   alias Pleroma.Bookmark
   8   alias Pleroma.Formatter
   9   alias Pleroma.Object
  10   alias Pleroma.ThreadMute
  11   alias Pleroma.User
  12   alias Pleroma.Web.ActivityPub.ActivityPub
  13   alias Pleroma.Web.ActivityPub.Utils
  14
  15   import Pleroma.Web.CommonAPI.Utils
  16
  17   def follow(follower, followed) do
  18     with {:ok, follower} <- User.maybe_direct_follow(follower, followed),
  19          {:ok, activity} <- ActivityPub.follow(follower, followed),
  20          {:ok, follower, followed} <-
  21            User.wait_and_refresh(
  22              Pleroma.Config.get([:activitypub, :follow_handshake_timeout]),
  23              follower,
  24              followed
  25            ) do
  26       {:ok, follower, followed, activity}
  27     end
  28   end
  29
  30   def unfollow(follower, unfollowed) do
  31     with {:ok, follower, _follow_activity} <- User.unfollow(follower, unfollowed),
  32          {:ok, _activity} <- ActivityPub.unfollow(follower, unfollowed) do
  33       {:ok, follower}
  34     end
  35   end
  36
  37   def accept_follow_request(follower, followed) do
  38     with {:ok, follower} <- User.maybe_follow(follower, followed),
  39          %Activity{} = follow_activity <- Utils.fetch_latest_follow(follower, followed),
  40          {:ok, follow_activity} <- Utils.update_follow_state(follow_activity, "accept"),
  41          {:ok, _activity} <-
  42            ActivityPub.accept(%{
  43              to: [follower.ap_id],
  44              actor: followed,
  45              object: follow_activity.data["id"],
  46              type: "Accept"
  47            }) do
  48       {:ok, follower}
  49     end
  50   end
  51
  52   def reject_follow_request(follower, followed) do
  53     with %Activity{} = follow_activity <- Utils.fetch_latest_follow(follower, followed),
  54          {:ok, follow_activity} <- Utils.update_follow_state(follow_activity, "reject"),
  55          {:ok, _activity} <-
  56            ActivityPub.reject(%{
  57              to: [follower.ap_id],
  58              actor: followed,
  59              object: follow_activity.data["id"],
  60              type: "Reject"
  61            }) do
  62       {:ok, follower}
  63     end
  64   end
  65
  66   def delete(activity_id, user) do
  67     with %Activity{data: %{"object" => _}} = activity <-
  68            Activity.get_by_id_with_object(activity_id),
  69          %Object{} = object <- Object.normalize(activity),
  70          true <- User.superuser?(user) || user.ap_id == object.data["actor"],
  71          {:ok, _} <- unpin(activity_id, user),
  72          {:ok, delete} <- ActivityPub.delete(object) do
  73       {:ok, delete}
  74     end
  75   end
  76
  77   def repeat(id_or_ap_id, user) do
  78     with %Activity{} = activity <- get_by_id_or_ap_id(id_or_ap_id),
  79          object <- Object.normalize(activity),
  80          nil <- Utils.get_existing_announce(user.ap_id, object) do
  81       ActivityPub.announce(user, object)
  82     else
  83       _ ->
  84         {:error, "Could not repeat"}
  85     end
  86   end
  87
  88   def unrepeat(id_or_ap_id, user) do
  89     with %Activity{} = activity <- get_by_id_or_ap_id(id_or_ap_id),
  90          object <- Object.normalize(activity) do
  91       ActivityPub.unannounce(user, object)
  92     else
  93       _ ->
  94         {:error, "Could not unrepeat"}
  95     end
  96   end
  97
  98   def favorite(id_or_ap_id, user) do
  99     with %Activity{} = activity <- get_by_id_or_ap_id(id_or_ap_id),
 100          object <- Object.normalize(activity),
 101          nil <- Utils.get_existing_like(user.ap_id, object) do
 102       ActivityPub.like(user, object)
 103     else
 104       _ ->
 105         {:error, "Could not favorite"}
 106     end
 107   end
 108
 109   def unfavorite(id_or_ap_id, user) do
 110     with %Activity{} = activity <- get_by_id_or_ap_id(id_or_ap_id),
 111          object <- Object.normalize(activity) do
 112       ActivityPub.unlike(user, object)
 113     else
 114       _ ->
 115         {:error, "Could not unfavorite"}
 116     end
 117   end
 118
 119   def get_visibility(%{"visibility" => visibility})
 120       when visibility in ~w{public unlisted private direct},
 121       do: visibility
 122
 123   def get_visibility(%{"in_reply_to_status_id" => status_id}) when not is_nil(status_id) do
 124     case get_replied_to_activity(status_id) do
 125       nil ->
 126         "public"
 127
 128       in_reply_to ->
 129         # XXX: these heuristics should be moved out of MastodonAPI.
 130         with %Object{} = object <- Object.normalize(in_reply_to) do
 131           Pleroma.Web.MastodonAPI.StatusView.get_visibility(object)
 132         end
 133     end
 134   end
 135
 136   def get_visibility(_), do: "public"
 137
 138   def post(user, %{"status" => status} = data) do
 139     visibility = get_visibility(data)
 140     limit = Pleroma.Config.get([:instance, :limit])
 141
 142     with status <- String.trim(status),
 143          attachments <- attachments_from_ids(data),
 144          in_reply_to <- get_replied_to_activity(data["in_reply_to_status_id"]),
 145          {content_html, mentions, tags} <-
 146            make_content_html(
 147              status,
 148              attachments,
 149              data,
 150              visibility
 151            ),
 152          {to, cc} <- to_for_user_and_mentions(user, mentions, in_reply_to, visibility),
 153          context <- make_context(in_reply_to),
 154          cw <- data["spoiler_text"] || "",
 155          full_payload <- String.trim(status <> cw),
 156          length when length in 1..limit <- String.length(full_payload),
 157          object <-
 158            make_note_data(
 159              user.ap_id,
 160              to,
 161              context,
 162              content_html,
 163              attachments,
 164              in_reply_to,
 165              tags,
 166              cw,
 167              cc
 168            ),
 169          object <-
 170            Map.put(
 171              object,
 172              "emoji",
 173              Formatter.get_emoji_map(full_payload)
 174            ) do
 175       res =
 176         ActivityPub.create(
 177           %{
 178             to: to,
 179             actor: user,
 180             context: context,
 181             object: object,
 182             additional: %{"cc" => cc, "directMessage" => visibility == "direct"}
 183           },
 184           Pleroma.Web.ControllerHelper.truthy_param?(data["preview"]) || false
 185         )
 186
 187       res
 188     end
 189   end
 190
 191   # Updates the emojis for a user based on their profile
 192   def update(user) do
 193     user =
 194       with emoji <- emoji_from_profile(user),
 195            source_data <- (user.info.source_data || %{}) |> Map.put("tag", emoji),
 196            info_cng <- Pleroma.User.Info.set_source_data(user.info, source_data),
 197            change <- Ecto.Changeset.change(user) |> Ecto.Changeset.put_embed(:info, info_cng),
 198            {:ok, user} <- User.update_and_set_cache(change) do
 199         user
 200       else
 201         _e ->
 202           user
 203       end
 204
 205     ActivityPub.update(%{
 206       local: true,
 207       to: [user.follower_address],
 208       cc: [],
 209       actor: user.ap_id,
 210       object: Pleroma.Web.ActivityPub.UserView.render("user.json", %{user: user})
 211     })
 212   end
 213
 214   def pin(id_or_ap_id, %{ap_id: user_ap_id} = user) do
 215     with %Activity{
 216            actor: ^user_ap_id,
 217            data: %{
 218              "type" => "Create"
 219            },
 220            object: %Object{
 221              data: %{
 222                "to" => object_to,
 223                "type" => "Note"
 224              }
 225            }
 226          } = activity <- get_by_id_or_ap_id(id_or_ap_id),
 227          true <- Enum.member?(object_to, "https://www.w3.org/ns/activitystreams#Public"),
 228          %{valid?: true} = info_changeset <-
 229            Pleroma.User.Info.add_pinnned_activity(user.info, activity),
 230          changeset <-
 231            Ecto.Changeset.change(user) |> Ecto.Changeset.put_embed(:info, info_changeset),
 232          {:ok, _user} <- User.update_and_set_cache(changeset) do
 233       {:ok, activity}
 234     else
 235       %{errors: [pinned_activities: {err, _}]} ->
 236         {:error, err}
 237
 238       _ ->
 239         {:error, "Could not pin"}
 240     end
 241   end
 242
 243   def unpin(id_or_ap_id, user) do
 244     with %Activity{} = activity <- get_by_id_or_ap_id(id_or_ap_id),
 245          %{valid?: true} = info_changeset <-
 246            Pleroma.User.Info.remove_pinnned_activity(user.info, activity),
 247          changeset <-
 248            Ecto.Changeset.change(user) |> Ecto.Changeset.put_embed(:info, info_changeset),
 249          {:ok, _user} <- User.update_and_set_cache(changeset) do
 250       {:ok, activity}
 251     else
 252       %{errors: [pinned_activities: {err, _}]} ->
 253         {:error, err}
 254
 255       _ ->
 256         {:error, "Could not unpin"}
 257     end
 258   end
 259
 260   def add_mute(user, activity) do
 261     with {:ok, _} <- ThreadMute.add_mute(user.id, activity.data["context"]) do
 262       {:ok, activity}
 263     else
 264       {:error, _} -> {:error, "conversation is already muted"}
 265     end
 266   end
 267
 268   def remove_mute(user, activity) do
 269     ThreadMute.remove_mute(user.id, activity.data["context"])
 270     {:ok, activity}
 271   end
 272
 273   def thread_muted?(%{id: nil} = _user, _activity), do: false
 274
 275   def thread_muted?(user, activity) do
 276     with [] <- ThreadMute.check_muted(user.id, activity.data["context"]) do
 277       false
 278     else
 279       _ -> true
 280     end
 281   end
 282
 283   def bookmarked?(user, activity) do
 284     with %Bookmark{} <- Bookmark.get(user.id, activity.id) do
 285       true
 286     else
 287       _ ->
 288         false
 289     end
 290   end
 291
 292   def report(user, data) do
 293     with {:account_id, %{"account_id" => account_id}} <- {:account_id, data},
 294          {:account, %User{} = account} <- {:account, User.get_cached_by_id(account_id)},
 295          {:ok, {content_html, _, _}} <- make_report_content_html(data["comment"]),
 296          {:ok, statuses} <- get_report_statuses(account, data),
 297          {:ok, activity} <-
 298            ActivityPub.flag(%{
 299              context: Utils.generate_context_id(),
 300              actor: user,
 301              account: account,
 302              statuses: statuses,
 303              content: content_html,
 304              forward: data["forward"] || false
 305            }) do
 306       {:ok, activity}
 307     else
 308       {:error, err} -> {:error, err}
 309       {:account_id, %{}} -> {:error, "Valid `account_id` required"}
 310       {:account, nil} -> {:error, "Account not found"}
 311     end
 312   end
 313
 314   def hide_reblogs(user, muted) do
 315     ap_id = muted.ap_id
 316
 317     if ap_id not in user.info.muted_reblogs do
 318       info_changeset = User.Info.add_reblog_mute(user.info, ap_id)
 319       changeset = Ecto.Changeset.change(user) |> Ecto.Changeset.put_embed(:info, info_changeset)
 320       User.update_and_set_cache(changeset)
 321     end
 322   end
 323
 324   def show_reblogs(user, muted) do
 325     ap_id = muted.ap_id
 326
 327     if ap_id in user.info.muted_reblogs do
 328       info_changeset = User.Info.remove_reblog_mute(user.info, ap_id)
 329       changeset = Ecto.Changeset.change(user) |> Ecto.Changeset.put_embed(:info, info_changeset)
 330       User.update_and_set_cache(changeset)
 331     end
 332   end
 333 end