git.squeep.com Git - akkoma/blob - lib/pleroma/web/auth/pleroma_authenticator.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.Auth.PleromaAuthenticator do
   6   alias Comeonin.Pbkdf2
   7   alias Pleroma.User
   8
   9   @behaviour Pleroma.Web.Auth.Authenticator
  10
  11   def get_user(%Plug.Conn{} = _conn, params) do
  12     {name, password} =
  13       case params do
  14         %{"authorization" => %{"name" => name, "password" => password}} ->
  15           {name, password}
  16
  17         %{"grant_type" => "password", "username" => name, "password" => password} ->
  18           {name, password}
  19       end
  20
  21     with {_, %User{} = user} <- {:user, User.get_by_nickname_or_email(name)},
  22          {_, true} <- {:checkpw, Pbkdf2.checkpw(password, user.password_hash)} do
  23       {:ok, user}
  24     else
  25       error ->
  26         {:error, error}
  27     end
  28   end
  29
  30   def get_or_create_user_by_oauth(
  31         %Plug.Conn{assigns: %{ueberauth_auth: %{provider: provider, uid: uid} = auth}},
  32         _params
  33       ) do
  34     user = User.get_by_auth_provider_uid(provider, uid)
  35
  36     if user do
  37       {:ok, user}
  38     else
  39       info = auth.info
  40       email = info.email
  41       nickname = info.nickname
  42
  43       # TODO: FIXME: connect to existing (non-oauth) account (need a UI flow for that) / generate a random nickname?
  44       email =
  45         if email && User.get_by_email(email) do
  46           nil
  47         else
  48           email
  49         end
  50
  51       nickname =
  52         if nickname && User.get_by_nickname(nickname) do
  53           nil
  54         else
  55           nickname
  56         end
  57
  58       new_user =
  59         User.oauth_register_changeset(
  60           %User{},
  61           %{
  62             auth_provider: to_string(provider),
  63             auth_provider_uid: to_string(uid),
  64             name: info.name,
  65             bio: info.description,
  66             email: email,
  67             nickname: nickname
  68           }
  69         )
  70
  71       Pleroma.Repo.insert(new_user)
  72     end
  73   end
  74
  75   def get_or_create_user_by_oauth(%Plug.Conn{} = _conn, _params),
  76     do: {:error, :missing_credentials}
  77
  78   def handle_error(%Plug.Conn{} = _conn, error) do
  79     error
  80   end
  81
  82   def auth_template, do: nil
  83 end