git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/views/user_view.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.UserView do
   6   use Pleroma.Web, :view
   7
   8   alias Pleroma.Keys
   9   alias Pleroma.Repo
  10   alias Pleroma.User
  11   alias Pleroma.Web.ActivityPub.Transmogrifier
  12   alias Pleroma.Web.ActivityPub.Utils
  13   alias Pleroma.Web.Endpoint
  14   alias Pleroma.Web.Router.Helpers
  15
  16   import Ecto.Query
  17
  18   def render("endpoints.json", %{user: %User{nickname: nil, local: true} = _user}) do
  19     %{"sharedInbox" => Helpers.activity_pub_url(Endpoint, :inbox)}
  20   end
  21
  22   def render("endpoints.json", %{user: %User{local: true} = _user}) do
  23     %{
  24       "oauthAuthorizationEndpoint" => Helpers.o_auth_url(Endpoint, :authorize),
  25       "oauthRegistrationEndpoint" => Helpers.app_url(Endpoint, :create),
  26       "oauthTokenEndpoint" => Helpers.o_auth_url(Endpoint, :token_exchange),
  27       "sharedInbox" => Helpers.activity_pub_url(Endpoint, :inbox),
  28       "uploadMedia" => Helpers.activity_pub_url(Endpoint, :upload_media)
  29     }
  30   end
  31
  32   def render("endpoints.json", _), do: %{}
  33
  34   def render("service.json", %{user: user}) do
  35     {:ok, user} = User.ensure_keys_present(user)
  36     {:ok, _, public_key} = Keys.keys_from_pem(user.keys)
  37     public_key = :public_key.pem_entry_encode(:SubjectPublicKeyInfo, public_key)
  38     public_key = :public_key.pem_encode([public_key])
  39
  40     endpoints = render("endpoints.json", %{user: user})
  41
  42     %{
  43       "id" => user.ap_id,
  44       "type" => "Application",
  45       "following" => "#{user.ap_id}/following",
  46       "followers" => "#{user.ap_id}/followers",
  47       "inbox" => "#{user.ap_id}/inbox",
  48       "name" => "Pleroma",
  49       "summary" =>
  50         "An internal service actor for this Pleroma instance.  No user-serviceable parts inside.",
  51       "url" => user.ap_id,
  52       "manuallyApprovesFollowers" => false,
  53       "publicKey" => %{
  54         "id" => "#{user.ap_id}#main-key",
  55         "owner" => user.ap_id,
  56         "publicKeyPem" => public_key
  57       },
  58       "endpoints" => endpoints
  59     }
  60     |> Map.merge(Utils.make_json_ld_header())
  61   end
  62
  63   # the instance itself is not a Person, but instead an Application
  64   def render("user.json", %{user: %User{nickname: nil} = user}),
  65     do: render("service.json", %{user: user})
  66
  67   def render("user.json", %{user: %User{nickname: "internal." <> _} = user}),
  68     do: render("service.json", %{user: user}) |> Map.put("preferredUsername", user.nickname)
  69
  70   def render("user.json", %{user: user}) do
  71     {:ok, user} = User.ensure_keys_present(user)
  72     {:ok, _, public_key} = Keys.keys_from_pem(user.keys)
  73     public_key = :public_key.pem_entry_encode(:SubjectPublicKeyInfo, public_key)
  74     public_key = :public_key.pem_encode([public_key])
  75
  76     endpoints = render("endpoints.json", %{user: user})
  77
  78     emoji_tags = Transmogrifier.take_emoji_tags(user)
  79
  80     fields =
  81       user.info
  82       |> User.Info.fields()
  83       |> Enum.map(fn %{"name" => name, "value" => value} ->
  84         %{
  85           "name" => Pleroma.HTML.strip_tags(name),
  86           "value" => Pleroma.HTML.filter_tags(value, Pleroma.HTML.Scrubber.LinksOnly)
  87         }
  88       end)
  89       |> Enum.map(&Map.put(&1, "type", "PropertyValue"))
  90
  91     %{
  92       "id" => user.ap_id,
  93       "type" => "Person",
  94       "following" => "#{user.ap_id}/following",
  95       "followers" => "#{user.ap_id}/followers",
  96       "inbox" => "#{user.ap_id}/inbox",
  97       "outbox" => "#{user.ap_id}/outbox",
  98       "preferredUsername" => user.nickname,
  99       "name" => user.name,
 100       "summary" => user.bio,
 101       "url" => user.ap_id,
 102       "manuallyApprovesFollowers" => user.info.locked,
 103       "publicKey" => %{
 104         "id" => "#{user.ap_id}#main-key",
 105         "owner" => user.ap_id,
 106         "publicKeyPem" => public_key
 107       },
 108       "endpoints" => endpoints,
 109       "attachment" => fields,
 110       "tag" => (user.info.source_data["tag"] || []) ++ emoji_tags,
 111       "discoverable" => user.info.discoverable
 112     }
 113     |> Map.merge(maybe_make_image(&User.avatar_url/2, "icon", user))
 114     |> Map.merge(maybe_make_image(&User.banner_url/2, "image", user))
 115     |> Map.merge(Utils.make_json_ld_header())
 116   end
 117
 118   def render("following.json", %{user: user, page: page} = opts) do
 119     showing_items = (opts[:for] && opts[:for] == user) || !user.info.hide_follows
 120     showing_count = showing_items || !user.info.hide_follows_count
 121
 122     query = User.get_friends_query(user)
 123     query = from(user in query, select: [:ap_id])
 124     following = Repo.all(query)
 125
 126     total =
 127       if showing_count do
 128         length(following)
 129       else
 130         0
 131       end
 132
 133     collection(following, "#{user.ap_id}/following", page, showing_items, total)
 134     |> Map.merge(Utils.make_json_ld_header())
 135   end
 136
 137   def render("following.json", %{user: user} = opts) do
 138     showing_items = (opts[:for] && opts[:for] == user) || !user.info.hide_follows
 139     showing_count = showing_items || !user.info.hide_follows_count
 140
 141     query = User.get_friends_query(user)
 142     query = from(user in query, select: [:ap_id])
 143     following = Repo.all(query)
 144
 145     total =
 146       if showing_count do
 147         length(following)
 148       else
 149         0
 150       end
 151
 152     %{
 153       "id" => "#{user.ap_id}/following",
 154       "type" => "OrderedCollection",
 155       "totalItems" => total,
 156       "first" =>
 157         if showing_items do
 158           collection(following, "#{user.ap_id}/following", 1, !user.info.hide_follows)
 159         else
 160           "#{user.ap_id}/following?page=1"
 161         end
 162     }
 163     |> Map.merge(Utils.make_json_ld_header())
 164   end
 165
 166   def render("followers.json", %{user: user, page: page} = opts) do
 167     showing_items = (opts[:for] && opts[:for] == user) || !user.info.hide_followers
 168     showing_count = showing_items || !user.info.hide_followers_count
 169
 170     query = User.get_followers_query(user)
 171     query = from(user in query, select: [:ap_id])
 172     followers = Repo.all(query)
 173
 174     total =
 175       if showing_count do
 176         length(followers)
 177       else
 178         0
 179       end
 180
 181     collection(followers, "#{user.ap_id}/followers", page, showing_items, total)
 182     |> Map.merge(Utils.make_json_ld_header())
 183   end
 184
 185   def render("followers.json", %{user: user} = opts) do
 186     showing_items = (opts[:for] && opts[:for] == user) || !user.info.hide_followers
 187     showing_count = showing_items || !user.info.hide_followers_count
 188
 189     query = User.get_followers_query(user)
 190     query = from(user in query, select: [:ap_id])
 191     followers = Repo.all(query)
 192
 193     total =
 194       if showing_count do
 195         length(followers)
 196       else
 197         0
 198       end
 199
 200     %{
 201       "id" => "#{user.ap_id}/followers",
 202       "type" => "OrderedCollection",
 203       "totalItems" => total,
 204       "first" =>
 205         if showing_items do
 206           collection(followers, "#{user.ap_id}/followers", 1, showing_items, total)
 207         else
 208           "#{user.ap_id}/followers?page=1"
 209         end
 210     }
 211     |> Map.merge(Utils.make_json_ld_header())
 212   end
 213
 214   def render("activity_collection.json", %{iri: iri}) do
 215     %{
 216       "id" => iri,
 217       "type" => "OrderedCollection",
 218       "first" => "#{iri}?page=true"
 219     }
 220     |> Map.merge(Utils.make_json_ld_header())
 221   end
 222
 223   def render("activity_collection_page.json", %{activities: activities, iri: iri}) do
 224     # this is sorted chronologically, so first activity is the newest (max)
 225     {max_id, min_id, collection} =
 226       if length(activities) > 0 do
 227         {
 228           Enum.at(activities, 0).id,
 229           Enum.at(Enum.reverse(activities), 0).id,
 230           Enum.map(activities, fn act ->
 231             {:ok, data} = Transmogrifier.prepare_outgoing(act.data)
 232             data
 233           end)
 234         }
 235       else
 236         {
 237           0,
 238           0,
 239           []
 240         }
 241       end
 242
 243     %{
 244       "id" => "#{iri}?max_id=#{max_id}&page=true",
 245       "type" => "OrderedCollectionPage",
 246       "partOf" => iri,
 247       "orderedItems" => collection,
 248       "next" => "#{iri}?max_id=#{min_id}&page=true"
 249     }
 250     |> Map.merge(Utils.make_json_ld_header())
 251   end
 252
 253   def collection(collection, iri, page, show_items \\ true, total \\ nil) do
 254     offset = (page - 1) * 10
 255     items = Enum.slice(collection, offset, 10)
 256     items = Enum.map(items, fn user -> user.ap_id end)
 257     total = total || length(collection)
 258
 259     map = %{
 260       "id" => "#{iri}?page=#{page}",
 261       "type" => "OrderedCollectionPage",
 262       "partOf" => iri,
 263       "totalItems" => total,
 264       "orderedItems" => if(show_items, do: items, else: [])
 265     }
 266
 267     if offset < total do
 268       Map.put(map, "next", "#{iri}?page=#{page + 1}")
 269     else
 270       map
 271     end
 272   end
 273
 274   defp maybe_make_image(func, key, user) do
 275     if image = func.(user, no_default: true) do
 276       %{
 277         key => %{
 278           "type" => "Image",
 279           "url" => image
 280         }
 281       }
 282     else
 283       %{}
 284     end
 285   end
 286 end