git.squeep.com Git - akkoma/blob - lib/pleroma/web/auth/ldap_authenticator.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.Auth.LDAPAuthenticator do
   6   alias Pleroma.User
   7
   8   require Logger
   9
  10   @behaviour Pleroma.Web.Auth.Authenticator
  11   @base Pleroma.Web.Auth.PleromaAuthenticator
  12
  13   @connection_timeout 10_000
  14   @search_timeout 10_000
  15
  16   defdelegate get_registration(conn, params), to: @base
  17
  18   defdelegate create_from_registration(conn, params, registration), to: @base
  19
  20   def get_user(%Plug.Conn{} = conn, params) do
  21     if Pleroma.Config.get([:ldap, :enabled]) do
  22       {name, password} =
  23         case params do
  24           %{"authorization" => %{"name" => name, "password" => password}} ->
  25             {name, password}
  26
  27           %{"grant_type" => "password", "username" => name, "password" => password} ->
  28             {name, password}
  29         end
  30
  31       case ldap_user(name, password) do
  32         %User{} = user ->
  33           {:ok, user}
  34
  35         {:error, {:ldap_connection_error, _}} ->
  36           # When LDAP is unavailable, try default authenticator
  37           @base.get_user(conn, params)
  38
  39         error ->
  40           error
  41       end
  42     else
  43       # Fall back to default authenticator
  44       @base.get_user(conn, params)
  45     end
  46   end
  47
  48   def handle_error(%Plug.Conn{} = _conn, error) do
  49     error
  50   end
  51
  52   def auth_template, do: nil
  53
  54   defp ldap_user(name, password) do
  55     ldap = Pleroma.Config.get(:ldap, [])
  56     host = Keyword.get(ldap, :host, "localhost")
  57     port = Keyword.get(ldap, :port, 389)
  58     ssl = Keyword.get(ldap, :ssl, false)
  59     sslopts = Keyword.get(ldap, :sslopts, [])
  60
  61     options =
  62       [{:port, port}, {:ssl, ssl}, {:timeout, @connection_timeout}] ++
  63         if sslopts != [], do: [{:sslopts, sslopts}], else: []
  64
  65     case :eldap.open([to_charlist(host)], options) do
  66       {:ok, connection} ->
  67         try do
  68           if Keyword.get(ldap, :tls, false) do
  69             :application.ensure_all_started(:ssl)
  70
  71             case :eldap.start_tls(
  72                    connection,
  73                    Keyword.get(ldap, :tlsopts, []),
  74                    @connection_timeout
  75                  ) do
  76               :ok ->
  77                 :ok
  78
  79               error ->
  80                 Logger.error("Could not start TLS: #{inspect(error)}")
  81             end
  82           end
  83
  84           bind_user(connection, ldap, name, password)
  85         after
  86           :eldap.close(connection)
  87         end
  88
  89       {:error, error} ->
  90         Logger.error("Could not open LDAP connection: #{inspect(error)}")
  91         {:error, {:ldap_connection_error, error}}
  92     end
  93   end
  94
  95   defp bind_user(connection, ldap, name, password) do
  96     uid = Keyword.get(ldap, :uid, "cn")
  97     base = Keyword.get(ldap, :base)
  98
  99     case :eldap.simple_bind(connection, "#{uid}=#{name},#{base}", password) do
 100       :ok ->
 101         case User.get_by_nickname_or_email(name) do
 102           %User{} = user ->
 103             user
 104
 105           _ ->
 106             register_user(connection, base, uid, name, password)
 107         end
 108
 109       error ->
 110         error
 111     end
 112   end
 113
 114   defp register_user(connection, base, uid, name, password) do
 115     case :eldap.search(connection, [
 116            {:base, to_charlist(base)},
 117            {:filter, :eldap.equalityMatch(to_charlist(uid), to_charlist(name))},
 118            {:scope, :eldap.wholeSubtree()},
 119            {:attributes, ['mail', 'email']},
 120            {:timeout, @search_timeout}
 121          ]) do
 122       {:ok, {:eldap_search_result, [{:eldap_entry, _, attributes}], _}} ->
 123         with {_, [mail]} <- List.keyfind(attributes, 'mail', 0) do
 124           params = %{
 125             email: :erlang.list_to_binary(mail),
 126             name: name,
 127             nickname: name,
 128             password: password,
 129             password_confirmation: password
 130           }
 131
 132           changeset = User.register_changeset(%User{}, params)
 133
 134           case User.register(changeset) do
 135             {:ok, user} -> user
 136             error -> error
 137           end
 138         else
 139           _ ->
 140             Logger.error("Could not find LDAP attribute mail: #{inspect(attributes)}")
 141             {:error, :ldap_registration_missing_attributes}
 142         end
 143
 144       error ->
 145         error
 146     end
 147   end
 148 end