git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/views/user_view.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.UserView do
   6   use Pleroma.Web, :view
   7
   8   alias Pleroma.Keys
   9   alias Pleroma.Repo
  10   alias Pleroma.User
  11   alias Pleroma.Web.ActivityPub.ActivityPub
  12   alias Pleroma.Web.ActivityPub.Transmogrifier
  13   alias Pleroma.Web.ActivityPub.Utils
  14   alias Pleroma.Web.Endpoint
  15   alias Pleroma.Web.Router.Helpers
  16
  17   import Ecto.Query
  18
  19   def render("endpoints.json", %{user: %User{nickname: nil, local: true} = _user}) do
  20     %{"sharedInbox" => Helpers.activity_pub_url(Endpoint, :inbox)}
  21   end
  22
  23   def render("endpoints.json", %{user: %User{local: true} = _user}) do
  24     %{
  25       "oauthAuthorizationEndpoint" => Helpers.o_auth_url(Endpoint, :authorize),
  26       "oauthRegistrationEndpoint" => Helpers.mastodon_api_url(Endpoint, :create_app),
  27       "oauthTokenEndpoint" => Helpers.o_auth_url(Endpoint, :token_exchange),
  28       "sharedInbox" => Helpers.activity_pub_url(Endpoint, :inbox)
  29     }
  30   end
  31
  32   def render("endpoints.json", _), do: %{}
  33
  34   def render("service.json", %{user: user}) do
  35     {:ok, user} = User.ensure_keys_present(user)
  36     {:ok, _, public_key} = Keys.keys_from_pem(user.info.keys)
  37     public_key = :public_key.pem_entry_encode(:SubjectPublicKeyInfo, public_key)
  38     public_key = :public_key.pem_encode([public_key])
  39
  40     endpoints = render("endpoints.json", %{user: user})
  41
  42     %{
  43       "id" => user.ap_id,
  44       "type" => "Application",
  45       "following" => "#{user.ap_id}/following",
  46       "followers" => "#{user.ap_id}/followers",
  47       "inbox" => "#{user.ap_id}/inbox",
  48       "name" => "Pleroma",
  49       "summary" =>
  50         "An internal service actor for this Pleroma instance.  No user-serviceable parts inside.",
  51       "url" => user.ap_id,
  52       "manuallyApprovesFollowers" => false,
  53       "publicKey" => %{
  54         "id" => "#{user.ap_id}#main-key",
  55         "owner" => user.ap_id,
  56         "publicKeyPem" => public_key
  57       },
  58       "endpoints" => endpoints
  59     }
  60     |> Map.merge(Utils.make_json_ld_header())
  61   end
  62
  63   # the instance itself is not a Person, but instead an Application
  64   def render("user.json", %{user: %User{nickname: nil} = user}),
  65     do: render("service.json", %{user: user})
  66
  67   def render("user.json", %{user: %User{nickname: "internal." <> _} = user}),
  68     do: render("service.json", %{user: user}) |> Map.put("preferredUsername", user.nickname)
  69
  70   def render("user.json", %{user: user}) do
  71     {:ok, user} = User.ensure_keys_present(user)
  72     {:ok, _, public_key} = Keys.keys_from_pem(user.info.keys)
  73     public_key = :public_key.pem_entry_encode(:SubjectPublicKeyInfo, public_key)
  74     public_key = :public_key.pem_encode([public_key])
  75
  76     endpoints = render("endpoints.json", %{user: user})
  77
  78     user_tags =
  79       user
  80       |> Transmogrifier.add_emoji_tags()
  81       |> Map.get("tag", [])
  82
  83     fields =
  84       user.info
  85       |> User.Info.fields()
  86       |> Enum.map(&Map.put(&1, "type", "PropertyValue"))
  87
  88     %{
  89       "id" => user.ap_id,
  90       "type" => "Person",
  91       "following" => "#{user.ap_id}/following",
  92       "followers" => "#{user.ap_id}/followers",
  93       "inbox" => "#{user.ap_id}/inbox",
  94       "outbox" => "#{user.ap_id}/outbox",
  95       "preferredUsername" => user.nickname,
  96       "name" => user.name,
  97       "summary" => user.bio,
  98       "url" => user.ap_id,
  99       "manuallyApprovesFollowers" => user.info.locked,
 100       "publicKey" => %{
 101         "id" => "#{user.ap_id}#main-key",
 102         "owner" => user.ap_id,
 103         "publicKeyPem" => public_key
 104       },
 105       "endpoints" => endpoints,
 106       "attachment" => fields,
 107       "tag" => (user.info.source_data["tag"] || []) ++ user_tags
 108     }
 109     |> Map.merge(maybe_make_image(&User.avatar_url/2, "icon", user))
 110     |> Map.merge(maybe_make_image(&User.banner_url/2, "image", user))
 111     |> Map.merge(Utils.make_json_ld_header())
 112   end
 113
 114   def render("following.json", %{user: user, page: page} = opts) do
 115     showing = (opts[:for] && opts[:for] == user) || !user.info.hide_follows
 116     query = User.get_friends_query(user)
 117     query = from(user in query, select: [:ap_id])
 118     following = Repo.all(query)
 119
 120     total =
 121       if showing do
 122         length(following)
 123       else
 124         0
 125       end
 126
 127     collection(following, "#{user.ap_id}/following", page, showing, total)
 128     |> Map.merge(Utils.make_json_ld_header())
 129   end
 130
 131   def render("following.json", %{user: user} = opts) do
 132     showing = (opts[:for] && opts[:for] == user) || !user.info.hide_follows
 133     query = User.get_friends_query(user)
 134     query = from(user in query, select: [:ap_id])
 135     following = Repo.all(query)
 136
 137     total =
 138       if showing do
 139         length(following)
 140       else
 141         0
 142       end
 143
 144     %{
 145       "id" => "#{user.ap_id}/following",
 146       "type" => "OrderedCollection",
 147       "totalItems" => total,
 148       "first" =>
 149         if showing do
 150           collection(following, "#{user.ap_id}/following", 1, !user.info.hide_follows)
 151         else
 152           "#{user.ap_id}/following?page=1"
 153         end
 154     }
 155     |> Map.merge(Utils.make_json_ld_header())
 156   end
 157
 158   def render("followers.json", %{user: user, page: page} = opts) do
 159     showing = (opts[:for] && opts[:for] == user) || !user.info.hide_followers
 160
 161     query = User.get_followers_query(user)
 162     query = from(user in query, select: [:ap_id])
 163     followers = Repo.all(query)
 164
 165     total =
 166       if showing do
 167         length(followers)
 168       else
 169         0
 170       end
 171
 172     collection(followers, "#{user.ap_id}/followers", page, showing, total)
 173     |> Map.merge(Utils.make_json_ld_header())
 174   end
 175
 176   def render("followers.json", %{user: user} = opts) do
 177     showing = (opts[:for] && opts[:for] == user) || !user.info.hide_followers
 178
 179     query = User.get_followers_query(user)
 180     query = from(user in query, select: [:ap_id])
 181     followers = Repo.all(query)
 182
 183     total =
 184       if showing do
 185         length(followers)
 186       else
 187         0
 188       end
 189
 190     %{
 191       "id" => "#{user.ap_id}/followers",
 192       "type" => "OrderedCollection",
 193       "totalItems" => total,
 194       "first" =>
 195         if showing do
 196           collection(followers, "#{user.ap_id}/followers", 1, showing, total)
 197         else
 198           "#{user.ap_id}/followers?page=1"
 199         end
 200     }
 201     |> Map.merge(Utils.make_json_ld_header())
 202   end
 203
 204   def render("outbox.json", %{user: user, max_id: max_qid}) do
 205     params = %{
 206       "limit" => "10"
 207     }
 208
 209     params =
 210       if max_qid != nil do
 211         Map.put(params, "max_id", max_qid)
 212       else
 213         params
 214       end
 215
 216     activities = ActivityPub.fetch_user_activities(user, nil, params)
 217
 218     {max_id, min_id, collection} =
 219       if length(activities) > 0 do
 220         {
 221           Enum.at(Enum.reverse(activities), 0).id,
 222           Enum.at(activities, 0).id,
 223           Enum.map(activities, fn act ->
 224             {:ok, data} = Transmogrifier.prepare_outgoing(act.data)
 225             data
 226           end)
 227         }
 228       else
 229         {
 230           0,
 231           0,
 232           []
 233         }
 234       end
 235
 236     iri = "#{user.ap_id}/outbox"
 237
 238     page = %{
 239       "id" => "#{iri}?max_id=#{max_id}",
 240       "type" => "OrderedCollectionPage",
 241       "partOf" => iri,
 242       "orderedItems" => collection,
 243       "next" => "#{iri}?max_id=#{min_id}"
 244     }
 245
 246     if max_qid == nil do
 247       %{
 248         "id" => iri,
 249         "type" => "OrderedCollection",
 250         "first" => page
 251       }
 252       |> Map.merge(Utils.make_json_ld_header())
 253     else
 254       page |> Map.merge(Utils.make_json_ld_header())
 255     end
 256   end
 257
 258   def render("inbox.json", %{user: user, max_id: max_qid}) do
 259     params = %{
 260       "limit" => "10"
 261     }
 262
 263     params =
 264       if max_qid != nil do
 265         Map.put(params, "max_id", max_qid)
 266       else
 267         params
 268       end
 269
 270     activities = ActivityPub.fetch_activities([user.ap_id | user.following], params)
 271
 272     min_id = Enum.at(Enum.reverse(activities), 0).id
 273     max_id = Enum.at(activities, 0).id
 274
 275     collection =
 276       Enum.map(activities, fn act ->
 277         {:ok, data} = Transmogrifier.prepare_outgoing(act.data)
 278         data
 279       end)
 280
 281     iri = "#{user.ap_id}/inbox"
 282
 283     page = %{
 284       "id" => "#{iri}?max_id=#{max_id}",
 285       "type" => "OrderedCollectionPage",
 286       "partOf" => iri,
 287       "orderedItems" => collection,
 288       "next" => "#{iri}?max_id=#{min_id}"
 289     }
 290
 291     if max_qid == nil do
 292       %{
 293         "id" => iri,
 294         "type" => "OrderedCollection",
 295         "first" => page
 296       }
 297       |> Map.merge(Utils.make_json_ld_header())
 298     else
 299       page |> Map.merge(Utils.make_json_ld_header())
 300     end
 301   end
 302
 303   def collection(collection, iri, page, show_items \\ true, total \\ nil) do
 304     offset = (page - 1) * 10
 305     items = Enum.slice(collection, offset, 10)
 306     items = Enum.map(items, fn user -> user.ap_id end)
 307     total = total || length(collection)
 308
 309     map = %{
 310       "id" => "#{iri}?page=#{page}",
 311       "type" => "OrderedCollectionPage",
 312       "partOf" => iri,
 313       "totalItems" => total,
 314       "orderedItems" => if(show_items, do: items, else: [])
 315     }
 316
 317     if offset < total do
 318       Map.put(map, "next", "#{iri}?page=#{page + 1}")
 319     else
 320       map
 321     end
 322   end
 323
 324   defp maybe_make_image(func, key, user) do
 325     if image = func.(user, no_default: true) do
 326       %{
 327         key => %{
 328           "type" => "Image",
 329           "url" => image
 330         }
 331       }
 332     else
 333       %{}
 334     end
 335   end
 336 end