git.squeep.com Git - akkoma/blob - lib/pleroma/web/common_api/common_api.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.CommonAPI do
   6   alias Pleroma.Activity
   7   alias Pleroma.Bookmark
   8   alias Pleroma.Formatter
   9   alias Pleroma.Object
  10   alias Pleroma.ThreadMute
  11   alias Pleroma.User
  12   alias Pleroma.Web.ActivityPub.ActivityPub
  13   alias Pleroma.Web.ActivityPub.Utils
  14
  15   import Pleroma.Web.CommonAPI.Utils
  16
  17   def follow(follower, followed) do
  18     with {:ok, follower} <- User.maybe_direct_follow(follower, followed),
  19          {:ok, activity} <- ActivityPub.follow(follower, followed),
  20          {:ok, follower, followed} <-
  21            User.wait_and_refresh(
  22              Pleroma.Config.get([:activitypub, :follow_handshake_timeout]),
  23              follower,
  24              followed
  25            ) do
  26       {:ok, follower, followed, activity}
  27     end
  28   end
  29
  30   def unfollow(follower, unfollowed) do
  31     with {:ok, follower, _follow_activity} <- User.unfollow(follower, unfollowed),
  32          {:ok, _activity} <- ActivityPub.unfollow(follower, unfollowed) do
  33       {:ok, follower}
  34     end
  35   end
  36
  37   def accept_follow_request(follower, followed) do
  38     with {:ok, follower} <- User.maybe_follow(follower, followed),
  39          %Activity{} = follow_activity <- Utils.fetch_latest_follow(follower, followed),
  40          {:ok, follow_activity} <- Utils.update_follow_state(follow_activity, "accept"),
  41          {:ok, _activity} <-
  42            ActivityPub.accept(%{
  43              to: [follower.ap_id],
  44              actor: followed,
  45              object: follow_activity.data["id"],
  46              type: "Accept"
  47            }) do
  48       {:ok, follower}
  49     end
  50   end
  51
  52   def reject_follow_request(follower, followed) do
  53     with %Activity{} = follow_activity <- Utils.fetch_latest_follow(follower, followed),
  54          {:ok, follow_activity} <- Utils.update_follow_state(follow_activity, "reject"),
  55          {:ok, _activity} <-
  56            ActivityPub.reject(%{
  57              to: [follower.ap_id],
  58              actor: followed,
  59              object: follow_activity.data["id"],
  60              type: "Reject"
  61            }) do
  62       {:ok, follower}
  63     end
  64   end
  65
  66   def delete(activity_id, user) do
  67     with %Activity{data: %{"object" => _}} = activity <-
  68            Activity.get_by_id_with_object(activity_id),
  69          %Object{} = object <- Object.normalize(activity),
  70          true <- User.superuser?(user) || user.ap_id == object.data["actor"],
  71          {:ok, _} <- unpin(activity_id, user),
  72          {:ok, delete} <- ActivityPub.delete(object) do
  73       {:ok, delete}
  74     end
  75   end
  76
  77   def repeat(id_or_ap_id, user) do
  78     with %Activity{} = activity <- get_by_id_or_ap_id(id_or_ap_id),
  79          object <- Object.normalize(activity),
  80          nil <- Utils.get_existing_announce(user.ap_id, object) do
  81       ActivityPub.announce(user, object)
  82     else
  83       _ ->
  84         {:error, "Could not repeat"}
  85     end
  86   end
  87
  88   def unrepeat(id_or_ap_id, user) do
  89     with %Activity{} = activity <- get_by_id_or_ap_id(id_or_ap_id),
  90          object <- Object.normalize(activity) do
  91       ActivityPub.unannounce(user, object)
  92     else
  93       _ ->
  94         {:error, "Could not unrepeat"}
  95     end
  96   end
  97
  98   def favorite(id_or_ap_id, user) do
  99     with %Activity{} = activity <- get_by_id_or_ap_id(id_or_ap_id),
 100          object <- Object.normalize(activity),
 101          nil <- Utils.get_existing_like(user.ap_id, object) do
 102       ActivityPub.like(user, object)
 103     else
 104       _ ->
 105         {:error, "Could not favorite"}
 106     end
 107   end
 108
 109   def unfavorite(id_or_ap_id, user) do
 110     with %Activity{} = activity <- get_by_id_or_ap_id(id_or_ap_id),
 111          object <- Object.normalize(activity) do
 112       ActivityPub.unlike(user, object)
 113     else
 114       _ ->
 115         {:error, "Could not unfavorite"}
 116     end
 117   end
 118
 119   def get_visibility(%{"visibility" => visibility}, in_reply_to)
 120       when visibility in ~w{public unlisted private direct},
 121       do: {visibility, get_replied_to_visibility(in_reply_to)}
 122
 123   def get_visibility(_, in_reply_to) when not is_nil(in_reply_to) do
 124     visibility = get_replied_to_visibility(in_reply_to)
 125     {visibility, visibility}
 126   end
 127
 128   def get_visibility(_, in_reply_to), do: {"public", get_replied_to_visibility(in_reply_to)}
 129
 130   def get_replied_to_visibility(nil), do: nil
 131
 132   def get_replied_to_visibility(activity) do
 133     with %Object{} = object <- Object.normalize(activity) do
 134       Pleroma.Web.ActivityPub.Visibility.get_visibility(object)
 135     end
 136   end
 137
 138   def post(user, %{"status" => status} = data) do
 139     limit = Pleroma.Config.get([:instance, :limit])
 140
 141     with status <- String.trim(status),
 142          attachments <- attachments_from_ids(data),
 143          in_reply_to <- get_replied_to_activity(data["in_reply_to_status_id"]),
 144          {visibility, in_reply_to_visibility} <- get_visibility(data, in_reply_to),
 145          {_, false} <-
 146            {:private_to_public, in_reply_to_visibility == "direct" && visibility != "direct"},
 147          {content_html, mentions, tags} <-
 148            make_content_html(
 149              status,
 150              attachments,
 151              data,
 152              visibility
 153            ),
 154          {to, cc} <- to_for_user_and_mentions(user, mentions, in_reply_to, visibility),
 155          context <- make_context(in_reply_to),
 156          cw <- data["spoiler_text"] || "",
 157          full_payload <- String.trim(status <> cw),
 158          length when length in 1..limit <- String.length(full_payload),
 159          object <-
 160            make_note_data(
 161              user.ap_id,
 162              to,
 163              context,
 164              content_html,
 165              attachments,
 166              in_reply_to,
 167              tags,
 168              cw,
 169              cc
 170            ),
 171          object <-
 172            Map.put(
 173              object,
 174              "emoji",
 175              Formatter.get_emoji_map(full_payload)
 176            ) do
 177       res =
 178         ActivityPub.create(
 179           %{
 180             to: to,
 181             actor: user,
 182             context: context,
 183             object: object,
 184             additional: %{"cc" => cc, "directMessage" => visibility == "direct"}
 185           },
 186           Pleroma.Web.ControllerHelper.truthy_param?(data["preview"]) || false
 187         )
 188
 189       res
 190     else
 191       e -> {:error, e}
 192     end
 193   end
 194
 195   # Updates the emojis for a user based on their profile
 196   def update(user) do
 197     user =
 198       with emoji <- emoji_from_profile(user),
 199            source_data <- (user.info.source_data || %{}) |> Map.put("tag", emoji),
 200            info_cng <- Pleroma.User.Info.set_source_data(user.info, source_data),
 201            change <- Ecto.Changeset.change(user) |> Ecto.Changeset.put_embed(:info, info_cng),
 202            {:ok, user} <- User.update_and_set_cache(change) do
 203         user
 204       else
 205         _e ->
 206           user
 207       end
 208
 209     ActivityPub.update(%{
 210       local: true,
 211       to: [user.follower_address],
 212       cc: [],
 213       actor: user.ap_id,
 214       object: Pleroma.Web.ActivityPub.UserView.render("user.json", %{user: user})
 215     })
 216   end
 217
 218   def pin(id_or_ap_id, %{ap_id: user_ap_id} = user) do
 219     with %Activity{
 220            actor: ^user_ap_id,
 221            data: %{
 222              "type" => "Create"
 223            },
 224            object: %Object{
 225              data: %{
 226                "to" => object_to,
 227                "type" => "Note"
 228              }
 229            }
 230          } = activity <- get_by_id_or_ap_id(id_or_ap_id),
 231          true <- Enum.member?(object_to, "https://www.w3.org/ns/activitystreams#Public"),
 232          %{valid?: true} = info_changeset <-
 233            Pleroma.User.Info.add_pinnned_activity(user.info, activity),
 234          changeset <-
 235            Ecto.Changeset.change(user) |> Ecto.Changeset.put_embed(:info, info_changeset),
 236          {:ok, _user} <- User.update_and_set_cache(changeset) do
 237       {:ok, activity}
 238     else
 239       %{errors: [pinned_activities: {err, _}]} ->
 240         {:error, err}
 241
 242       _ ->
 243         {:error, "Could not pin"}
 244     end
 245   end
 246
 247   def unpin(id_or_ap_id, user) do
 248     with %Activity{} = activity <- get_by_id_or_ap_id(id_or_ap_id),
 249          %{valid?: true} = info_changeset <-
 250            Pleroma.User.Info.remove_pinnned_activity(user.info, activity),
 251          changeset <-
 252            Ecto.Changeset.change(user) |> Ecto.Changeset.put_embed(:info, info_changeset),
 253          {:ok, _user} <- User.update_and_set_cache(changeset) do
 254       {:ok, activity}
 255     else
 256       %{errors: [pinned_activities: {err, _}]} ->
 257         {:error, err}
 258
 259       _ ->
 260         {:error, "Could not unpin"}
 261     end
 262   end
 263
 264   def add_mute(user, activity) do
 265     with {:ok, _} <- ThreadMute.add_mute(user.id, activity.data["context"]) do
 266       {:ok, activity}
 267     else
 268       {:error, _} -> {:error, "conversation is already muted"}
 269     end
 270   end
 271
 272   def remove_mute(user, activity) do
 273     ThreadMute.remove_mute(user.id, activity.data["context"])
 274     {:ok, activity}
 275   end
 276
 277   def thread_muted?(%{id: nil} = _user, _activity), do: false
 278
 279   def thread_muted?(user, activity) do
 280     with [] <- ThreadMute.check_muted(user.id, activity.data["context"]) do
 281       false
 282     else
 283       _ -> true
 284     end
 285   end
 286
 287   def bookmarked?(user, activity) do
 288     with %Bookmark{} <- Bookmark.get(user.id, activity.id) do
 289       true
 290     else
 291       _ ->
 292         false
 293     end
 294   end
 295
 296   def report(user, data) do
 297     with {:account_id, %{"account_id" => account_id}} <- {:account_id, data},
 298          {:account, %User{} = account} <- {:account, User.get_cached_by_id(account_id)},
 299          {:ok, {content_html, _, _}} <- make_report_content_html(data["comment"]),
 300          {:ok, statuses} <- get_report_statuses(account, data),
 301          {:ok, activity} <-
 302            ActivityPub.flag(%{
 303              context: Utils.generate_context_id(),
 304              actor: user,
 305              account: account,
 306              statuses: statuses,
 307              content: content_html,
 308              forward: data["forward"] || false
 309            }) do
 310       {:ok, activity}
 311     else
 312       {:error, err} -> {:error, err}
 313       {:account_id, %{}} -> {:error, "Valid `account_id` required"}
 314       {:account, nil} -> {:error, "Account not found"}
 315     end
 316   end
 317
 318   def hide_reblogs(user, muted) do
 319     ap_id = muted.ap_id
 320
 321     if ap_id not in user.info.muted_reblogs do
 322       info_changeset = User.Info.add_reblog_mute(user.info, ap_id)
 323       changeset = Ecto.Changeset.change(user) |> Ecto.Changeset.put_embed(:info, info_changeset)
 324       User.update_and_set_cache(changeset)
 325     end
 326   end
 327
 328   def show_reblogs(user, muted) do
 329     ap_id = muted.ap_id
 330
 331     if ap_id in user.info.muted_reblogs do
 332       info_changeset = User.Info.remove_reblog_mute(user.info, ap_id)
 333       changeset = Ecto.Changeset.change(user) |> Ecto.Changeset.put_embed(:info, info_changeset)
 334       User.update_and_set_cache(changeset)
 335     end
 336   end
 337 end