git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/views/user_view.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.UserView do
   6   use Pleroma.Web, :view
   7
   8   alias Pleroma.Web.WebFinger
   9   alias Pleroma.Web.Salmon
  10   alias Pleroma.User
  11   alias Pleroma.Repo
  12   alias Pleroma.Web.ActivityPub.ActivityPub
  13   alias Pleroma.Web.ActivityPub.Transmogrifier
  14   alias Pleroma.Web.ActivityPub.Utils
  15
  16   import Ecto.Query
  17
  18   def render("endpoints.json", %{user: %User{local: true} = _user}) do
  19     %{
  20       "oauthAuthorizationEndpoint" => "#{Pleroma.Web.Endpoint.url()}/oauth/authorize",
  21       "oauthRegistrationEndpoint" => "#{Pleroma.Web.Endpoint.url()}/api/v1/apps",
  22       "oauthTokenEndpoint" => "#{Pleroma.Web.Endpoint.url()}/oauth/token"
  23     }
  24     |> Map.merge(render("endpoints.json", %{user: nil}))
  25   end
  26
  27   def render("endpoints.json", _) do
  28     %{
  29       "sharedInbox" => "#{Pleroma.Web.Endpoint.url()}/inbox"
  30     }
  31   end
  32
  33   # the instance itself is not a Person, but instead an Application
  34   def render("user.json", %{user: %{nickname: nil} = user}) do
  35     {:ok, user} = WebFinger.ensure_keys_present(user)
  36     {:ok, _, public_key} = Salmon.keys_from_pem(user.info.keys)
  37     public_key = :public_key.pem_entry_encode(:SubjectPublicKeyInfo, public_key)
  38     public_key = :public_key.pem_encode([public_key])
  39
  40     endpoints = render("endpoints.json", %{user: user})
  41
  42     %{
  43       "id" => user.ap_id,
  44       "type" => "Application",
  45       "following" => "#{user.ap_id}/following",
  46       "followers" => "#{user.ap_id}/followers",
  47       "inbox" => "#{user.ap_id}/inbox",
  48       "name" => "Pleroma",
  49       "summary" => "Virtual actor for Pleroma relay",
  50       "url" => user.ap_id,
  51       "manuallyApprovesFollowers" => false,
  52       "publicKey" => %{
  53         "id" => "#{user.ap_id}#main-key",
  54         "owner" => user.ap_id,
  55         "publicKeyPem" => public_key
  56       },
  57       "endpoints" => endpoints
  58     }
  59     |> Map.merge(Utils.make_json_ld_header())
  60   end
  61
  62   def render("user.json", %{user: user}) do
  63     {:ok, user} = WebFinger.ensure_keys_present(user)
  64     {:ok, _, public_key} = Salmon.keys_from_pem(user.info.keys)
  65     public_key = :public_key.pem_entry_encode(:SubjectPublicKeyInfo, public_key)
  66     public_key = :public_key.pem_encode([public_key])
  67
  68     endpoints = render("endpoints.json", %{user: user})
  69
  70     %{
  71       "id" => user.ap_id,
  72       "type" => "Person",
  73       "following" => "#{user.ap_id}/following",
  74       "followers" => "#{user.ap_id}/followers",
  75       "inbox" => "#{user.ap_id}/inbox",
  76       "outbox" => "#{user.ap_id}/outbox",
  77       "preferredUsername" => user.nickname,
  78       "name" => user.name,
  79       "summary" => user.bio,
  80       "url" => user.ap_id,
  81       "manuallyApprovesFollowers" => user.info.locked,
  82       "publicKey" => %{
  83         "id" => "#{user.ap_id}#main-key",
  84         "owner" => user.ap_id,
  85         "publicKeyPem" => public_key
  86       },
  87       "endpoints" => endpoints,
  88       "icon" => %{
  89         "type" => "Image",
  90         "url" => User.avatar_url(user)
  91       },
  92       "image" => %{
  93         "type" => "Image",
  94         "url" => User.banner_url(user)
  95       },
  96       "tag" => user.info.source_data["tag"] || []
  97     }
  98     |> Map.merge(Utils.make_json_ld_header())
  99   end
 100
 101   def render("following.json", %{user: user, page: page}) do
 102     query = User.get_friends_query(user)
 103     query = from(user in query, select: [:ap_id])
 104     following = Repo.all(query)
 105
 106     collection(following, "#{user.ap_id}/following", page, !user.info.hide_follows)
 107     |> Map.merge(Utils.make_json_ld_header())
 108   end
 109
 110   def render("following.json", %{user: user}) do
 111     query = User.get_friends_query(user)
 112     query = from(user in query, select: [:ap_id])
 113     following = Repo.all(query)
 114
 115     %{
 116       "id" => "#{user.ap_id}/following",
 117       "type" => "OrderedCollection",
 118       "totalItems" => length(following),
 119       "first" => collection(following, "#{user.ap_id}/following", 1, !user.info.hide_follows)
 120     }
 121     |> Map.merge(Utils.make_json_ld_header())
 122   end
 123
 124   def render("followers.json", %{user: user, page: page}) do
 125     query = User.get_followers_query(user)
 126     query = from(user in query, select: [:ap_id])
 127     followers = Repo.all(query)
 128
 129     collection(followers, "#{user.ap_id}/followers", page, !user.info.hide_followers)
 130     |> Map.merge(Utils.make_json_ld_header())
 131   end
 132
 133   def render("followers.json", %{user: user}) do
 134     query = User.get_followers_query(user)
 135     query = from(user in query, select: [:ap_id])
 136     followers = Repo.all(query)
 137
 138     %{
 139       "id" => "#{user.ap_id}/followers",
 140       "type" => "OrderedCollection",
 141       "totalItems" => length(followers),
 142       "first" => collection(followers, "#{user.ap_id}/followers", 1, !user.info.hide_followers)
 143     }
 144     |> Map.merge(Utils.make_json_ld_header())
 145   end
 146
 147   def render("outbox.json", %{user: user, max_id: max_qid}) do
 148     # XXX: technically note_count is wrong for this, but it's better than nothing
 149     info = User.user_info(user)
 150
 151     params = %{
 152       "limit" => "10"
 153     }
 154
 155     params =
 156       if max_qid != nil do
 157         Map.put(params, "max_id", max_qid)
 158       else
 159         params
 160       end
 161
 162     activities = ActivityPub.fetch_user_activities(user, nil, params)
 163     min_id = Enum.at(Enum.reverse(activities), 0).id
 164     max_id = Enum.at(activities, 0).id
 165
 166     collection =
 167       Enum.map(activities, fn act ->
 168         {:ok, data} = Transmogrifier.prepare_outgoing(act.data)
 169         data
 170       end)
 171
 172     iri = "#{user.ap_id}/outbox"
 173
 174     page = %{
 175       "id" => "#{iri}?max_id=#{max_id}",
 176       "type" => "OrderedCollectionPage",
 177       "partOf" => iri,
 178       "totalItems" => info.note_count,
 179       "orderedItems" => collection,
 180       "next" => "#{iri}?max_id=#{min_id}"
 181     }
 182
 183     if max_qid == nil do
 184       %{
 185         "id" => iri,
 186         "type" => "OrderedCollection",
 187         "totalItems" => info.note_count,
 188         "first" => page
 189       }
 190       |> Map.merge(Utils.make_json_ld_header())
 191     else
 192       page |> Map.merge(Utils.make_json_ld_header())
 193     end
 194   end
 195
 196   def render("inbox.json", %{user: user, max_id: max_qid}) do
 197     params = %{
 198       "limit" => "10"
 199     }
 200
 201     params =
 202       if max_qid != nil do
 203         Map.put(params, "max_id", max_qid)
 204       else
 205         params
 206       end
 207
 208     activities = ActivityPub.fetch_activities([user.ap_id | user.following], params)
 209
 210     min_id = Enum.at(Enum.reverse(activities), 0).id
 211     max_id = Enum.at(activities, 0).id
 212
 213     collection =
 214       Enum.map(activities, fn act ->
 215         {:ok, data} = Transmogrifier.prepare_outgoing(act.data)
 216         data
 217       end)
 218
 219     iri = "#{user.ap_id}/inbox"
 220
 221     page = %{
 222       "id" => "#{iri}?max_id=#{max_id}",
 223       "type" => "OrderedCollectionPage",
 224       "partOf" => iri,
 225       "totalItems" => -1,
 226       "orderedItems" => collection,
 227       "next" => "#{iri}?max_id=#{min_id}"
 228     }
 229
 230     if max_qid == nil do
 231       %{
 232         "id" => iri,
 233         "type" => "OrderedCollection",
 234         "totalItems" => -1,
 235         "first" => page
 236       }
 237       |> Map.merge(Utils.make_json_ld_header())
 238     else
 239       page |> Map.merge(Utils.make_json_ld_header())
 240     end
 241   end
 242
 243   def collection(collection, iri, page, show_items \\ true, total \\ nil) do
 244     offset = (page - 1) * 10
 245     items = Enum.slice(collection, offset, 10)
 246     items = Enum.map(items, fn user -> user.ap_id end)
 247     total = total || length(collection)
 248
 249     map = %{
 250       "id" => "#{iri}?page=#{page}",
 251       "type" => "OrderedCollectionPage",
 252       "partOf" => iri,
 253       "totalItems" => total,
 254       "orderedItems" => if(show_items, do: items, else: [])
 255     }
 256
 257     if offset < total do
 258       Map.put(map, "next", "#{iri}?page=#{page + 1}")
 259     else
 260       map
 261     end
 262   end
 263 end