git.squeep.com Git - akkoma/blob - lib/pleroma/web/auth/ldap_authenticator.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.Auth.LDAPAuthenticator do
   6   alias Pleroma.User
   7
   8   require Logger
   9
  10   import Pleroma.Web.Auth.Authenticator,
  11     only: [fetch_credentials: 1, fetch_user: 1]
  12
  13   @behaviour Pleroma.Web.Auth.Authenticator
  14   @base Pleroma.Web.Auth.PleromaAuthenticator
  15
  16   @connection_timeout 10_000
  17   @search_timeout 10_000
  18
  19   defdelegate get_registration(conn), to: @base
  20   defdelegate create_from_registration(conn, registration), to: @base
  21   defdelegate handle_error(conn, error), to: @base
  22   defdelegate auth_template, to: @base
  23   defdelegate oauth_consumer_template, to: @base
  24
  25   def get_user(%Plug.Conn{} = conn) do
  26     with {:ldap, true} <- {:ldap, Pleroma.Config.get([:ldap, :enabled])},
  27          {:ok, {name, password}} <- fetch_credentials(conn),
  28          %User{} = user <- ldap_user(name, password) do
  29       {:ok, user}
  30     else
  31       {:ldap, _} ->
  32         @base.get_user(conn)
  33
  34       error ->
  35         error
  36     end
  37   end
  38
  39   defp ldap_user(name, password) do
  40     ldap = Pleroma.Config.get(:ldap, [])
  41     host = Keyword.get(ldap, :host, "localhost")
  42     port = Keyword.get(ldap, :port, 389)
  43     ssl = Keyword.get(ldap, :ssl, false)
  44     sslopts = Keyword.get(ldap, :sslopts, [])
  45
  46     options =
  47       [{:port, port}, {:ssl, ssl}, {:timeout, @connection_timeout}] ++
  48         if sslopts != [], do: [{:sslopts, sslopts}], else: []
  49
  50     case :eldap.open([to_charlist(host)], options) do
  51       {:ok, connection} ->
  52         try do
  53           if Keyword.get(ldap, :tls, false) do
  54             :application.ensure_all_started(:ssl)
  55
  56             case :eldap.start_tls(
  57                    connection,
  58                    Keyword.get(ldap, :tlsopts, []),
  59                    @connection_timeout
  60                  ) do
  61               :ok ->
  62                 :ok
  63
  64               error ->
  65                 Logger.error("Could not start TLS: #{inspect(error)}")
  66             end
  67           end
  68
  69           bind_user(connection, ldap, name, password)
  70         after
  71           :eldap.close(connection)
  72         end
  73
  74       {:error, error} ->
  75         Logger.error("Could not open LDAP connection: #{inspect(error)}")
  76         {:error, {:ldap_connection_error, error}}
  77     end
  78   end
  79
  80   defp bind_user(connection, ldap, name, password) do
  81     uid = Keyword.get(ldap, :uid, "cn")
  82     base = Keyword.get(ldap, :base)
  83
  84     case :eldap.simple_bind(connection, "#{uid}=#{name},#{base}", password) do
  85       :ok ->
  86         case fetch_user(name) do
  87           %User{} = user ->
  88             user
  89
  90           _ ->
  91             register_user(connection, base, uid, name)
  92         end
  93
  94       error ->
  95         error
  96     end
  97   end
  98
  99   defp register_user(connection, base, uid, name) do
 100     case :eldap.search(connection, [
 101            {:base, to_charlist(base)},
 102            {:filter, :eldap.equalityMatch(to_charlist(uid), to_charlist(name))},
 103            {:scope, :eldap.wholeSubtree()},
 104            {:timeout, @search_timeout}
 105          ]) do
 106       {:ok, {:eldap_search_result, [{:eldap_entry, _, attributes}], _}} ->
 107         params = %{
 108           name: name,
 109           nickname: name,
 110           password: nil
 111         }
 112
 113         params =
 114           case List.keyfind(attributes, 'mail', 0) do
 115             {_, [mail]} -> Map.put_new(params, :email, :erlang.list_to_binary(mail))
 116             _ -> params
 117           end
 118
 119         changeset = User.register_changeset_ldap(%User{}, params)
 120
 121         case User.register(changeset) do
 122           {:ok, user} -> user
 123           error -> error
 124         end
 125
 126       error ->
 127         error
 128     end
 129   end
 130 end