git.squeep.com Git - akkoma/blob - lib/pleroma/web/admin_api/controllers/media_proxy_cache_controller.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.AdminAPI.MediaProxyCacheController do
   6   use Pleroma.Web, :controller
   7
   8   alias Pleroma.Plugs.OAuthScopesPlug
   9   alias Pleroma.Web.ApiSpec.Admin, as: Spec
  10   alias Pleroma.Web.MediaProxy
  11
  12   plug(Pleroma.Web.ApiSpec.CastAndValidate)
  13
  14   plug(
  15     OAuthScopesPlug,
  16     %{scopes: ["read:media_proxy_caches"], admin: true} when action in [:index]
  17   )
  18
  19   plug(
  20     OAuthScopesPlug,
  21     %{scopes: ["write:media_proxy_caches"], admin: true} when action in [:purge, :delete]
  22   )
  23
  24   action_fallback(Pleroma.Web.AdminAPI.FallbackController)
  25
  26   defdelegate open_api_operation(action), to: Spec.MediaProxyCacheOperation
  27
  28   def index(%{assigns: %{user: _}} = conn, params) do
  29     cursor =
  30       :banned_urls_cache
  31       |> :ets.table([{:traverse, {:select, Cachex.Query.create(true, :key)}}])
  32       |> :qlc.cursor()
  33
  34     urls =
  35       case params.page do
  36         1 ->
  37           :qlc.next_answers(cursor, params.page_size)
  38
  39         _ ->
  40           :qlc.next_answers(cursor, (params.page - 1) * params.page_size)
  41           :qlc.next_answers(cursor, params.page_size)
  42       end
  43
  44     :qlc.delete_cursor(cursor)
  45
  46     render(conn, "index.json", urls: urls)
  47   end
  48
  49   def delete(%{assigns: %{user: _}, body_params: %{urls: urls}} = conn, _) do
  50     MediaProxy.remove_from_banned_urls(urls)
  51     render(conn, "index.json", urls: urls)
  52   end
  53
  54   def purge(%{assigns: %{user: _}, body_params: %{urls: urls, ban: ban}} = conn, _) do
  55     MediaProxy.Invalidation.purge(urls)
  56
  57     if ban do
  58       MediaProxy.put_in_banned_urls(urls)
  59     end
  60
  61     render(conn, "index.json", urls: urls)
  62   end
  63 end