git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/visibility.ex

   1 defmodule Pleroma.Web.ActivityPub.Visibility do
   2   alias Pleroma.Activity
   3   alias Pleroma.Object
   4   alias Pleroma.User
   5
   6   def is_public?(%Object{data: %{"type" => "Tombstone"}}), do: false
   7   def is_public?(%Object{data: data}), do: is_public?(data)
   8   def is_public?(%Activity{data: data}), do: is_public?(data)
   9   def is_public?(%{"directMessage" => true}), do: false
  10
  11   def is_public?(data) do
  12     "https://www.w3.org/ns/activitystreams#Public" in (data["to"] ++ (data["cc"] || []))
  13   end
  14
  15   def is_private?(activity) do
  16     unless is_public?(activity) do
  17       follower_address = User.get_cached_by_ap_id(activity.data["actor"]).follower_address
  18       Enum.any?(activity.data["to"], &(&1 == follower_address))
  19     else
  20       false
  21     end
  22   end
  23
  24   def is_direct?(%Activity{data: %{"directMessage" => true}}), do: true
  25   def is_direct?(%Object{data: %{"directMessage" => true}}), do: true
  26
  27   def is_direct?(activity) do
  28     !is_public?(activity) && !is_private?(activity)
  29   end
  30
  31   def visible_for_user?(activity, nil) do
  32     is_public?(activity)
  33   end
  34
  35   def visible_for_user?(activity, user) do
  36     x = [user.ap_id | user.following]
  37     y = [activity.actor] ++ activity.data["to"] ++ (activity.data["cc"] || [])
  38     visible_for_user?(activity, nil) || Enum.any?(x, &(&1 in y))
  39   end
  40
  41   # guard
  42   def entire_thread_visible_for_user?(nil, _user), do: false
  43
  44   # child
  45   def entire_thread_visible_for_user?(
  46         %Activity{data: %{"object" => %{"inReplyTo" => parent_id}}} = tail,
  47         user
  48       )
  49       when is_binary(parent_id) do
  50     parent = Activity.get_in_reply_to_activity(tail)
  51     visible_for_user?(tail, user) && entire_thread_visible_for_user?(parent, user)
  52   end
  53
  54   # root
  55   def entire_thread_visible_for_user?(tail, user), do: visible_for_user?(tail, user)
  56 end