git.squeep.com Git - akkoma/blob - lib/pleroma/web/admin_api/controllers/config_controller.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.AdminAPI.ConfigController do
   6   use Pleroma.Web, :controller
   7
   8   alias Pleroma.Config
   9   alias Pleroma.ConfigDB
  10   alias Pleroma.Plugs.OAuthScopesPlug
  11
  12   @descriptions Pleroma.Docs.JSON.compile()
  13
  14   plug(Pleroma.Web.ApiSpec.CastAndValidate)
  15   plug(OAuthScopesPlug, %{scopes: ["write"], admin: true} when action == :update)
  16
  17   plug(
  18     OAuthScopesPlug,
  19     %{scopes: ["read"], admin: true}
  20     when action in [:show, :descriptions]
  21   )
  22
  23   action_fallback(Pleroma.Web.AdminAPI.FallbackController)
  24
  25   defdelegate open_api_operation(action), to: Pleroma.Web.ApiSpec.Admin.ConfigOperation
  26
  27   def descriptions(conn, _params) do
  28     descriptions = Enum.filter(@descriptions, &whitelisted_config?/1)
  29
  30     json(conn, descriptions)
  31   end
  32
  33   def show(conn, %{only_db: true}) do
  34     with :ok <- configurable_from_database() do
  35       configs = Pleroma.Repo.all(ConfigDB)
  36       render(conn, "index.json", %{configs: configs})
  37     end
  38   end
  39
  40   def show(conn, _params) do
  41     with :ok <- configurable_from_database() do
  42       configs = ConfigDB.get_all_as_keyword()
  43
  44       merged =
  45         Config.Holder.default_config()
  46         |> ConfigDB.merge(configs)
  47         |> Enum.map(fn {group, values} ->
  48           Enum.map(values, fn {key, value} ->
  49             db =
  50               if configs[group][key] do
  51                 ConfigDB.get_db_keys(configs[group][key], key)
  52               end
  53
  54             db_value = configs[group][key]
  55
  56             merged_value =
  57               if not is_nil(db_value) and Keyword.keyword?(db_value) and
  58                    ConfigDB.sub_key_full_update?(group, key, Keyword.keys(db_value)) do
  59                 ConfigDB.merge_group(group, key, value, db_value)
  60               else
  61                 value
  62               end
  63
  64             %{
  65               group: ConfigDB.convert(group),
  66               key: ConfigDB.convert(key),
  67               value: ConfigDB.convert(merged_value)
  68             }
  69             |> Pleroma.Maps.put_if_present(:db, db)
  70           end)
  71         end)
  72         |> List.flatten()
  73
  74       json(conn, %{configs: merged, need_reboot: Restarter.Pleroma.need_reboot?()})
  75     end
  76   end
  77
  78   def update(%{body_params: %{configs: configs}} = conn, _) do
  79     with :ok <- configurable_from_database() do
  80       results =
  81         configs
  82         |> Enum.filter(&whitelisted_config?/1)
  83         |> Enum.map(fn
  84           %{group: group, key: key, delete: true} = params ->
  85             ConfigDB.delete(%{group: group, key: key, subkeys: params[:subkeys]})
  86
  87           %{group: group, key: key, value: value} ->
  88             ConfigDB.update_or_create(%{group: group, key: key, value: value})
  89         end)
  90         |> Enum.reject(fn {result, _} -> result == :error end)
  91
  92       {deleted, updated} =
  93         results
  94         |> Enum.map(fn {:ok, config} ->
  95           Map.put(config, :db, ConfigDB.get_db_keys(config))
  96         end)
  97         |> Enum.split_with(fn config ->
  98           Ecto.get_meta(config, :state) == :deleted
  99         end)
 100
 101       Config.TransferTask.load_and_update_env(deleted, false)
 102
 103       if not Restarter.Pleroma.need_reboot?() do
 104         changed_reboot_settings? =
 105           (updated ++ deleted)
 106           |> Enum.any?(fn config ->
 107             group = ConfigDB.from_string(config.group)
 108             key = ConfigDB.from_string(config.key)
 109             value = ConfigDB.from_binary(config.value)
 110             Config.TransferTask.pleroma_need_restart?(group, key, value)
 111           end)
 112
 113         if changed_reboot_settings?, do: Restarter.Pleroma.need_reboot()
 114       end
 115
 116       render(conn, "index.json", %{
 117         configs: updated,
 118         need_reboot: Restarter.Pleroma.need_reboot?()
 119       })
 120     end
 121   end
 122
 123   defp configurable_from_database do
 124     if Config.get(:configurable_from_database) do
 125       :ok
 126     else
 127       {:error, "To use this endpoint you need to enable configuration from database."}
 128     end
 129   end
 130
 131   defp whitelisted_config?(group, key) do
 132     if whitelisted_configs = Config.get(:database_config_whitelist) do
 133       Enum.any?(whitelisted_configs, fn
 134         {whitelisted_group} ->
 135           group == inspect(whitelisted_group)
 136
 137         {whitelisted_group, whitelisted_key} ->
 138           group == inspect(whitelisted_group) && key == inspect(whitelisted_key)
 139       end)
 140     else
 141       true
 142     end
 143   end
 144
 145   defp whitelisted_config?(%{group: group, key: key}) do
 146     whitelisted_config?(group, key)
 147   end
 148
 149   defp whitelisted_config?(%{group: group} = config) do
 150     whitelisted_config?(group, config[:key])
 151   end
 152 end