git.squeep.com Git - akkoma/blob - lib/pleroma/web/admin_api/controllers/media_proxy_cache_controller.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.AdminAPI.MediaProxyCacheController do
   6   use Pleroma.Web, :controller
   7
   8   alias Pleroma.Plugs.OAuthScopesPlug
   9   alias Pleroma.Web.ApiSpec.Admin, as: Spec
  10   alias Pleroma.Web.MediaProxy
  11
  12   plug(Pleroma.Web.ApiSpec.CastAndValidate)
  13
  14   plug(
  15     OAuthScopesPlug,
  16     %{scopes: ["read:media_proxy_caches"], admin: true} when action in [:index]
  17   )
  18
  19   plug(
  20     OAuthScopesPlug,
  21     %{scopes: ["write:media_proxy_caches"], admin: true} when action in [:purge, :delete]
  22   )
  23
  24   action_fallback(Pleroma.Web.AdminAPI.FallbackController)
  25
  26   defdelegate open_api_operation(action), to: Spec.MediaProxyCacheOperation
  27
  28   def index(%{assigns: %{user: _}} = conn, params) do
  29     entries = fetch_entries(params)
  30     urls = paginate_entries(entries, params.page, params.page_size)
  31
  32     render(conn, "index.json",
  33       urls: urls,
  34       page_size: params.page_size,
  35       count: length(entries)
  36     )
  37   end
  38
  39   defp fetch_entries(params) do
  40     MediaProxy.cache_table()
  41     |> Cachex.export!()
  42     |> filter_urls(params[:query])
  43   end
  44
  45   defp filter_urls(entries, query) when is_binary(query) do
  46     for {_, url, _, _, _} <- entries, String.contains?(url, query), do: url
  47   end
  48
  49   defp filter_urls(entries, _) do
  50     Enum.map(entries, fn {_, url, _, _, _} -> url end)
  51   end
  52
  53   defp paginate_entries(entries, page, page_size) do
  54     offset = page_size * (page - 1)
  55     Enum.slice(entries, offset, page_size)
  56   end
  57
  58   def delete(%{assigns: %{user: _}, body_params: %{urls: urls}} = conn, _) do
  59     MediaProxy.remove_from_banned_urls(urls)
  60     json(conn, %{})
  61   end
  62
  63   def purge(%{assigns: %{user: _}, body_params: %{urls: urls, ban: ban}} = conn, _) do
  64     MediaProxy.Invalidation.purge(urls)
  65
  66     if ban do
  67       MediaProxy.put_in_banned_urls(urls)
  68     end
  69
  70     json(conn, %{})
  71   end
  72 end