git.squeep.com Git - akkoma/blob - lib/pleroma/web/admin_api/config.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.AdminAPI.Config do
   6   use Ecto.Schema
   7   import Ecto.Changeset
   8   import Pleroma.Web.Gettext
   9   alias __MODULE__
  10   alias Pleroma.Repo
  11
  12   @type t :: %__MODULE__{}
  13
  14   schema "config" do
  15     field(:key, :string)
  16     field(:group, :string)
  17     field(:value, :binary)
  18
  19     timestamps()
  20   end
  21
  22   @spec get_by_params(map()) :: Config.t() | nil
  23   def get_by_params(params), do: Repo.get_by(Config, params)
  24
  25   @spec changeset(Config.t(), map()) :: Changeset.t()
  26   def changeset(config, params \\ %{}) do
  27     config
  28     |> cast(params, [:key, :group, :value])
  29     |> validate_required([:key, :group, :value])
  30     |> unique_constraint(:key, name: :config_group_key_index)
  31   end
  32
  33   @spec create(map()) :: {:ok, Config.t()} | {:error, Changeset.t()}
  34   def create(params) do
  35     %Config{}
  36     |> changeset(Map.put(params, :value, transform(params[:value])))
  37     |> Repo.insert()
  38   end
  39
  40   @spec update(Config.t(), map()) :: {:ok, Config} | {:error, Changeset.t()}
  41   def update(%Config{} = config, %{value: value}) do
  42     config
  43     |> change(value: transform(value))
  44     |> Repo.update()
  45   end
  46
  47   @spec update_or_create(map()) :: {:ok, Config.t()} | {:error, Changeset.t()}
  48   def update_or_create(params) do
  49     with %Config{} = config <- Config.get_by_params(Map.take(params, [:group, :key])) do
  50       Config.update(config, params)
  51     else
  52       nil -> Config.create(params)
  53     end
  54   end
  55
  56   @spec delete(map()) :: {:ok, Config.t()} | {:error, Changeset.t()}
  57   def delete(params) do
  58     with %Config{} = config <- Config.get_by_params(params) do
  59       Repo.delete(config)
  60     else
  61       nil ->
  62         err =
  63           dgettext("errors", "Config with params %{params} not found", params: inspect(params))
  64
  65         {:error, err}
  66     end
  67   end
  68
  69   @spec from_binary(binary()) :: term()
  70   def from_binary(binary), do: :erlang.binary_to_term(binary)
  71
  72   @spec from_binary_with_convert(binary()) :: any()
  73   def from_binary_with_convert(binary) do
  74     from_binary(binary)
  75     |> do_convert()
  76   end
  77
  78   defp do_convert(entity) when is_list(entity) do
  79     for v <- entity, into: [], do: do_convert(v)
  80   end
  81
  82   defp do_convert(entity) when is_map(entity) do
  83     for {k, v} <- entity, into: %{}, do: {do_convert(k), do_convert(v)}
  84   end
  85
  86   defp do_convert({:dispatch, [entity]}), do: %{"tuple" => [":dispatch", [inspect(entity)]]}
  87
  88   defp do_convert(entity) when is_tuple(entity),
  89     do: %{"tuple" => do_convert(Tuple.to_list(entity))}
  90
  91   defp do_convert(entity) when is_boolean(entity) or is_number(entity) or is_nil(entity),
  92     do: entity
  93
  94   defp do_convert(entity) when is_atom(entity) do
  95     string = to_string(entity)
  96
  97     if String.starts_with?(string, "Elixir."),
  98       do: do_convert(string),
  99       else: ":" <> string
 100   end
 101
 102   defp do_convert("Elixir." <> module_name), do: module_name
 103
 104   defp do_convert(entity) when is_binary(entity), do: entity
 105
 106   @spec transform(any()) :: binary()
 107   def transform(entity) when is_binary(entity) or is_map(entity) or is_list(entity) do
 108     :erlang.term_to_binary(do_transform(entity))
 109   end
 110
 111   def transform(entity), do: :erlang.term_to_binary(entity)
 112
 113   defp do_transform(%Regex{} = entity) when is_map(entity), do: entity
 114
 115   defp do_transform(%{"tuple" => [":dispatch", [entity]]}) do
 116     cleaned_string = String.replace(entity, ~r/[^\w|^{:,[|^,|^[|^\]^}|^\/|^\.|^"]^\s/, "")
 117     {dispatch_settings, []} = Code.eval_string(cleaned_string, [], requires: [], macros: [])
 118     {:dispatch, [dispatch_settings]}
 119   end
 120
 121   defp do_transform(%{"tuple" => entity}) do
 122     Enum.reduce(entity, {}, fn val, acc -> Tuple.append(acc, do_transform(val)) end)
 123   end
 124
 125   defp do_transform(entity) when is_map(entity) do
 126     for {k, v} <- entity, into: %{}, do: {do_transform(k), do_transform(v)}
 127   end
 128
 129   defp do_transform(entity) when is_list(entity) do
 130     for v <- entity, into: [], do: do_transform(v)
 131   end
 132
 133   defp do_transform(entity) when is_binary(entity) do
 134     String.trim(entity)
 135     |> do_transform_string()
 136   end
 137
 138   defp do_transform(entity), do: entity
 139
 140   defp do_transform_string("~r/" <> pattern) do
 141     pattern = String.trim_trailing(pattern, "/")
 142     ~r/#{pattern}/
 143   end
 144
 145   defp do_transform_string(":" <> atom), do: String.to_atom(atom)
 146
 147   defp do_transform_string(value) do
 148     if String.starts_with?(value, "Pleroma") or String.starts_with?(value, "Phoenix"),
 149       do: String.to_existing_atom("Elixir." <> value),
 150       else: value
 151   end
 152 end