git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/views/user_view.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.UserView do
   6   use Pleroma.Web, :view
   7
   8   alias Pleroma.Keys
   9   alias Pleroma.Repo
  10   alias Pleroma.User
  11   alias Pleroma.Web.ActivityPub.ActivityPub
  12   alias Pleroma.Web.ActivityPub.Transmogrifier
  13   alias Pleroma.Web.ActivityPub.Utils
  14   alias Pleroma.Web.Endpoint
  15   alias Pleroma.Web.Router.Helpers
  16
  17   import Ecto.Query
  18
  19   def render("endpoints.json", %{user: %User{nickname: nil, local: true} = _user}) do
  20     %{"sharedInbox" => Helpers.activity_pub_url(Endpoint, :inbox)}
  21   end
  22
  23   def render("endpoints.json", %{user: %User{local: true} = _user}) do
  24     %{
  25       "oauthAuthorizationEndpoint" => Helpers.o_auth_url(Endpoint, :authorize),
  26       "oauthRegistrationEndpoint" => Helpers.mastodon_api_url(Endpoint, :create_app),
  27       "oauthTokenEndpoint" => Helpers.o_auth_url(Endpoint, :token_exchange),
  28       "sharedInbox" => Helpers.activity_pub_url(Endpoint, :inbox)
  29     }
  30   end
  31
  32   def render("endpoints.json", _), do: %{}
  33
  34   def render("service.json", %{user: user}) do
  35     {:ok, user} = User.ensure_keys_present(user)
  36     {:ok, _, public_key} = Keys.keys_from_pem(user.info.keys)
  37     public_key = :public_key.pem_entry_encode(:SubjectPublicKeyInfo, public_key)
  38     public_key = :public_key.pem_encode([public_key])
  39
  40     endpoints = render("endpoints.json", %{user: user})
  41
  42     %{
  43       "id" => user.ap_id,
  44       "type" => "Application",
  45       "following" => "#{user.ap_id}/following",
  46       "followers" => "#{user.ap_id}/followers",
  47       "inbox" => "#{user.ap_id}/inbox",
  48       "name" => "Pleroma",
  49       "summary" =>
  50         "An internal service actor for this Pleroma instance.  No user-serviceable parts inside.",
  51       "url" => user.ap_id,
  52       "manuallyApprovesFollowers" => false,
  53       "publicKey" => %{
  54         "id" => "#{user.ap_id}#main-key",
  55         "owner" => user.ap_id,
  56         "publicKeyPem" => public_key
  57       },
  58       "endpoints" => endpoints
  59     }
  60     |> Map.merge(Utils.make_json_ld_header())
  61   end
  62
  63   # the instance itself is not a Person, but instead an Application
  64   def render("user.json", %{user: %User{nickname: nil} = user}),
  65     do: render("service.json", %{user: user})
  66
  67   def render("user.json", %{user: %User{nickname: "internal." <> _} = user}),
  68     do: render("service.json", %{user: user}) |> Map.put("preferredUsername", user.nickname)
  69
  70   def render("user.json", %{user: user}) do
  71     {:ok, user} = User.ensure_keys_present(user)
  72     {:ok, _, public_key} = Keys.keys_from_pem(user.info.keys)
  73     public_key = :public_key.pem_entry_encode(:SubjectPublicKeyInfo, public_key)
  74     public_key = :public_key.pem_encode([public_key])
  75
  76     endpoints = render("endpoints.json", %{user: user})
  77
  78     user_tags =
  79       user
  80       |> Transmogrifier.add_emoji_tags()
  81       |> Map.get("tag", [])
  82
  83     fields =
  84       user.info
  85       |> User.Info.fields()
  86       |> Enum.map(&Map.put(&1, "type", "PropertyValue"))
  87       |> Enum.map(fn f -> Map.update!(f, "value", &AutoLinker.link(&1)) end)
  88
  89     %{
  90       "id" => user.ap_id,
  91       "type" => "Person",
  92       "following" => "#{user.ap_id}/following",
  93       "followers" => "#{user.ap_id}/followers",
  94       "inbox" => "#{user.ap_id}/inbox",
  95       "outbox" => "#{user.ap_id}/outbox",
  96       "preferredUsername" => user.nickname,
  97       "name" => user.name,
  98       "summary" => user.bio,
  99       "url" => user.ap_id,
 100       "manuallyApprovesFollowers" => user.info.locked,
 101       "publicKey" => %{
 102         "id" => "#{user.ap_id}#main-key",
 103         "owner" => user.ap_id,
 104         "publicKeyPem" => public_key
 105       },
 106       "endpoints" => endpoints,
 107       "attachment" => fields,
 108       "tag" => (user.info.source_data["tag"] || []) ++ user_tags
 109     }
 110     |> Map.merge(maybe_make_image(&User.avatar_url/2, "icon", user))
 111     |> Map.merge(maybe_make_image(&User.banner_url/2, "image", user))
 112     |> Map.merge(Utils.make_json_ld_header())
 113   end
 114
 115   def render("following.json", %{user: user, page: page} = opts) do
 116     showing = (opts[:for] && opts[:for] == user) || !user.info.hide_follows
 117     query = User.get_friends_query(user)
 118     query = from(user in query, select: [:ap_id])
 119     following = Repo.all(query)
 120
 121     total =
 122       if showing do
 123         length(following)
 124       else
 125         0
 126       end
 127
 128     collection(following, "#{user.ap_id}/following", page, showing, total)
 129     |> Map.merge(Utils.make_json_ld_header())
 130   end
 131
 132   def render("following.json", %{user: user} = opts) do
 133     showing = (opts[:for] && opts[:for] == user) || !user.info.hide_follows
 134     query = User.get_friends_query(user)
 135     query = from(user in query, select: [:ap_id])
 136     following = Repo.all(query)
 137
 138     total =
 139       if showing do
 140         length(following)
 141       else
 142         0
 143       end
 144
 145     %{
 146       "id" => "#{user.ap_id}/following",
 147       "type" => "OrderedCollection",
 148       "totalItems" => total,
 149       "first" =>
 150         if showing do
 151           collection(following, "#{user.ap_id}/following", 1, !user.info.hide_follows)
 152         else
 153           "#{user.ap_id}/following?page=1"
 154         end
 155     }
 156     |> Map.merge(Utils.make_json_ld_header())
 157   end
 158
 159   def render("followers.json", %{user: user, page: page} = opts) do
 160     showing = (opts[:for] && opts[:for] == user) || !user.info.hide_followers
 161
 162     query = User.get_followers_query(user)
 163     query = from(user in query, select: [:ap_id])
 164     followers = Repo.all(query)
 165
 166     total =
 167       if showing do
 168         length(followers)
 169       else
 170         0
 171       end
 172
 173     collection(followers, "#{user.ap_id}/followers", page, showing, total)
 174     |> Map.merge(Utils.make_json_ld_header())
 175   end
 176
 177   def render("followers.json", %{user: user} = opts) do
 178     showing = (opts[:for] && opts[:for] == user) || !user.info.hide_followers
 179
 180     query = User.get_followers_query(user)
 181     query = from(user in query, select: [:ap_id])
 182     followers = Repo.all(query)
 183
 184     total =
 185       if showing do
 186         length(followers)
 187       else
 188         0
 189       end
 190
 191     %{
 192       "id" => "#{user.ap_id}/followers",
 193       "type" => "OrderedCollection",
 194       "totalItems" => total,
 195       "first" =>
 196         if showing do
 197           collection(followers, "#{user.ap_id}/followers", 1, showing, total)
 198         else
 199           "#{user.ap_id}/followers?page=1"
 200         end
 201     }
 202     |> Map.merge(Utils.make_json_ld_header())
 203   end
 204
 205   def render("outbox.json", %{user: user, max_id: max_qid}) do
 206     params = %{
 207       "limit" => "10"
 208     }
 209
 210     params =
 211       if max_qid != nil do
 212         Map.put(params, "max_id", max_qid)
 213       else
 214         params
 215       end
 216
 217     activities = ActivityPub.fetch_user_activities(user, nil, params)
 218
 219     {max_id, min_id, collection} =
 220       if length(activities) > 0 do
 221         {
 222           Enum.at(Enum.reverse(activities), 0).id,
 223           Enum.at(activities, 0).id,
 224           Enum.map(activities, fn act ->
 225             {:ok, data} = Transmogrifier.prepare_outgoing(act.data)
 226             data
 227           end)
 228         }
 229       else
 230         {
 231           0,
 232           0,
 233           []
 234         }
 235       end
 236
 237     iri = "#{user.ap_id}/outbox"
 238
 239     page = %{
 240       "id" => "#{iri}?max_id=#{max_id}",
 241       "type" => "OrderedCollectionPage",
 242       "partOf" => iri,
 243       "orderedItems" => collection,
 244       "next" => "#{iri}?max_id=#{min_id}"
 245     }
 246
 247     if max_qid == nil do
 248       %{
 249         "id" => iri,
 250         "type" => "OrderedCollection",
 251         "first" => page
 252       }
 253       |> Map.merge(Utils.make_json_ld_header())
 254     else
 255       page |> Map.merge(Utils.make_json_ld_header())
 256     end
 257   end
 258
 259   def render("inbox.json", %{user: user, max_id: max_qid}) do
 260     params = %{
 261       "limit" => "10"
 262     }
 263
 264     params =
 265       if max_qid != nil do
 266         Map.put(params, "max_id", max_qid)
 267       else
 268         params
 269       end
 270
 271     activities = ActivityPub.fetch_activities([user.ap_id | user.following], params)
 272
 273     min_id = Enum.at(Enum.reverse(activities), 0).id
 274     max_id = Enum.at(activities, 0).id
 275
 276     collection =
 277       Enum.map(activities, fn act ->
 278         {:ok, data} = Transmogrifier.prepare_outgoing(act.data)
 279         data
 280       end)
 281
 282     iri = "#{user.ap_id}/inbox"
 283
 284     page = %{
 285       "id" => "#{iri}?max_id=#{max_id}",
 286       "type" => "OrderedCollectionPage",
 287       "partOf" => iri,
 288       "orderedItems" => collection,
 289       "next" => "#{iri}?max_id=#{min_id}"
 290     }
 291
 292     if max_qid == nil do
 293       %{
 294         "id" => iri,
 295         "type" => "OrderedCollection",
 296         "first" => page
 297       }
 298       |> Map.merge(Utils.make_json_ld_header())
 299     else
 300       page |> Map.merge(Utils.make_json_ld_header())
 301     end
 302   end
 303
 304   def collection(collection, iri, page, show_items \\ true, total \\ nil) do
 305     offset = (page - 1) * 10
 306     items = Enum.slice(collection, offset, 10)
 307     items = Enum.map(items, fn user -> user.ap_id end)
 308     total = total || length(collection)
 309
 310     map = %{
 311       "id" => "#{iri}?page=#{page}",
 312       "type" => "OrderedCollectionPage",
 313       "partOf" => iri,
 314       "totalItems" => total,
 315       "orderedItems" => if(show_items, do: items, else: [])
 316     }
 317
 318     if offset < total do
 319       Map.put(map, "next", "#{iri}?page=#{page + 1}")
 320     else
 321       map
 322     end
 323   end
 324
 325   defp maybe_make_image(func, key, user) do
 326     if image = func.(user, no_default: true) do
 327       %{
 328         key => %{
 329           "type" => "Image",
 330           "url" => image
 331         }
 332       }
 333     else
 334       %{}
 335     end
 336   end
 337 end