git.squeep.com Git - akkoma/blob - lib/pleroma/web/auth/ldap_authenticator.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.Auth.LDAPAuthenticator do
   6   alias Pleroma.User
   7
   8   require Logger
   9
  10   @behaviour Pleroma.Web.Auth.Authenticator
  11
  12   @connection_timeout 10_000
  13   @search_timeout 10_000
  14
  15   def get_user(%Plug.Conn{} = conn) do
  16     if Pleroma.Config.get([:ldap, :enabled]) do
  17       {name, password} =
  18         case conn.params do
  19           %{"authorization" => %{"name" => name, "password" => password}} ->
  20             {name, password}
  21
  22           %{"grant_type" => "password", "username" => name, "password" => password} ->
  23             {name, password}
  24         end
  25
  26       case ldap_user(name, password) do
  27         %User{} = user ->
  28           {:ok, user}
  29
  30         {:error, {:ldap_connection_error, _}} ->
  31           # When LDAP is unavailable, try default authenticator
  32           Pleroma.Web.Auth.PleromaAuthenticator.get_user(conn)
  33
  34         error ->
  35           error
  36       end
  37     else
  38       # Fall back to default authenticator
  39       Pleroma.Web.Auth.PleromaAuthenticator.get_user(conn)
  40     end
  41   end
  42
  43   def handle_error(%Plug.Conn{} = _conn, error) do
  44     error
  45   end
  46
  47   def auth_template, do: nil
  48
  49   defp ldap_user(name, password) do
  50     ldap = Pleroma.Config.get(:ldap, [])
  51     host = Keyword.get(ldap, :host, "localhost")
  52     port = Keyword.get(ldap, :port, 389)
  53     ssl = Keyword.get(ldap, :ssl, false)
  54     sslopts = Keyword.get(ldap, :sslopts, [])
  55
  56     options =
  57       [{:port, port}, {:ssl, ssl}, {:timeout, @connection_timeout}] ++
  58         if sslopts != [], do: [{:sslopts, sslopts}], else: []
  59
  60     case :eldap.open([to_charlist(host)], options) do
  61       {:ok, connection} ->
  62         try do
  63           if Keyword.get(ldap, :tls, false) do
  64             :application.ensure_all_started(:ssl)
  65
  66             case :eldap.start_tls(
  67                    connection,
  68                    Keyword.get(ldap, :tlsopts, []),
  69                    @connection_timeout
  70                  ) do
  71               :ok ->
  72                 :ok
  73
  74               error ->
  75                 Logger.error("Could not start TLS: #{inspect(error)}")
  76             end
  77           end
  78
  79           bind_user(connection, ldap, name, password)
  80         after
  81           :eldap.close(connection)
  82         end
  83
  84       {:error, error} ->
  85         Logger.error("Could not open LDAP connection: #{inspect(error)}")
  86         {:error, {:ldap_connection_error, error}}
  87     end
  88   end
  89
  90   defp bind_user(connection, ldap, name, password) do
  91     uid = Keyword.get(ldap, :uid, "cn")
  92     base = Keyword.get(ldap, :base)
  93
  94     case :eldap.simple_bind(connection, "#{uid}=#{name},#{base}", password) do
  95       :ok ->
  96         case User.get_by_nickname_or_email(name) do
  97           %User{} = user ->
  98             user
  99
 100           _ ->
 101             register_user(connection, base, uid, name, password)
 102         end
 103
 104       error ->
 105         error
 106     end
 107   end
 108
 109   defp register_user(connection, base, uid, name, password) do
 110     case :eldap.search(connection, [
 111            {:base, to_charlist(base)},
 112            {:filter, :eldap.equalityMatch(to_charlist(uid), to_charlist(name))},
 113            {:scope, :eldap.wholeSubtree()},
 114            {:attributes, ['mail', 'email']},
 115            {:timeout, @search_timeout}
 116          ]) do
 117       {:ok, {:eldap_search_result, [{:eldap_entry, _, attributes}], _}} ->
 118         with {_, [mail]} <- List.keyfind(attributes, 'mail', 0) do
 119           params = %{
 120             email: :erlang.list_to_binary(mail),
 121             name: name,
 122             nickname: name,
 123             password: password,
 124             password_confirmation: password
 125           }
 126
 127           changeset = User.register_changeset(%User{}, params)
 128
 129           case User.register(changeset) do
 130             {:ok, user} -> user
 131             error -> error
 132           end
 133         else
 134           _ ->
 135             Logger.error("Could not find LDAP attribute mail: #{inspect(attributes)}")
 136             {:error, :ldap_registration_missing_attributes}
 137         end
 138
 139       error ->
 140         error
 141     end
 142   end
 143 end