git.squeep.com Git - akkoma/blob - lib/pleroma/web/chat_channel.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ChatChannel do
   6   use Phoenix.Channel
   7   alias Pleroma.Web.ChatChannel.ChatChannelState
   8   alias Pleroma.User
   9
  10   def join("chat:public", _message, socket) do
  11     send(self(), :after_join)
  12     {:ok, socket}
  13   end
  14
  15   def handle_info(:after_join, socket) do
  16     push(socket, "messages", %{messages: ChatChannelState.messages()})
  17     {:noreply, socket}
  18   end
  19
  20   def handle_in("new_msg", %{"text" => text}, %{assigns: %{user_name: user_name}} = socket) do
  21     text = String.trim(text)
  22
  23     if String.length(text) > 0 do
  24       author = User.get_cached_by_nickname(user_name)
  25       author = Pleroma.Web.MastodonAPI.AccountView.render("account.json", user: author)
  26       message = ChatChannelState.add_message(%{text: text, author: author})
  27
  28       broadcast!(socket, "new_msg", message)
  29     end
  30
  31     {:noreply, socket}
  32   end
  33 end
  34
  35 defmodule Pleroma.Web.ChatChannel.ChatChannelState do
  36   @max_messages 20
  37
  38   def start_link do
  39     Agent.start_link(fn -> %{max_id: 1, messages: []} end, name: __MODULE__)
  40   end
  41
  42   def add_message(message) do
  43     Agent.get_and_update(__MODULE__, fn state ->
  44       id = state[:max_id] + 1
  45       message = Map.put(message, "id", id)
  46       messages = [message | state[:messages]] |> Enum.take(@max_messages)
  47       {message, %{max_id: id, messages: messages}}
  48     end)
  49   end
  50
  51   def messages() do
  52     Agent.get(__MODULE__, fn state -> state[:messages] |> Enum.reverse() end)
  53   end
  54 end