git.squeep.com Git - akkoma/blob - lib/pleroma/web/common_api/common_api.ex

   1 defmodule Pleroma.Web.CommonAPI do
   2   alias Pleroma.{Repo, Activity, Object, User}
   3   alias Pleroma.Web.ActivityPub.ActivityPub
   4   alias Pleroma.Formatter
   5
   6   import Pleroma.Web.CommonAPI.Utils
   7
   8   def delete(activity_id, user) do
   9     with %Activity{data: %{"object" => %{"id" => object_id}}} <- Repo.get(Activity, activity_id),
  10          %Object{} = object <- Object.get_by_ap_id(object_id),
  11            true <- user.ap_id == object.data["actor"],
  12          {:ok, delete} <- ActivityPub.delete(object) do
  13       {:ok, delete}
  14     end
  15   end
  16
  17   def repeat(id_or_ap_id, user) do
  18     with %Activity{} = activity <- get_by_id_or_ap_id(id_or_ap_id),
  19          object <- Object.get_by_ap_id(activity.data["object"]["id"]) do
  20       ActivityPub.announce(user, object)
  21     else
  22       _ ->
  23         {:error, "Could not repeat"}
  24     end
  25   end
  26
  27   def favorite(id_or_ap_id, user) do
  28     with %Activity{} = activity <- get_by_id_or_ap_id(id_or_ap_id),
  29          false <- activity.data["actor"] == user.ap_id,
  30          object <- Object.get_by_ap_id(activity.data["object"]["id"]) do
  31       ActivityPub.like(user, object)
  32     else
  33       _ ->
  34         {:error, "Could not favorite"}
  35     end
  36   end
  37
  38   def unfavorite(id_or_ap_id, user) do
  39     with %Activity{} = activity <- get_by_id_or_ap_id(id_or_ap_id),
  40          false <- activity.data["actor"] == user.ap_id,
  41          object <- Object.get_by_ap_id(activity.data["object"]["id"]) do
  42       ActivityPub.unlike(user, object)
  43     else
  44       _ ->
  45         {:error, "Could not unfavorite"}
  46     end
  47   end
  48
  49   @instance Application.get_env(:pleroma, :instance)
  50   @limit Keyword.get(@instance, :limit)
  51   def post(user, %{"status" => status} = data) do
  52     with status <- String.trim(status),
  53          length when length in 1..@limit <- String.length(status),
  54          attachments <- attachments_from_ids(data["media_ids"]),
  55          mentions <- Formatter.parse_mentions(status),
  56          inReplyTo <- get_replied_to_activity(data["in_reply_to_status_id"]),
  57          to <- to_for_user_and_mentions(user, mentions, inReplyTo),
  58          tags <- Formatter.parse_tags(status, data),
  59          content_html <- make_content_html(status, mentions, attachments, tags),
  60          context <- make_context(inReplyTo),
  61          cw <- data["spoiler_text"],
  62          object <- make_note_data(user.ap_id, to, context, content_html, attachments, inReplyTo, tags, cw) do
  63       res = ActivityPub.create(to, user, context, object)
  64       User.increase_note_count(user)
  65       res
  66     end
  67   end
  68 end