git.squeep.com Git - akkoma/blob - lib/pleroma/web/common_api/common_api.ex

   1 defmodule Pleroma.Web.CommonAPI do
   2   alias Pleroma.{Repo, Activity, Object, User}
   3   alias Pleroma.Web.ActivityPub.ActivityPub
   4   alias Pleroma.Formatter
   5
   6   import Pleroma.Web.CommonAPI.Utils
   7
   8   def delete(activity_id, user) do
   9     with %Activity{data: %{"object" => %{"id" => object_id}}} <- Repo.get(Activity, activity_id),
  10          %Object{} = object <- Object.get_by_ap_id(object_id),
  11          true <- user.info["is_moderator"] || user.ap_id == object.data["actor"],
  12          {:ok, delete} <- ActivityPub.delete(object) do
  13       {:ok, delete}
  14     end
  15   end
  16
  17   def repeat(id_or_ap_id, user) do
  18     with %Activity{} = activity <- get_by_id_or_ap_id(id_or_ap_id),
  19          object <- Object.get_by_ap_id(activity.data["object"]["id"]) do
  20       ActivityPub.announce(user, object)
  21     else
  22       _ ->
  23         {:error, "Could not repeat"}
  24     end
  25   end
  26
  27   def favorite(id_or_ap_id, user) do
  28     with %Activity{} = activity <- get_by_id_or_ap_id(id_or_ap_id),
  29          false <- activity.data["actor"] == user.ap_id,
  30          object <- Object.get_by_ap_id(activity.data["object"]["id"]) do
  31       ActivityPub.like(user, object)
  32     else
  33       _ ->
  34         {:error, "Could not favorite"}
  35     end
  36   end
  37
  38   def unfavorite(id_or_ap_id, user) do
  39     with %Activity{} = activity <- get_by_id_or_ap_id(id_or_ap_id),
  40          false <- activity.data["actor"] == user.ap_id,
  41          object <- Object.get_by_ap_id(activity.data["object"]["id"]) do
  42       ActivityPub.unlike(user, object)
  43     else
  44       _ ->
  45         {:error, "Could not unfavorite"}
  46     end
  47   end
  48
  49   def get_visibility(%{"visibility" => visibility})
  50       when visibility in ~w{public unlisted private direct},
  51       do: visibility
  52
  53   def get_visibility(%{"in_reply_to_status_id" => status_id}) when not is_nil(status_id) do
  54     inReplyTo = get_replied_to_activity(status_id)
  55     Pleroma.Web.MastodonAPI.StatusView.get_visibility(inReplyTo.data["object"])
  56   end
  57
  58   def get_visibility(_), do: "public"
  59
  60   @instance Application.get_env(:pleroma, :instance)
  61   @limit Keyword.get(@instance, :limit)
  62   def post(user, %{"status" => status} = data) do
  63     visibility = get_visibility(data)
  64
  65     with status <- String.trim(status),
  66          length when length in 1..@limit <- String.length(status),
  67          attachments <- attachments_from_ids(data["media_ids"]),
  68          mentions <- Formatter.parse_mentions(status),
  69          inReplyTo <- get_replied_to_activity(data["in_reply_to_status_id"]),
  70          {to, cc} <- to_for_user_and_mentions(user, mentions, inReplyTo, visibility),
  71          tags <- Formatter.parse_tags(status, data),
  72          content_html <-
  73            make_content_html(status, mentions, attachments, tags, data["no_attachment_links"]),
  74          context <- make_context(inReplyTo),
  75          cw <- data["spoiler_text"],
  76          object <-
  77            make_note_data(
  78              user.ap_id,
  79              to,
  80              context,
  81              content_html,
  82              attachments,
  83              inReplyTo,
  84              tags,
  85              cw,
  86              cc
  87            ),
  88          object <-
  89            Map.put(
  90              object,
  91              "emoji",
  92              Formatter.get_emoji(status)
  93              |> Enum.reduce(%{}, fn {name, file}, acc ->
  94                Map.put(acc, name, "#{Pleroma.Web.Endpoint.static_url()}#{file}")
  95              end)
  96            ) do
  97       res =
  98         ActivityPub.create(%{
  99           to: to,
 100           actor: user,
 101           context: context,
 102           object: object,
 103           additional: %{"cc" => cc}
 104         })
 105
 106       User.increase_note_count(user)
 107       res
 108     end
 109   end
 110
 111   def update(user) do
 112     ActivityPub.update(%{
 113       local: true,
 114       to: [user.follower_address],
 115       cc: [],
 116       actor: user.ap_id,
 117       object: Pleroma.Web.ActivityPub.UserView.render("user.json", %{user: user})
 118     })
 119   end
 120 end