git.squeep.com Git - akkoma/blob - lib/pleroma/web/admin_api/views/account_view.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2021 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.AdminAPI.AccountView do
   6   use Pleroma.Web, :view
   7
   8   alias Pleroma.User
   9   alias Pleroma.Web.AdminAPI
  10   alias Pleroma.Web.AdminAPI.AccountView
  11   alias Pleroma.Web.CommonAPI
  12   alias Pleroma.Web.MastodonAPI
  13   alias Pleroma.Web.MediaProxy
  14
  15   def render("index.json", %{users: users, count: count, page_size: page_size}) do
  16     %{
  17       users: render_many(users, AccountView, "show.json", as: :user),
  18       count: count,
  19       page_size: page_size
  20     }
  21   end
  22
  23   def render("index.json", %{users: users}) do
  24     %{
  25       users: render_many(users, AccountView, "show.json", as: :user)
  26     }
  27   end
  28
  29   def render("credentials.json", %{user: user, for: for_user}) do
  30     user = User.sanitize_html(user, User.html_filter_policy(for_user))
  31     avatar = User.avatar_url(user) |> MediaProxy.url()
  32     banner = User.banner_url(user) |> MediaProxy.url()
  33     background = image_url(user.background) |> MediaProxy.url()
  34
  35     user
  36     |> Map.take([
  37       :id,
  38       :bio,
  39       :email,
  40       :fields,
  41       :name,
  42       :nickname,
  43       :is_locked,
  44       :no_rich_text,
  45       :default_scope,
  46       :hide_follows,
  47       :hide_followers_count,
  48       :hide_follows_count,
  49       :hide_followers,
  50       :hide_favorites,
  51       :allow_following_move,
  52       :show_role,
  53       :skip_thread_containment,
  54       :pleroma_settings_store,
  55       :raw_fields,
  56       :is_discoverable,
  57       :actor_type
  58     ])
  59     |> Map.merge(%{
  60       "avatar" => avatar,
  61       "banner" => banner,
  62       "background" => background
  63     })
  64   end
  65
  66   def render("show.json", %{user: user}) do
  67     avatar = User.avatar_url(user) |> MediaProxy.url()
  68     display_name = Pleroma.HTML.strip_tags(user.name || user.nickname)
  69     user = User.sanitize_html(user, FastSanitize.Sanitizer.StripTags)
  70
  71     %{
  72       "id" => user.id,
  73       "email" => user.email,
  74       "avatar" => avatar,
  75       "nickname" => user.nickname,
  76       "display_name" => display_name,
  77       "is_active" => user.is_active,
  78       "local" => user.local,
  79       "roles" => roles(user),
  80       "tags" => user.tags || [],
  81       "is_confirmed" => user.is_confirmed,
  82       "is_approved" => user.is_approved,
  83       "url" => user.uri || user.ap_id,
  84       "registration_reason" => user.registration_reason,
  85       "actor_type" => user.actor_type,
  86       "created_at" => CommonAPI.Utils.to_masto_date(user.inserted_at)
  87     }
  88   end
  89
  90   def render("created_many.json", %{users: users}) do
  91     render_many(users, AccountView, "created.json", as: :user)
  92   end
  93
  94   def render("created.json", %{user: user}) do
  95     %{
  96       type: "success",
  97       code: 200,
  98       data: %{
  99         nickname: user.nickname,
 100         email: user.email
 101       }
 102     }
 103   end
 104
 105   def render("create_errors.json", %{changesets: changesets}) do
 106     render_many(changesets, AccountView, "create_error.json", as: :changeset)
 107   end
 108
 109   def render("create_error.json", %{changeset: %Ecto.Changeset{changes: changes, errors: errors}}) do
 110     %{
 111       type: "error",
 112       code: 409,
 113       error: parse_error(errors),
 114       data: %{
 115         nickname: Map.get(changes, :nickname),
 116         email: Map.get(changes, :email)
 117       }
 118     }
 119   end
 120
 121   def merge_account_views(%User{} = user) do
 122     MastodonAPI.AccountView.render("show.json", %{user: user, skip_visibility_check: true})
 123     |> Map.merge(AdminAPI.AccountView.render("show.json", %{user: user}))
 124   end
 125
 126   def merge_account_views(_), do: %{}
 127
 128   defp parse_error([]), do: ""
 129
 130   defp parse_error(errors) do
 131     ## when nickname is duplicate ap_id constraint error is raised
 132     nickname_error = Keyword.get(errors, :nickname) || Keyword.get(errors, :ap_id)
 133     email_error = Keyword.get(errors, :email)
 134     password_error = Keyword.get(errors, :password)
 135
 136     cond do
 137       nickname_error ->
 138         "nickname #{elem(nickname_error, 0)}"
 139
 140       email_error ->
 141         "email #{elem(email_error, 0)}"
 142
 143       password_error ->
 144         "password #{elem(password_error, 0)}"
 145
 146       true ->
 147         ""
 148     end
 149   end
 150
 151   defp image_url(%{"url" => [%{"href" => href} | _]}), do: href
 152   defp image_url(_), do: nil
 153
 154   defp roles(%{is_moderator: is_moderator, is_admin: is_admin}) do
 155     %{
 156       admin: is_admin,
 157       moderator: is_moderator
 158     }
 159   end
 160 end