git.squeep.com Git - akkoma/blob - lib/pleroma/web/admin_api/config.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.AdminAPI.Config do
   6   use Ecto.Schema
   7   import Ecto.Changeset
   8   import Pleroma.Web.Gettext
   9   alias __MODULE__
  10   alias Pleroma.Repo
  11
  12   @type t :: %__MODULE__{}
  13
  14   schema "config" do
  15     field(:key, :string)
  16     field(:group, :string)
  17     field(:value, :binary)
  18
  19     timestamps()
  20   end
  21
  22   @spec get_by_params(map()) :: Config.t() | nil
  23   def get_by_params(params), do: Repo.get_by(Config, params)
  24
  25   @spec changeset(Config.t(), map()) :: Changeset.t()
  26   def changeset(config, params \\ %{}) do
  27     params = Map.put(params, :value, transform(params[:value]))
  28
  29     config
  30     |> cast(params, [:key, :group, :value])
  31     |> validate_required([:key, :group, :value])
  32     |> unique_constraint(:key, name: :config_group_key_index)
  33   end
  34
  35   @spec create(map()) :: {:ok, Config.t()} | {:error, Changeset.t()}
  36   def create(params) do
  37     %Config{}
  38     |> changeset(params)
  39     |> Repo.insert()
  40   end
  41
  42   @spec update(Config.t(), map()) :: {:ok, Config} | {:error, Changeset.t()}
  43   def update(%Config{} = config, %{value: value}) do
  44     config
  45     |> changeset(%{value: value})
  46     |> Repo.update()
  47   end
  48
  49   @full_key_update [
  50     {:pleroma, :ecto_repos},
  51     {:quack, :meta},
  52     {:mime, :types},
  53     {:cors_plug, [:max_age, :methods, :expose, :headers]},
  54     {:auto_linker, :opts},
  55     {:swarm, :node_blacklist},
  56     {:logger, :backends}
  57   ]
  58
  59   defp only_full_update?(%Config{} = config) do
  60     config_group = Config.from_string(config.group)
  61     config_key = Config.from_string(config.key)
  62
  63     Enum.any?(@full_key_update, fn
  64       {group, key} when is_list(key) ->
  65         config_group == group and config_key in key
  66
  67       {group, key} ->
  68         config_group == group and config_key == key
  69     end)
  70   end
  71
  72   defp can_be_partially_updated?(%Config{} = config), do: not only_full_update?(config)
  73
  74   @spec update_or_create(map()) :: {:ok, Config.t()} | {:error, Changeset.t()}
  75   def update_or_create(params) do
  76     search_opts = Map.take(params, [:group, :key])
  77
  78     with %Config{} = config <- Config.get_by_params(search_opts),
  79          {:partial_update, true, config} <-
  80            {:partial_update, can_be_partially_updated?(config), config},
  81          old_value <- from_binary(config.value),
  82          transformed_value <- do_transform(params[:value]),
  83          {:can_be_merged, true, config} <- {:can_be_merged, is_list(transformed_value), config},
  84          new_value <- Keyword.merge(old_value, transformed_value) do
  85       Config.update(config, %{value: new_value, transformed?: true})
  86     else
  87       {reason, false, config} when reason in [:partial_update, :can_be_merged] ->
  88         Config.update(config, params)
  89
  90       nil ->
  91         Config.create(params)
  92     end
  93   end
  94
  95   @spec delete(map()) :: {:ok, Config.t()} | {:error, Changeset.t()} | {:ok, nil}
  96   def delete(params) do
  97     search_opts = Map.delete(params, :subkeys)
  98
  99     with %Config{} = config <- Config.get_by_params(search_opts),
 100          {config, sub_keys} when is_list(sub_keys) <- {config, params[:subkeys]},
 101          old_value <- from_binary(config.value),
 102          keys <- Enum.map(sub_keys, &do_transform_string(&1)),
 103          new_value <- Keyword.drop(old_value, keys) do
 104       Config.update(config, %{value: new_value})
 105     else
 106       {config, nil} ->
 107         Repo.delete(config)
 108         {:ok, nil}
 109
 110       nil ->
 111         err =
 112           dgettext("errors", "Config with params %{params} not found", params: inspect(params))
 113
 114         {:error, err}
 115     end
 116   end
 117
 118   @spec from_binary(binary()) :: term()
 119   def from_binary(binary), do: :erlang.binary_to_term(binary)
 120
 121   @spec from_binary_with_convert(binary()) :: any()
 122   def from_binary_with_convert(binary) do
 123     binary
 124     |> from_binary()
 125     |> do_convert()
 126   end
 127
 128   @spec from_string(String.t()) :: atom() | no_return()
 129   def from_string(":" <> entity), do: String.to_existing_atom(entity)
 130
 131   def from_string(entity) when is_binary(entity) do
 132     if is_module_name?(entity) do
 133       String.to_existing_atom("Elixir.#{entity}")
 134     else
 135       entity
 136     end
 137   end
 138
 139   defp do_convert(entity) when is_list(entity) do
 140     for v <- entity, into: [], do: do_convert(v)
 141   end
 142
 143   defp do_convert(%Regex{} = entity), do: inspect(entity)
 144
 145   defp do_convert(entity) when is_map(entity) do
 146     for {k, v} <- entity, into: %{}, do: {do_convert(k), do_convert(v)}
 147   end
 148
 149   defp do_convert({:proxy_url, {type, :localhost, port}}) do
 150     %{"tuple" => [":proxy_url", %{"tuple" => [do_convert(type), "localhost", port]}]}
 151   end
 152
 153   defp do_convert({:proxy_url, {type, host, port}}) when is_tuple(host) do
 154     ip =
 155       host
 156       |> :inet_parse.ntoa()
 157       |> to_string()
 158
 159     %{
 160       "tuple" => [
 161         ":proxy_url",
 162         %{"tuple" => [do_convert(type), ip, port]}
 163       ]
 164     }
 165   end
 166
 167   defp do_convert({:proxy_url, {type, host, port}}) do
 168     %{
 169       "tuple" => [
 170         ":proxy_url",
 171         %{"tuple" => [do_convert(type), to_string(host), port]}
 172       ]
 173     }
 174   end
 175
 176   defp do_convert({:dispatch, [entity]}), do: %{"tuple" => [":dispatch", [inspect(entity)]]}
 177   # TODO: will become useless after removing hackney
 178   defp do_convert({:partial_chain, entity}), do: %{"tuple" => [":partial_chain", inspect(entity)]}
 179
 180   defp do_convert(entity) when is_tuple(entity),
 181     do: %{"tuple" => do_convert(Tuple.to_list(entity))}
 182
 183   defp do_convert(entity) when is_boolean(entity) or is_number(entity) or is_nil(entity),
 184     do: entity
 185
 186   defp do_convert(entity) when is_atom(entity), do: inspect(entity)
 187
 188   defp do_convert(entity) when is_binary(entity), do: entity
 189
 190   @spec transform(any()) :: binary() | no_return()
 191   def transform(entity) when is_binary(entity) or is_map(entity) or is_list(entity) do
 192     entity
 193     |> do_transform()
 194     |> to_binary()
 195   end
 196
 197   def transform(entity), do: to_binary(entity)
 198
 199   @spec to_binary(any()) :: binary()
 200   def to_binary(entity), do: :erlang.term_to_binary(entity)
 201
 202   defp do_transform(%Regex{} = entity), do: entity
 203
 204   defp do_transform(%{"tuple" => [":proxy_url", %{"tuple" => [type, host, port]}]}) do
 205     {:proxy_url, {do_transform_string(type), parse_host(host), port}}
 206   end
 207
 208   defp do_transform(%{"tuple" => [":dispatch", [entity]]}) do
 209     {dispatch_settings, []} = do_eval(entity)
 210     {:dispatch, [dispatch_settings]}
 211   end
 212
 213   # TODO: will become useless after removing hackney
 214   defp do_transform(%{"tuple" => [":partial_chain", entity]}) do
 215     {partial_chain, []} = do_eval(entity)
 216     {:partial_chain, partial_chain}
 217   end
 218
 219   defp do_transform(%{"tuple" => entity}) do
 220     Enum.reduce(entity, {}, fn val, acc -> Tuple.append(acc, do_transform(val)) end)
 221   end
 222
 223   defp do_transform(entity) when is_map(entity) do
 224     for {k, v} <- entity, into: %{}, do: {do_transform(k), do_transform(v)}
 225   end
 226
 227   defp do_transform(entity) when is_list(entity) do
 228     for v <- entity, into: [], do: do_transform(v)
 229   end
 230
 231   defp do_transform(entity) when is_binary(entity) do
 232     entity
 233     |> String.trim()
 234     |> do_transform_string()
 235   end
 236
 237   defp do_transform(entity), do: entity
 238
 239   defp parse_host("localhost"), do: :localhost
 240
 241   defp parse_host(host) do
 242     charlist = to_charlist(host)
 243
 244     case :inet.parse_address(charlist) do
 245       {:error, :einval} ->
 246         charlist
 247
 248       {:ok, ip} ->
 249         ip
 250     end
 251   end
 252
 253   @delimiters ["/", "|", "\"", "'", {"(", ")"}, {"[", "]"}, {"{", "}"}, {"<", ">"}]
 254
 255   defp find_valid_delimiter([], _string, _),
 256     do: raise(ArgumentError, message: "valid delimiter for Regex expression not found")
 257
 258   defp find_valid_delimiter([{leading, closing} = delimiter | others], pattern, regex_delimiter)
 259        when is_tuple(delimiter) do
 260     if String.contains?(pattern, closing) do
 261       find_valid_delimiter(others, pattern, regex_delimiter)
 262     else
 263       {:ok, {leading, closing}}
 264     end
 265   end
 266
 267   defp find_valid_delimiter([delimiter | others], pattern, regex_delimiter) do
 268     if String.contains?(pattern, delimiter) do
 269       find_valid_delimiter(others, pattern, regex_delimiter)
 270     else
 271       {:ok, {delimiter, delimiter}}
 272     end
 273   end
 274
 275   @regex_parts ~r/^~r(?'delimiter'[\/|"'([{<]{1})(?'pattern'.+)[\/|"')\]}>]{1}(?'modifier'[uismxfU]*)/u
 276
 277   defp do_transform_string("~r" <> _pattern = regex) do
 278     with %{"modifier" => modifier, "pattern" => pattern, "delimiter" => regex_delimiter} <-
 279            Regex.named_captures(@regex_parts, regex),
 280          {:ok, {leading, closing}} <- find_valid_delimiter(@delimiters, pattern, regex_delimiter),
 281          {result, _} <- Code.eval_string("~r#{leading}#{pattern}#{closing}#{modifier}") do
 282       result
 283     end
 284   end
 285
 286   defp do_transform_string(":" <> atom), do: String.to_atom(atom)
 287
 288   defp do_transform_string(value) do
 289     if is_module_name?(value) do
 290       String.to_existing_atom("Elixir." <> value)
 291     else
 292       value
 293     end
 294   end
 295
 296   @spec is_module_name?(String.t()) :: boolean()
 297   def is_module_name?(string) do
 298     Regex.match?(~r/^(Pleroma|Phoenix|Tesla)\./, string) or string in ["Oban", "Ueberauth"]
 299   end
 300
 301   defp do_eval(entity) do
 302     cleaned_string = String.replace(entity, ~r/[^\w|^{:,[|^,|^[|^\]^}|^\/|^\.|^"]^\s/, "")
 303     Code.eval_string(cleaned_string)
 304   end
 305 end