git.squeep.com Git - akkoma/blob - lib/pleroma/web/admin_api/views/account_view.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2021 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.AdminAPI.AccountView do
   6   use Pleroma.Web, :view
   7
   8   alias Pleroma.User
   9   alias Pleroma.Web.AdminAPI
  10   alias Pleroma.Web.AdminAPI.AccountView
  11   alias Pleroma.Web.CommonAPI
  12   alias Pleroma.Web.MastodonAPI
  13   alias Pleroma.Web.MediaProxy
  14
  15   def render("index.json", %{users: users, count: count, page_size: page_size}) do
  16     %{
  17       users: render_many(users, AccountView, "show.json", as: :user),
  18       count: count,
  19       page_size: page_size
  20     }
  21   end
  22
  23   def render("index.json", %{users: users}) do
  24     %{
  25       users: render_many(users, AccountView, "show.json", as: :user)
  26     }
  27   end
  28
  29   def render("credentials.json", %{user: user, for: for_user}) do
  30     user = User.sanitize_html(user, User.html_filter_policy(for_user))
  31     avatar = User.avatar_url(user) |> MediaProxy.url()
  32     banner = User.banner_url(user) |> MediaProxy.url()
  33     background = image_url(user.background) |> MediaProxy.url()
  34
  35     user
  36     |> Map.take([
  37       :id,
  38       :bio,
  39       :email,
  40       :fields,
  41       :name,
  42       :nickname,
  43       :is_locked,
  44       :no_rich_text,
  45       :default_scope,
  46       :hide_follows,
  47       :hide_followers_count,
  48       :hide_follows_count,
  49       :hide_followers,
  50       :hide_favorites,
  51       :allow_following_move,
  52       :show_role,
  53       :skip_thread_containment,
  54       :pleroma_settings_store,
  55       :raw_fields,
  56       :is_discoverable,
  57       :actor_type
  58     ])
  59     |> Map.merge(%{
  60       "avatar" => avatar,
  61       "banner" => banner,
  62       "background" => background
  63     })
  64   end
  65
  66   def render("show.json", %{user: user}) do
  67     avatar = User.avatar_url(user) |> MediaProxy.url()
  68     display_name = Pleroma.HTML.strip_tags(user.name || user.nickname)
  69     user = User.sanitize_html(user, FastSanitize.Sanitizer.StripTags)
  70
  71     %{
  72       "id" => user.id,
  73       "email" => user.email,
  74       "avatar" => avatar,
  75       "nickname" => user.nickname,
  76       "display_name" => display_name,
  77       "is_active" => user.is_active,
  78       "local" => user.local,
  79       "roles" => User.roles(user),
  80       "tags" => user.tags || [],
  81       "is_confirmed" => user.is_confirmed,
  82       "is_approved" => user.is_approved,
  83       "url" => user.uri || user.ap_id,
  84       "registration_reason" => user.registration_reason,
  85       "actor_type" => user.actor_type,
  86       "created_at" => CommonAPI.Utils.to_masto_date(user.inserted_at)
  87     }
  88   end
  89
  90   def render("created.json", %{user: user}) do
  91     %{
  92       type: "success",
  93       code: 200,
  94       data: %{
  95         nickname: user.nickname,
  96         email: user.email
  97       }
  98     }
  99   end
 100
 101   def render("create-error.json", %{changeset: %Ecto.Changeset{changes: changes, errors: errors}}) do
 102     %{
 103       type: "error",
 104       code: 409,
 105       error: parse_error(errors),
 106       data: %{
 107         nickname: Map.get(changes, :nickname),
 108         email: Map.get(changes, :email)
 109       }
 110     }
 111   end
 112
 113   def merge_account_views(%User{} = user) do
 114     MastodonAPI.AccountView.render("show.json", %{user: user, skip_visibility_check: true})
 115     |> Map.merge(AdminAPI.AccountView.render("show.json", %{user: user}))
 116   end
 117
 118   def merge_account_views(_), do: %{}
 119
 120   defp parse_error([]), do: ""
 121
 122   defp parse_error(errors) do
 123     ## when nickname is duplicate ap_id constraint error is raised
 124     nickname_error = Keyword.get(errors, :nickname) || Keyword.get(errors, :ap_id)
 125     email_error = Keyword.get(errors, :email)
 126     password_error = Keyword.get(errors, :password)
 127
 128     cond do
 129       nickname_error ->
 130         "nickname #{elem(nickname_error, 0)}"
 131
 132       email_error ->
 133         "email #{elem(email_error, 0)}"
 134
 135       password_error ->
 136         "password #{elem(password_error, 0)}"
 137
 138       true ->
 139         ""
 140     end
 141   end
 142
 143   defp image_url(%{"url" => [%{"href" => href} | _]}), do: href
 144   defp image_url(_), do: nil
 145 end