git.squeep.com Git - akkoma/blob - lib/pleroma/web/common_api/common_api.ex

   1 defmodule Pleroma.Web.CommonAPI do
   2   alias Pleroma.{Repo, Activity, Object, User}
   3   alias Pleroma.Web.ActivityPub.ActivityPub
   4   alias Pleroma.Formatter
   5
   6   import Pleroma.Web.CommonAPI.Utils
   7
   8   def delete(activity_id, user) do
   9     with %Activity{data: %{"object" => %{"id" => object_id}}} <- Repo.get(Activity, activity_id),
  10          %Object{} = object <- Object.get_by_ap_id(object_id),
  11          true <- user.info["is_moderator"] || user.ap_id == object.data["actor"],
  12          {:ok, delete} <- ActivityPub.delete(object) do
  13       {:ok, delete}
  14     end
  15   end
  16
  17   def repeat(id_or_ap_id, user) do
  18     with %Activity{} = activity <- get_by_id_or_ap_id(id_or_ap_id),
  19          object <- Object.get_by_ap_id(activity.data["object"]["id"]) do
  20       ActivityPub.announce(user, object)
  21     else
  22       _ ->
  23         {:error, "Could not repeat"}
  24     end
  25   end
  26
  27   def unrepeat(id_or_ap_id, user) do
  28     with %Activity{} = activity <- get_by_id_or_ap_id(id_or_ap_id),
  29          object <- Object.get_by_ap_id(activity.data["object"]["id"]) do
  30       ActivityPub.unannounce(user, object)
  31     else
  32       _ ->
  33         {:error, "Could not unrepeat"}
  34     end
  35   end
  36
  37   def favorite(id_or_ap_id, user) do
  38     with %Activity{} = activity <- get_by_id_or_ap_id(id_or_ap_id),
  39          false <- activity.data["actor"] == user.ap_id,
  40          object <- Object.get_by_ap_id(activity.data["object"]["id"]) do
  41       ActivityPub.like(user, object)
  42     else
  43       _ ->
  44         {:error, "Could not favorite"}
  45     end
  46   end
  47
  48   def unfavorite(id_or_ap_id, user) do
  49     with %Activity{} = activity <- get_by_id_or_ap_id(id_or_ap_id),
  50          false <- activity.data["actor"] == user.ap_id,
  51          object <- Object.get_by_ap_id(activity.data["object"]["id"]) do
  52       ActivityPub.unlike(user, object)
  53     else
  54       _ ->
  55         {:error, "Could not unfavorite"}
  56     end
  57   end
  58
  59   def get_visibility(%{"visibility" => visibility})
  60       when visibility in ~w{public unlisted private direct},
  61       do: visibility
  62
  63   def get_visibility(%{"in_reply_to_status_id" => status_id}) when not is_nil(status_id) do
  64     inReplyTo = get_replied_to_activity(status_id)
  65     Pleroma.Web.MastodonAPI.StatusView.get_visibility(inReplyTo.data["object"])
  66   end
  67
  68   def get_visibility(_), do: "public"
  69
  70   @instance Application.get_env(:pleroma, :instance)
  71   @limit Keyword.get(@instance, :limit)
  72   def post(user, %{"status" => status} = data) do
  73     visibility = get_visibility(data)
  74
  75     with status <- String.trim(status),
  76          length when length in 1..@limit <- String.length(status),
  77          attachments <- attachments_from_ids(data["media_ids"]),
  78          mentions <- Formatter.parse_mentions(status),
  79          inReplyTo <- get_replied_to_activity(data["in_reply_to_status_id"]),
  80          {to, cc} <- to_for_user_and_mentions(user, mentions, inReplyTo, visibility),
  81          tags <- Formatter.parse_tags(status, data),
  82          content_html <-
  83            make_content_html(status, mentions, attachments, tags, data["no_attachment_links"]),
  84          context <- make_context(inReplyTo),
  85          cw <- data["spoiler_text"],
  86          object <-
  87            make_note_data(
  88              user.ap_id,
  89              to,
  90              context,
  91              content_html,
  92              attachments,
  93              inReplyTo,
  94              tags,
  95              cw,
  96              cc
  97            ),
  98          object <-
  99            Map.put(
 100              object,
 101              "emoji",
 102              Formatter.get_emoji(status)
 103              |> Enum.reduce(%{}, fn {name, file}, acc ->
 104                Map.put(acc, name, "#{Pleroma.Web.Endpoint.static_url()}#{file}")
 105              end)
 106            ) do
 107       res =
 108         ActivityPub.create(%{
 109           to: to,
 110           actor: user,
 111           context: context,
 112           object: object,
 113           additional: %{"cc" => cc}
 114         })
 115
 116       User.increase_note_count(user)
 117       res
 118     end
 119   end
 120
 121   def update(user) do
 122     ActivityPub.update(%{
 123       local: true,
 124       to: [user.follower_address],
 125       cc: [],
 126       actor: user.ap_id,
 127       object: Pleroma.Web.ActivityPub.UserView.render("user.json", %{user: user})
 128     })
 129   end
 130 end