git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/visibility.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.Visibility do
   6   alias Pleroma.Activity
   7   alias Pleroma.Object
   8   alias Pleroma.Repo
   9   alias Pleroma.User
  10
  11   require Pleroma.Constants
  12
  13   @spec is_public?(Object.t() | Activity.t() | map()) :: boolean()
  14   def is_public?(%Object{data: %{"type" => "Tombstone"}}), do: false
  15   def is_public?(%Object{data: data}), do: is_public?(data)
  16   def is_public?(%Activity{data: data}), do: is_public?(data)
  17   def is_public?(%{"directMessage" => true}), do: false
  18   def is_public?(data), do: Pleroma.Constants.as_public() in (data["to"] ++ (data["cc"] || []))
  19
  20   def is_private?(activity) do
  21     with false <- is_public?(activity),
  22          %User{follower_address: follower_address} <-
  23            User.get_cached_by_ap_id(activity.data["actor"]) do
  24       follower_address in activity.data["to"]
  25     else
  26       _ -> false
  27     end
  28   end
  29
  30   def is_announceable?(activity, user) do
  31     is_public?(activity) || activity.data["actor"] == user.ap_id
  32   end
  33
  34   def is_direct?(%Activity{data: %{"directMessage" => true}}), do: true
  35   def is_direct?(%Object{data: %{"directMessage" => true}}), do: true
  36
  37   def is_direct?(activity) do
  38     !is_public?(activity) && !is_private?(activity)
  39   end
  40
  41   def is_list?(%{data: %{"listMessage" => _}}), do: true
  42   def is_list?(_), do: false
  43
  44   def visible_for_user?(%{actor: ap_id}, %User{ap_id: ap_id}), do: true
  45
  46   def visible_for_user?(%{data: %{"listMessage" => list_ap_id}} = activity, %User{} = user) do
  47     user.ap_id in activity.data["to"] ||
  48       list_ap_id
  49       |> Pleroma.List.get_by_ap_id()
  50       |> Pleroma.List.member?(user)
  51   end
  52
  53   def visible_for_user?(%{data: %{"listMessage" => _}}, nil), do: false
  54
  55   def visible_for_user?(activity, nil) do
  56     is_public?(activity)
  57   end
  58
  59   def visible_for_user?(activity, user) do
  60     x = [user.ap_id | user.following]
  61     y = [activity.actor] ++ activity.data["to"] ++ (activity.data["cc"] || [])
  62     visible_for_user?(activity, nil) || Enum.any?(x, &(&1 in y))
  63   end
  64
  65   def entire_thread_visible_for_user?(%Activity{} = activity, %User{} = user) do
  66     {:ok, %{rows: [[result]]}} =
  67       Ecto.Adapters.SQL.query(Repo, "SELECT thread_visibility($1, $2)", [
  68         user.ap_id,
  69         activity.data["id"]
  70       ])
  71
  72     result
  73   end
  74
  75   def get_visibility(object) do
  76     to = object.data["to"] || []
  77     cc = object.data["cc"] || []
  78
  79     cond do
  80       Pleroma.Constants.as_public() in to ->
  81         "public"
  82
  83       Pleroma.Constants.as_public() in cc ->
  84         "unlisted"
  85
  86       # this should use the sql for the object's activity
  87       Enum.any?(to, &String.contains?(&1, "/followers")) ->
  88         "private"
  89
  90       object.data["directMessage"] == true ->
  91         "direct"
  92
  93       is_binary(object.data["listMessage"]) ->
  94         "list"
  95
  96       length(cc) > 0 ->
  97         "private"
  98
  99       true ->
 100         "direct"
 101     end
 102   end
 103 end